gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/Pyro4: EAPI 8, pytest, fix tests

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-10-17 08:02:30 +02:00
parent 3294f2f150
commit e198072a45
2 changed files with 60 additions and 55 deletions
Download Patch File Download Diff File Expand all files Collapse all files

60
dev-python/Pyro4/Pyro4-4.82-r1.ebuild Normal file
View File

@@ -0,0 +1,60 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
DESCRIPTION="Distributed object middleware for Python (RPC)"
HOMEPAGE="
https://github.com/irmen/Pyro4/
https://pypi.org/project/Pyro4/
"
SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm64 ppc x86"
IUSE="doc examples"
RDEPEND="
>=dev-python/serpent-1.27[${PYTHON_USEDEP}]
"
DEPEND="
test? (
>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
>=dev-python/dill-0.2.6[${PYTHON_USEDEP}]
>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# network
tests/PyroTests/test_naming.py
tests/PyroTests/test_naming2.py::OfflineNameServerTests::testStartNSfunc
tests/PyroTests/test_naming2.py::OfflineNameServerTestsDbmStorage::testStartNSfunc
tests/PyroTests/test_naming2.py::OfflineNameServerTestsSqlStorage::testStartNSfunc
tests/PyroTests/test_serialize.py::SerializeTests_dill::testSerCoreOffline
tests/PyroTests/test_serialize.py::SerializeTests_dill::testSerializeDumpsAndDumpsCall
tests/PyroTests/test_socket.py::TestSocketutil::testBroadcast
tests/PyroTests/test_socket.py::TestSocketutil::testGetIP
)
cd tests/PyroTests || die
epytest
}
python_install_all() {
use doc && HTML_DOCS=( docs/. )
if use examples; then
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}

55
dev-python/Pyro4/Pyro4-4.82.ebuild
View File

@@ -1,55 +0,0 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
DESCRIPTION="Distributed object middleware for Python (RPC)"
HOMEPAGE="https://pypi.org/project/Pyro4/
https://github.com/irmen/Pyro4"
SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm64 ppc x86"
IUSE="doc examples test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
test? (
>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
>=dev-python/dill-0.2.6[${PYTHON_USEDEP}]
>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
)"
python_prepare_all() {
# Disable tests requiring network connection.
rm tests/PyroTests/test_naming.py || die
sed \
-e "s/testStartNSfunc/_&/" \
-i tests/PyroTests/test_naming2.py || die
sed \
-e "s/testBroadcast/_&/" \
-e "s/testGetIP/_&/" \
-i tests/PyroTests/test_socket.py || die
distutils-r1_python_prepare_all
}
python_test() {
esetup.py test
}
python_install_all() {
use doc && HTML_DOCS=( docs/. )
if use examples; then
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}