gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-24 06:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/dns-lexicon: Bump to 3.15.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-10-01 05:12:35 +02:00
parent 74600b1719
commit e19f450fe0
2 changed files with 72 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/dns-lexicon/Manifest
View File

@@ -1,3 +1,4 @@
DIST dns-lexicon-3.12.0.gh.tar.gz 6729773 BLAKE2B 1566b98db71027a8c49c7c90060a67b0efc8dc8afb8c977c0277d29c751f26cabc824a510194f09d02f19a40151bfdebe877ccd3e0bfcc8484f694ce128c0d95 SHA512 4ba799c6f7a01b8209f5274337258d0525efff366b297fff2fcff1d40c7ee58850fa8c3743bf9d29a1a082288e1f615cd94036a9cdc7be9f85e46f26fe3d7fbc
DIST dns-lexicon-3.13.0.gh.tar.gz 6739417 BLAKE2B 86f879fb5b27c6d9b21788ce4a9d7573b9aca0eccc022f4ac81cbb0e683f089797156134720bcbd82b509253470b01ee3ead3161517a0108d16991b668e1b4f3 SHA512 582efefb93d9f122cf3f900ddc7cf615295855645f6d9621f14c11067e441eb67349adf40e5159b75e8c5703d1cfd874364d392ce2994feb89949d371b4b55be
DIST dns-lexicon-3.14.1.gh.tar.gz 6747567 BLAKE2B 55ddba2caf71b92ad0e5f34457d33c46be5969b13a12ac16a07e5c9ad8a25b921119edf89ce80928340e401308365eeb5b7c7c56f8e36482422f7e2e43412cde SHA512 13e4c5b046cad28e487b246b7c16a3ee71b2dbca4c40e513b234cee62e483e7702ce293c11ef96b245409229a7cd3a39c1771ebfc7b2430cd5b017d33e32a924
DIST dns-lexicon-3.15.0.gh.tar.gz 6200937 BLAKE2B 94ff86424e5f9d03d5ec059359f684cbcda8fd617f84510c7154c2f48072b766bab0497ef1dd46c630b25f8196d177715eeaa9223bf2b502f125526120f91327 SHA512 22e6f11e2b5750ff44c8a72b0e6c0a1a4126e247074b87cf7fbbf403d8858c261fb2c57a5d01daa218e4b3448782ccb5567fd6f29da78baabb2aded90a82c97c

71
dev-python/dns-lexicon/dns-lexicon-3.15.0.ebuild Normal file
View File

@@ -0,0 +1,71 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 optfeature
DESCRIPTION="Manipulate DNS records on various DNS providers in a standardized/agnostic way"
HOMEPAGE="
https://github.com/AnalogJ/lexicon/
https://pypi.org/project/dns-lexicon/
"
SRC_URI="
https://github.com/AnalogJ/lexicon/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/lexicon-${PV}"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
>=dev-python/pyotp-2[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/tldextract[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
>=dev-python/boto3-1.25[${PYTHON_USEDEP}]
dev-python/dnspython[${PYTHON_USEDEP}]
dev-python/zeep[${PYTHON_USEDEP}]
dev-python/vcrpy[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
EPYTEST_IGNORE=(
# Requires the "localzone" module
tests/providers/test_localzone.py
# Requires the "softlayer" module
tests/providers/test_softlayer.py
# Requires the "transip" module
tests/providers/test_transip.py
# Requires the "oci" module
tests/providers/test_oci.py
# Uses tldextract which needs Internet access to download its database
tests/providers/test_auto.py
# All recordings seem to be broken
tests/providers/test_namecheap.py
# Broken by minor vcrpy / urllib3-2 incompatibility
# https://github.com/kevin1024/vcrpy/issues/714
tests/providers/test_route53.py
)
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]]; then
optfeature_header \
"Install the following packages to enable support for additional DNS providers:"
optfeature Gransy dev-python/zeep
optfeature Route53 dev-python/boto3
optfeature DDNS dev-python/dnspython
fi
}