mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-10 06:57:08 -08:00
sys-apps/fwupd: drop 1.8.16
Signed-off-by: Marek Szuba <marecki@gentoo.org>
This commit is contained in:
Marek Szuba
@@ -1,3 +1,2 @@
|
||||
DIST fwupd-1.8.15.tar.xz 3734344 BLAKE2B 1b098b98b7700e4a9322c53d1c52408e581d124822d1cc7f4a9d25cf3a9169f3596c559f7b9997930e43a9da983fb0c232674726520c9565c250e6db3e4bc0fa SHA512 c7ad249118d84dab903644975761030bcc16d65d9cd4f8d4a58399f79b30a4889cc62d502d28037d61738da7287998328e6042d29c21c5113c29bfc1ba4c0b75
|
||||
DIST fwupd-1.8.16.tar.xz 3735128 BLAKE2B ae72b850f859e5c7cadbe78b86c2d9d0fc7b27f2de5838ab5c1ab7d7adf41d14ab5bfcb7db72795ca90b7626cf19212f3bb61e15e7ecdbd00a9a454aa80523f8 SHA512 25dd773ca703ab6ad11eb042948bb719c2f3974a2e89ac8f9ae524384bce2c8a3d41e5754a5e0ab5595c14720737d53921dbf2859dd33519dcc480d227aac6c6
|
||||
DIST fwupd-1.9.3.tar.xz 3807376 BLAKE2B 2652bc0bb56419bf443476081eb4af2900f24dbf489970bed058f91958902c0fdc301ac163ddc106250a85f3de8fc2a4ca9518d5498efb3793ffbc6ba85fc0cb SHA512 53a3c7e0cebbc8726f07590b26a9d0a4443ff9b048304ed1bff403de532d64eec83b19e51907d39449d9afa78c1f78a139808cdc6249b7e76a1e3a179692acb0
|
||||
|
||||
@@ -1,193 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
|
||||
inherit meson python-single-r1 vala udev xdg
|
||||
|
||||
DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
|
||||
HOMEPAGE="https://fwupd.org"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
|
||||
|
||||
LICENSE="LGPL-2.1+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
|
||||
IUSE="amt +archive bash-completion bluetooth cbor dell elogind fastboot flashrom gnutls gtk-doc +gusb introspection logitech lzma minimal modemmanager nvme policykit spi +sqlite synaptics systemd test tpm uefi"
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}
|
||||
^^ ( elogind minimal systemd )
|
||||
dell? ( uefi )
|
||||
fastboot? ( gusb )
|
||||
logitech? ( gusb )
|
||||
minimal? ( !introspection )
|
||||
modemmanager? ( gusb )
|
||||
spi? ( lzma )
|
||||
synaptics? ( gnutls )
|
||||
test? ( archive gusb )
|
||||
uefi? ( gnutls )
|
||||
"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="$(vala_depend)
|
||||
>=dev-util/meson-0.60.0
|
||||
virtual/pkgconfig
|
||||
gtk-doc? (
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
|
||||
')
|
||||
>=dev-util/gi-docgen-2021.1
|
||||
)
|
||||
bash-completion? ( >=app-shells/bash-completion-2.0 )
|
||||
introspection? ( dev-libs/gobject-introspection )
|
||||
test? (
|
||||
dev-util/umockdev
|
||||
net-libs/gnutls[tools]
|
||||
)
|
||||
"
|
||||
COMMON_DEPEND="${PYTHON_DEPS}
|
||||
>=app-arch/gcab-1.0
|
||||
app-arch/xz-utils
|
||||
>=dev-libs/glib-2.58:2
|
||||
dev-libs/json-glib
|
||||
dev-libs/libgudev:=
|
||||
>=dev-libs/libjcat-0.1.4[gpg,pkcs7]
|
||||
>=dev-libs/libxmlb-0.1.13:=[introspection?]
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
|
||||
')
|
||||
net-misc/curl
|
||||
archive? ( app-arch/libarchive:= )
|
||||
cbor? ( dev-libs/libcbor:= )
|
||||
dell? (
|
||||
>=app-crypt/tpm2-tss-2.0
|
||||
>=sys-libs/libsmbios-2.4.0
|
||||
)
|
||||
elogind? ( >=sys-auth/elogind-211 )
|
||||
flashrom? ( >=sys-apps/flashrom-1.2-r3 )
|
||||
gnutls? ( net-libs/gnutls )
|
||||
gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
|
||||
logitech? ( dev-libs/protobuf-c:= )
|
||||
lzma? ( app-arch/xz-utils )
|
||||
modemmanager? ( net-misc/modemmanager[qmi] )
|
||||
policykit? ( >=sys-auth/polkit-0.114 )
|
||||
sqlite? ( dev-db/sqlite )
|
||||
systemd? ( >=sys-apps/systemd-211 )
|
||||
tpm? ( app-crypt/tpm2-tss:= )
|
||||
uefi? (
|
||||
sys-apps/fwupd-efi
|
||||
sys-boot/efibootmgr
|
||||
sys-fs/udisks
|
||||
sys-libs/efivar
|
||||
)
|
||||
"
|
||||
RDEPEND="
|
||||
${COMMON_DEPEND}
|
||||
sys-apps/dbus
|
||||
"
|
||||
|
||||
DEPEND="
|
||||
${COMMON_DEPEND}
|
||||
x11-libs/pango[introspection]
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-1.8.13-installed_tests.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
vala_setup
|
||||
|
||||
# c.f. https://github.com/fwupd/fwupd/issues/1414
|
||||
sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
|
||||
-i plugins/thunderbolt/meson.build || die
|
||||
|
||||
sed -e "/install_dir.*'doc'/s/doc/gtk-doc/" \
|
||||
-i docs/meson.build || die
|
||||
|
||||
python_fix_shebang "${S}"/contrib/*.py
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local plugins=(
|
||||
-Dplugin_gpio="enabled"
|
||||
$(meson_feature amt plugin_intel_me)
|
||||
$(meson_feature dell plugin_dell)
|
||||
$(meson_feature fastboot plugin_fastboot)
|
||||
$(meson_feature flashrom plugin_flashrom)
|
||||
$(meson_feature gusb plugin_uf2)
|
||||
$(meson_feature logitech plugin_logitech_bulkcontroller)
|
||||
$(meson_feature modemmanager plugin_modem_manager)
|
||||
$(meson_feature nvme plugin_nvme)
|
||||
$(meson_use spi plugin_intel_spi)
|
||||
$(meson_feature synaptics plugin_synaptics_mst)
|
||||
$(meson_feature synaptics plugin_synaptics_rmi)
|
||||
$(meson_feature tpm plugin_tpm)
|
||||
$(meson_feature uefi plugin_uefi_capsule)
|
||||
$(meson_use uefi plugin_uefi_capsule_splash)
|
||||
$(meson_feature uefi plugin_uefi_pk)
|
||||
)
|
||||
if use ppc64 || use riscv ; then
|
||||
plugins+=( -Dplugin_msr="disabled" )
|
||||
fi
|
||||
|
||||
local emesonargs=(
|
||||
--localstatedir "${EPREFIX}"/var
|
||||
-Dbuild="$(usex minimal standalone all)"
|
||||
-Dconsolekit="disabled"
|
||||
-Dcurl="enabled"
|
||||
-Defi_binary="false"
|
||||
-Dman="true"
|
||||
-Dsupported_build="enabled"
|
||||
-Dudevdir="${EPREFIX}$(get_udevdir)"
|
||||
$(meson_feature archive libarchive)
|
||||
$(meson_use bash-completion bash_completion)
|
||||
$(meson_feature bluetooth bluez)
|
||||
$(meson_feature cbor)
|
||||
$(meson_feature elogind)
|
||||
$(meson_feature gnutls)
|
||||
$(meson_feature gtk-doc docs)
|
||||
$(meson_feature gusb)
|
||||
$(meson_feature lzma)
|
||||
$(meson_feature introspection)
|
||||
$(meson_feature policykit polkit)
|
||||
$(meson_feature sqlite)
|
||||
$(meson_feature systemd)
|
||||
$(meson_use test tests)
|
||||
|
||||
${plugins[@]}
|
||||
)
|
||||
use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
|
||||
export CACHE_DIRECTORY="${T}"
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
LC_ALL="C" meson_src_test
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
if ! use minimal ; then
|
||||
newinitd "${FILESDIR}"/${PN}-r2 ${PN}
|
||||
|
||||
if ! use systemd ; then
|
||||
# Don't timeout when fwupd is running (#673140)
|
||||
sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
|
||||
-i "${ED}"/etc/${PN}/daemon.conf || die
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
use minimal || udev_reload
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_pkg_postrm
|
||||
use minimal || udev_reload
|
||||
}
|
||||
Reference in New Issue
Block a user