dev-python/pygobject: add 3.50.0

Signed-off-by: Blake Batson <bbatson101@gmail.com>
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

dev-python/pygobject/Manifest

@@ -1,2 +1,3 @@
 DIST pygobject-3.46.0.tar.xz 561552 BLAKE2B 6b8c9b4bf6df819c09b7bd2ea6dcb0e7c24ed7f171487b774469bd2c4694df9d4473dbde05273afc7a370f2b1f352d60347aa221bdd674a4aa8a54123d5e54cd SHA512 48293c193ba5aece38d99f45d325d0329ac33e88442bf00848fe818a7c838977b8d2cf50a404c30e8852ccc0b4a44dfda07751d51acc21f740aa2ab6aa3ce661
 DIST pygobject-3.48.2.tar.xz 556244 BLAKE2B 6ac7a42752d65668f228aa9823a4e256b030bc84683857e5470bc373eaaf383904d18399379b4a7d0989644e2b0825d63cc8b3f927b97608a209f888bf8cb276 SHA512 11619f73be5894fae82b261779f33390d1aec51b02bcf285c58f3c76ee46dfc1b3f435e4662176fde5ca899aee5afc453f8f0ba28e15e15330a52354cf737d45
+DIST pygobject-3.50.0.tar.xz 929848 BLAKE2B 1f3d27f055132e82c7aff2f4aa664d1dec57096027a4ceaf9c7245d0e05627d4ba5a8cb7396d35cec4ccf86db9cfedcf9f18a200252fffd00340888e95909c09 SHA512 59edec92b29f3101e4f1afd83a37f4d490e8d833e0dbba9ae8c30891541767e3738bb748ed939b2baef1041eec88f192188d38a82712f1ebc089005b4d6f03a9

dev-python/pygobject/pygobject-3.50.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit gnome.org meson virtualx xdg distutils-r1
+
+DESCRIPTION="Python bindings for GObject Introspection"
+HOMEPAGE="
+	https://pygobject.gnome.org/
+	https://gitlab.gnome.org/GNOME/pygobject/
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="+cairo examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.64:2
+	>=dev-libs/gobject-introspection-1.64:=
+	dev-libs/libffi:=
+	cairo? (
+		>=dev-python/pycairo-1.16.0[${PYTHON_USEDEP}]
+		x11-libs/cairo[glib]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=app-accessibility/at-spi2-core-2.46.0[introspection]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		x11-libs/gdk-pixbuf:2[introspection,jpeg]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+python_configure() {
+	local emesonargs=(
+		$(meson_feature cairo pycairo)
+		$(meson_use test tests)
+		-Dpython="${EPYTHON}"
+	)
+	meson_src_configure
+}
+
+python_compile() {
+	meson_src_compile
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
+	local -x GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x XDG_CACHE_HOME="${T}/${EPYTHON}"
+	meson_src_test --timeout-multiplier 3 || die "test failed for ${EPYTHON}"
+}
+
+python_install() {
+	meson_src_install
+	python_optimize
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}