mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
www-client/qutebrowser: add 2.5.0
This includes a workaround for CVE-2022-25255 wrt bug #833583 Bug: https://bugs.gentoo.org/833583 Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
Ionen Wolkens
@@ -1 +1,2 @@
|
||||
DIST qutebrowser-2.4.0.tar.gz 6074001 BLAKE2B 9eda4a72b9050d6992681803b69778d954654fffd78aa524dfba9bddcbb8e54bd84e6725c30d826dddeb45b6b76e06d7401c7ad22d15a153b4cc1104e791cc84 SHA512 e4341a57a259a31e1c665eec34329594bb3d8390e3c612a15c1857ff12cb9e1f5b30954dd0cd91bee0a40ec0d97c59349ab7cd699626434a89c7d40e5dd961f7
|
||||
DIST qutebrowser-2.5.0.tar.gz 6086105 BLAKE2B c95afbbdfeebe4352e461cef78d499e9efa9de2e4acc2cedf350904bd617a4f238c34042369655030e53433f941288ff676f8ffd873683939ddd38ff01604aa1 SHA512 41ab6f6d2b72c94e0f66ba0a80999d820748d0f86dbec92583a2be88725f1ebd7517dd75edbaa0ce60bc029ed4dc0dd3e30a1cb25ab4ef940b968c87b4df2472
|
||||
|
||||
122
www-client/qutebrowser/qutebrowser-2.5.0.ebuild
Normal file
122
www-client/qutebrowser/qutebrowser-2.5.0.ebuild
Normal file
@@ -0,0 +1,122 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_SINGLE_IMPL=1
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{8..10} )
|
||||
inherit distutils-r1 optfeature xdg
|
||||
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/qutebrowser/qutebrowser.git"
|
||||
else
|
||||
SRC_URI="https://github.com/qutebrowser/qutebrowser/releases/download/v${PV}/${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Keyboard-driven, vim-like browser based on PyQt5 and QtWebEngine"
|
||||
HOMEPAGE="https://www.qutebrowser.org/"
|
||||
|
||||
LICENSE="GPL-3+"
|
||||
SLOT="0"
|
||||
IUSE="+adblock widevine"
|
||||
|
||||
RDEPEND="
|
||||
dev-qt/qtcore:5[icu]
|
||||
dev-qt/qtgui:5[png]
|
||||
$(python_gen_cond_dep 'dev-python/importlib_resources[${PYTHON_USEDEP}]' python3_8)
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/colorama[${PYTHON_USEDEP}]
|
||||
>=dev-python/jinja-3.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/markupsafe-2.0.1[${PYTHON_USEDEP}]
|
||||
dev-python/pygments[${PYTHON_USEDEP}]
|
||||
dev-python/PyQt5[${PYTHON_USEDEP},dbus,declarative,multimedia,gui,network,opengl,printsupport,sql,widgets]
|
||||
dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
|
||||
dev-python/pyyaml[${PYTHON_USEDEP},libyaml(+)]
|
||||
dev-python/zipp[${PYTHON_USEDEP}]
|
||||
adblock? ( dev-python/adblock[${PYTHON_USEDEP}] )')
|
||||
widevine? ( www-plugins/chrome-binary-plugins )"
|
||||
BDEPEND="
|
||||
$(python_gen_cond_dep '
|
||||
test? (
|
||||
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
|
||||
dev-python/cheroot[${PYTHON_USEDEP}]
|
||||
dev-python/flask[${PYTHON_USEDEP}]
|
||||
dev-python/hypothesis[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-bdd[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-mock[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-qt[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-xvfb[${PYTHON_USEDEP}]
|
||||
dev-python/tldextract[${PYTHON_USEDEP}]
|
||||
)')"
|
||||
[[ ${PV} != 9999 ]] || BDEPEND+=" app-text/asciidoc"
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
python_prepare_all() {
|
||||
distutils-r1_python_prepare_all
|
||||
|
||||
if use widevine; then
|
||||
local widevine=${EPREFIX}/usr/$(get_libdir)/chromium-browser/WidevineCdm/_platform_specific/linux_x64/libwidevinecdm.so
|
||||
sed "/yield from _qtwebengine_settings_args/a\ yield '--widevine-path=${widevine}'" \
|
||||
-i ${PN}/config/qtargs.py || die
|
||||
fi
|
||||
|
||||
# let eclass handle python
|
||||
sed -i '/setup.py/d' misc/Makefile || die
|
||||
|
||||
[[ ${PV} != 9999 ]] || ${EPYTHON} scripts/asciidoc2html.py || die
|
||||
|
||||
# these plugins/tests are unnecessary here and have extra dependencies
|
||||
sed -e '/pytest-benchmark/d;s/--benchmark[^ ]*//' \
|
||||
-e '/pytest-instafail/d;s/--instafail//' \
|
||||
-i pytest.ini || die
|
||||
[[ ${PV} == 9999 ]] || rm tests/unit/scripts/test_problemmatchers.py || die
|
||||
[[ ${PV} != 9999 ]] || rm tests/unit/scripts/test_run_vulture.py || die
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local EPYTEST_DESELECT=(
|
||||
# end2end and other IPC tests are broken with "Name error" if
|
||||
# socket path is over 104 characters (=124 in /var/tmp/portage)
|
||||
# https://github.com/qutebrowser/qutebrowser/issues/888 (not just OSX)
|
||||
tests/end2end
|
||||
tests/unit/misc/test_ipc.py
|
||||
# tests that don't know about our newer qtwebengine
|
||||
tests/unit/browser/webengine/test_webenginedownloads.py::TestDataUrlWorkaround
|
||||
tests/unit/utils/test_version.py::TestChromiumVersion
|
||||
# may misbehave depending on installed old python versions
|
||||
tests/unit/misc/test_checkpyver.py::test_old_python
|
||||
# bug 819393
|
||||
tests/unit/commands/test_userscripts.py::test_custom_env[_POSIXUserscriptRunner]
|
||||
)
|
||||
use widevine && EPYTEST_DESELECT+=( tests/unit/config/test_qtargs.py )
|
||||
|
||||
# skip benchmarks (incl. _tree), and warning tests broken by -Wdefault
|
||||
epytest -k 'not _bench and not _matches_tree and not _warning'
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
emake -f misc/Makefile DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
|
||||
|
||||
rm "${ED}"/usr/share/${PN}/scripts/{mkvenv,utils}.py || die
|
||||
fperms -x /usr/share/${PN}/{scripts/cycle-inputs.js,userscripts/README.md}
|
||||
python_fix_shebang "${ED}"/usr/share/${PN}
|
||||
|
||||
einstalldocs
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
optfeature "PDF display support" www-plugins/pdfjs
|
||||
|
||||
if [[ ! ${REPLACING_VERSIONS} ]]; then
|
||||
elog "Note that optional scripts in ${EROOT}/usr/share/${PN}/{user,}scripts"
|
||||
elog "have additional dependencies not covered by this ebuild, for example"
|
||||
elog "view_in_mpv needs media-video/mpv[lua] and net-misc/yt-dlp."
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user