media-gfx/photoqt: add 4.9.1

use tarball from gitlab because photoqt.org has issues with ipv6

new option :
add wayland useflag (dev-libs/wayland)

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Part-of: https://github.com/gentoo/gentoo/pull/41959
Signed-off-by: Sam James <sam@gentoo.org>

media-gfx/photoqt/Manifest

@@ -1 +1,2 @@
 DIST photoqt-4.8.1.tar.gz 5422370 BLAKE2B dba86453107445ebbd4236f8c443c73c6416788ba0355d15be677deae9de1c33a4733ea0233d7d10813a6a0ce61e61eb5be2859b6c771cab2770c1cbd6fa8fa4 SHA512 89cc4b87aad4668fa6f44181b164816736ec21a8151fef96959c9a7a5b050173d385d73bd1615a758974abfde4eed338e348f03fce6c902fa6e1a7ff285279f9
+DIST photoqt-v4.9.1.tar.bz2 5195308 BLAKE2B 5d0d56ba57831a954ae1d3b97daff12c3e333f29b5bc1a4155c641b23011bafef190ea2d8f7c4ca111b33a354485da134bfa6193f0ea9018eaffb5c5e9072669 SHA512 4fcc08f21d7f759100546e2dfc3eaacd72e329eb34df47f545a6c2456e2ed30113f8ca6095fec23057230e70fa0fc45bd8c951b0153f5eadb8d87fa24c94a391

media-gfx/photoqt/photoqt-4.9.1.ebuild

@@ -0,0 +1,109 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit cmake optfeature python-single-r1 xdg
+
+DESCRIPTION="Simple but powerful Qt-based image viewer"
+HOMEPAGE="https://photoqt.org/"
+SRC_URI="https://gitlab.com/lspies/photoqt/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="barcode chromecast devil exif freeimage geolocation graphicsmagick +imagemagick lcms mpv pdf raw test vips wayland"
+REQUIRED_USE="chromecast? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	app-arch/libarchive:=
+	dev-libs/pugixml
+	dev-qt/qtbase:6[concurrent,dbus,gui,icu,network,opengl,sql,sqlite,widgets,xml]
+	dev-qt/qtdeclarative:6[opengl]
+	dev-qt/qtimageformats:6
+	dev-qt/qtmultimedia:6[qml]
+	dev-qt/qtsvg:6
+	barcode? ( media-libs/zxing-cpp:= )
+	chromecast? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep 'dev-python/pychromecast[${PYTHON_USEDEP}]')
+	)
+	devil? ( media-libs/devil )
+	exif? ( media-gfx/exiv2:=[bmff] )
+	freeimage? ( media-libs/freeimage )
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:=[cxx,hdri] )
+		graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
+	)
+	lcms? ( media-libs/lcms:2 )
+	mpv? ( media-video/mpv:=[libmpv] )
+	pdf? ( app-text/poppler[qt6] )
+	raw? ( media-libs/libraw:= )
+	vips? (
+		dev-libs/glib:2
+		media-libs/vips:=
+	)
+	wayland? ( dev-libs/wayland )
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-qt/qtcharts:6[qml]
+	geolocation? (
+		dev-qt/qtlocation:6
+		dev-qt/qtpositioning:6[qml]
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	vips? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	>=kde-frameworks/extra-cmake-modules-6.5.0:*
+	virtual/pkgconfig
+	chromecast? ( ${PYTHON_DEPS} )
+"
+
+pkg_setup() {
+	use chromecast && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_CHROMECAST=$(usex chromecast)
+		-DWITH_DEVIL=$(usex devil)
+		-DWITH_EXIV2=$(usex exif)
+		-DWITH_EXIV2_ENABLE_BMFF=$(usex exif)
+		-DWITH_FREEIMAGE=$(usex freeimage)
+		-DWITH_GRAPHICSMAGICK=$(usex graphicsmagick $(usex imagemagick))
+		-DWITH_IMAGEMAGICK=$(usex imagemagick $(usex !graphicsmagick))
+		-DWITH_LCMS2=$(usex lcms)
+		-DWITH_LOCATION=$(usex geolocation)
+		-DWITH_VIDEO_MPV=$(usex mpv)
+		-DWITH_POPPLER=$(usex pdf)
+		-DWITH_LIBRAW=$(usex raw)
+		-DWITH_RESVG=OFF # qt5 only
+		-DWITH_TESTING=$(usex test)
+		-DWITH_LIBVIPS=$(usex vips)
+		-DWITH_WAYLANDSPECIFIC=$(usex wayland)
+		-DWITH_ZXING=$(usex barcode)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QT_QPA_PLATFORM=offscreen
+	# QCollator::setNumericMode is not supported w/ POSIX/C locale or w/o icu
+	# Set LC_COLLATE=en_US.utf8 if available.
+	# Required for PQCTest::getFoldersIn()
+	unset LC_COLLATE
+	locale -a | grep -iq "en_US.utf8" || die "locale en_US.utf8 not available, testsuite not launched"
+	LC_COLLATE="en_US.utf8" "${BUILD_DIR}"/photoqt_test || die
+}
+
+pkg_postinst() {
+	optfeature "additional image formats like AVIF, EPS, HEIF/HEIC, PSD, etc." "kde-frameworks/kimageformats:6"
+	xdg_pkg_postinst
+}