app-misc/linux-logo: add 6.01

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

app-misc/linux-logo/Manifest

@@ -1 +1,2 @@
 DIST linux_logo-6.0.tar.gz 117486 BLAKE2B 3340b893574f0c18561b208824cd80cff19c387d981af6ca63f56e691cebd2030e058ef367d91a999fd662592582da38b21a5a31f3f8364dbd87a43bd2c2b608 SHA512 ebd7513f90e79bb21acd984c671a1d1ce8421411d2b2948b01e6e08f7c9826184f9b9d528e0cfc814df8d8015d444a09c45025c344115ac9a6c2cff5743f03ad
+DIST linux_logo-6.01.tar.gz 119482 BLAKE2B 369e99ab4fbc77fc41d3598c11a4a5c8c1b7bdd246408b0fab5f623fb6a701edf6e2e5f2ce494e9c8aaac3d00cc47525a0daf6525cf9bbbf068d5eeba93a9f6e SHA512 1949758289b79baa9219665f59f92edab20dfa4c3e33fa32ff99ea1da36eccaf65a5ac1135b70cb8309c13d722a651c639c210383510347789f949e9f5148809

app-misc/linux-logo/linux-logo-6.01.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit toolchain-funcs systemd
+
+MY_P=${PN/-/_}-${PV}
+DESCRIPTION="A utility that displays an ANSI/ASCII logo and some system information"
+HOMEPAGE="http://www.deater.net/weave/vmwprod/linux_logo/"
+SRC_URI="http://www.deater.net/weave/vmwprod/linux_logo/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+RDEPEND="nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/"${PN}"-6.0-configure.patch
+)
+
+DOCS=( BUGS README README.CUSTOM_LOGOS TODO USAGE LINUX_LOGO.FAQ )
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	cp "${FILESDIR}"/logo-config "${S}/logo_config" || die
+	cp "${FILESDIR}"/linux_logo_creator "${S}/" || die
+	cp "${FILESDIR}"/linux-logo.service "${S}/" || die
+	cp "${FILESDIR}"/gentoo-*.logo "${S}"/logos/ || die
+
+	sed -e 's#=$(PREFIX)#=$(DESTDIR)$(PREFIX)#' -i po/Makefile || die
+
+	# Manpage is already gzipped in tarball
+	gunzip linux_logo.1.gz || die
+	sed -e "s/.1.gz/.1/g" -i Makefile || die
+
+	default
+}
+
+src_configure() {
+	ARCH="" CC="$(tc-getCC)" AR="$(tc-getAR)" econf
+}
+
+src_install() {
+	default
+
+	dobin "${FILESDIR}"/linux_logo_creator
+	newinitd "${FILESDIR}"/${PN}.init.d ${PN}
+	newconfd "${FILESDIR}"/${PN}-5.11.conf ${PN}
+
+	# systemd support
+	systemd_newunit "${FILESDIR}/linux-logo.service" "linux-logo.service"
+}
+
+pkg_postinst() {
+	echo
+	elog "Linux_logo ebuild for Gentoo comes with two Gentoo logos."
+	elog ""
+	elog "To display the first Gentoo logo type: linux_logo -L gentoo"
+	elog "To display the second Gentoo logo type: linux_logo -L gentoo-alt"
+	elog "To display all the logos available type: linux_logo -L list."
+	elog ""
+	elog "To start linux_logo on boot, please type:"
+	elog "   rc-update add linux-logo default"
+	elog "or for systemd"
+	elog "   systemctl enable linux-logo.service"
+	elog "which uses the settings found in"
+	elog "   /etc/conf.d/linux-logo"
+	echo
+}
+
+pkg_prerm() {
+	# Restore issue files
+	mv /etc/issue.linux-logo.backup /etc/issue 2> /dev/null
+	mv /etc/issue.net.linux-logo.backup /etc/issue.net 2> /dev/null
+}