sci-astronomy/siril: add 1.2.0

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Closes: https://github.com/gentoo/gentoo/pull/32873
Signed-off-by: Sam James <sam@gentoo.org>

sci-astronomy/siril/Manifest

@@ -1,2 +1,3 @@
 DIST siril-1.0.6.tar.bz2 2893872 BLAKE2B 1f254dcb774c4bfb14fee4626d40e6eeedf866a7a96dca98502cd84e66b973c2201b1f88e2efcb89ce3401b13bd87a319b2ff11e7ba100d0689c9df429d01957 SHA512 afb5f1768a5884adcc13f2afd6fa386d836df5a1385b916df9df8da1fb464e0c8738123fb485ed92c749e596c744d5252a66444b840223488a0860e9324c4e9d
 DIST siril-1.2.0-rc1.tar.bz2 4353720 BLAKE2B 38c7b1585508ac9697847648f2d718899a296a4061b34fcf71424136daa50c68737f811fd9063aa80274708d085d8089dceff7d1fd25277b60f0482c17fa5cd1 SHA512 41d685c0aca79da8a9c17d729c710bdd51d3f8cd13b976fb4aad4750e74b600783b988246f008cf41246e7e5f05b8b42368d975cbd79f42e9121b39e367eb22f
+DIST siril-1.2.0.tar.bz2 4500147 BLAKE2B 7ff4fa5bf1b578336c82bd0f67e404fe47715640edae9cb231da4a3c6a30638612e77515049d56dd1d444965ad58f12d5e2516ad13d3e726f13242b11d91b954 SHA512 7df7b17d65a2aad9e0edd4b5022c1d23688ad8884a973d2195391234151aff0824e155ce949b385a951eaef71065a811f33b54e08b865ab5fa6c1d331841663c

sci-astronomy/siril/siril-1.2.0.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature toolchain-funcs xdg
+
+DESCRIPTION="A free astronomical image processing software"
+HOMEPAGE="https://siril.org/"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/free-astro/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/free-astro/siril/-/archive/${PV/_/-}/${PN}-${PV/_/-}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+LICENSE="GPL-3+ Boost-1.0"
+SLOT="0"
+IUSE="curl exif ffmpeg heif jpeg libconfig openmp png raw tiff wcs"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=dev-libs/json-glib-1.2.6
+	media-libs/librtprocess
+	>=media-libs/opencv-4.4.0:=
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	x11-libs/gdk-pixbuf:2
+	x11-libs/cairo
+	x11-libs/pango
+	>=x11-libs/gtk+-3.20.0:3
+	curl? ( net-misc/curl )
+	exif? ( >=media-gfx/exiv2-0.25:= )
+	ffmpeg? ( media-video/ffmpeg:= )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	libconfig? ( >=dev-libs/libconfig-1.4:=[cxx] )
+	png? ( >=media-libs/libpng-1.6.0:= )
+	raw? ( media-libs/libraw:= )
+	tiff? ( media-libs/tiff:= )
+	wcs? ( >=sci-astronomy/wcslib-7.7:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="dev-util/cmake
+	x11-base/xorg-proto"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-docfiles.patch"
+	"${FILESDIR}/${PN}-1.2-exiv2-0.28.patch" # bug 906499
+)
+
+DOCS=( README.md NEWS ChangeLog AUTHORS )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dffms2=false
+		-Dcriterion=false
+		$(meson_use exif exiv2)
+		$(meson_use ffmpeg)
+		$(meson_use heif libheif)
+		$(meson_use jpeg libjpeg)
+		$(meson_use libconfig)
+		$(meson_use openmp)
+		$(meson_use png libpng)
+		$(meson_use raw libraw)
+		$(meson_use tiff libtiff)
+		$(meson_use wcs wcslib)
+		$(usex curl -Denable-libcurl=yes -Denable-libcurl=no)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	optfeature "gnuplot support" sci-visualization/gnuplot
+}