dev-java/openjdk-jre-bin: add 17.0.14_p7

Bug: https://bugs.gentoo.org/948666
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -1,5 +1,6 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.25_9.tar.gz 43388792 BLAKE2B 59f2ea968f5f243dc2e0b8d82270620839a5cbafd93bfb611b3713455e366f956357b1424e69e3082730e6803934f78852db8e06d6ff6dcda7f7bf5ce2c6323c SHA512 3e602a497d66ef423ba9110a69149ad5fe3c939c629eda1a0946697623ada8a1582d08b55f498b1d0862c95a7c64b0fab804fb713e49bdd4ddd9657c164ab7db
 DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.13_11.tar.gz 46082619 BLAKE2B 18cfcba579deb6665f45de59b145d2f9b3c047456e548b0728619a8b711890f66c15d0522e89ef3f8d7f9747636cefc509efc0d8c12e709d6f7e2faf8c6d1860 SHA512 6ab44ec3ae9f610b68008e68069a66095c7b2d1deba2990e061baf9800cbeafd818cb16a9386aabbc18299bc46e0f23540111eb6a0597561c835e67506eeff97
+DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.14_7.tar.gz 46092700 BLAKE2B e4045ac58993c771e750464dba07432857facb49aca86954ff0446c3be7b4749848bc39a31519bc72ea83c81f70aa7c2c975ee750c41993bfd5fe37c7537ea28 SHA512 42cce997473203c1aa7bf4d64706b1031536cccbe40a35ef8ad37e23cc87e1ef6adca9afa69ac857d571ba888f7a9a8fe6a950f0084b22f58f36b865cbd975a6
 DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.5_11.tar.gz 51849867 BLAKE2B 6769bd34c2ba7f6d4939f1b7647cb7bd5eea5644a05f4e5474db612c29e05d247829b1eea2f0265febf41cd6a64a1e62c5eef7f1ee7c68e84f6bb085d3c656fb SHA512 7077e879e656a2b3bcb6274d5eb312320a95f13e909bd0fb5589e665db545caca0a6bf7d1117d76fe201caaa50a3bf917316e43f08d94b48872607bc25238a94
 DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.6_7.tar.gz 51858210 BLAKE2B f45a6578b92a04663d1b2cb5f6a8d2bd7d5f8eebdbb9cdb843ae37491c9f48f431ac6b3207711ed53d2cc2727aae274b475b698e3e8aa9714226bccddc7f35de SHA512 5b4c90176ae56880d3f71330032ca679fac4f6df8002c14dbeb095952b23a4a502433205ec3deffbe1a11f4a9211a4b32d50c7d44254d2fb7d2f7c027590a7f3
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u432b06.tar.gz 41407945 BLAKE2B 99d146ceb6627be04b30bde28691df1362f2acc147a8b260d9633fb11d9ef2f23f2a0876a6cd32515dc0541ce1f5feb475793225266da9197ac7392db13c512a SHA512 c32343125e66005c9239d1002fad2a183bc3834dc1be5f85ca9bf6535bc40bc629d7e538cefc0d07cc2b49275a54ebd19098e43aecfc34cbd40e549da902b894

dev-java/openjdk-jre-bin/openjdk-jre-bin-17.0.14_p7.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk-${MY_PV}/OpenJDK${SLOT}U-jre_${1}_linux_hotspot_${MY_PV//+/_}.tar.gz
+		)"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net/"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="alsa cups headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${PN}-${SLOT}"
+	local ddest="${ED}/${dest#/}"
+
+	# Not sure why they bundle this as it's commonly available and they
+	# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+	# also has an explicit dependency while Oracle seemingly dlopens it.
+	rm -vf lib/libfreetype.so || die
+
+	# Oracle and IcedTea have libjsoundalsa.so depending on
+	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+	if ! use alsa ; then
+		rm -v lib/libjsound.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -v lib/lib*{[jx]awt,splashscreen}* || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+}