dev-python/oslotest: 3.2.0 bup

Package-Manager: Portage-2.3.19, Repoman-2.3.6

dev-python/oslotest/Manifest

@@ -1 +1,2 @@
 DIST oslotest-2.17.1.tar.gz 32166 BLAKE2B 49922cedc32bebda867c6633118cbd8258a08048c510333d04e0b2f8f5efd4e5dde802bfb8910936dffca76823771d3e83e78528b5fd045ae4380e02f92cf809 SHA512 558d2c220a6b1235112022b495c77881f52895cb720d67090ad096576b4e81044b228bd95b8303779bf8cca2e1205ef912b1fedd1916a34130f4c68ef69fcc0d
+DIST oslotest-3.2.0.tar.gz 35445 BLAKE2B d33c70e760fc595586c2d7b0ce6ed1f63b73c89ba078f85b70d3b6b1af1c4d115e6eb7b431f9ef52abf50290eb47a1d3adb2d014c2ba5cf7b93ecf0e46401a26 SHA512 4513291e2bec939f9734255cb0fe3f85b9eb8a8cadce58873ad4e85365a0ec27bc2084085f5b95b681b5e811b62458e18fe63aff1e022b2d8ace0ca48bd6a527

dev-python/oslotest/oslotest-3.2.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Oslo test framework"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/oslo-config-5.1.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/openstackdocstheme-1.17.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		>=dev-python/reno-2.5.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mox3-0.20.0[${PYTHON_USEDEP}]
+	>=dev-python/os-client-config-1.28.0[${PYTHON_USEDEP}]
+"
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx -b man
+	fi
+}
+
+python_test() {
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPYTHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		doman doc/build/man/oslotest.1
+	fi
+
+	distutils-r1_python_install_all
+}