dev-util/rr: add 5.8.0

Signed-off-by: Sam James <sam@gentoo.org>

dev-util/rr/Manifest

@@ -1 +1,2 @@
 DIST mozilla-rr-5.7.0.tar.gz 1688069 BLAKE2B 613196a441b8c384765403838d4c89248eeb85af203b596ff01610fe65c62650cbeb7f8bde4c97ac4bb65f2bdcf7caa605ca1b6cb2f8f36b0355d816ed39a4f1 SHA512 e0e45f47a5f1de9e0e3f982e9eb5565699189ed23c52de03bf68b8215e7b8ac267619c04495c19e75a55aa8e0face08b9bb6c7f325650384c10a719c17ecf576
+DIST mozilla-rr-5.8.0.tar.gz 1734617 BLAKE2B 75fcd99da89dc4acc033d033abc91ff61500ad1429702641888c628ad0e70f1dfb61309aa76092f34d3314086572a6af334970e5f4abb4d7c812800b23e64869 SHA512 98f0c970fad5c3a2c5d7c17f40c454db072d31053425ffc308a66a643e2f36ede04f33ab8b13f94c42c60a3b00e18a790783467f99a97e421551c498df313a6b

dev-util/rr/rr-5.8.0.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+CMAKE_BUILD_TYPE=Release
+
+inherit cmake linux-info python-single-r1
+
+DESCRIPTION="Record and Replay Framework"
+HOMEPAGE="https://rr-project.org/"
+SRC_URI="https://github.com/rr-debugger/${PN}/archive/${PV}.tar.gz -> mozilla-${P}.tar.gz"
+
+# rr itself is MIT and BSD-2, but there's various bits under third-party too.
+LICENSE="MIT BSD-2 GPL-2 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="multilib test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	dev-libs/capnproto:=
+	sys-libs/zlib:=
+"
+RDEPEND="
+	${DEPEND}
+	dev-debug/gdb[xml]
+"
+# Add all the deps needed only at build/test time.
+DEPEND+="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pexpect[${PYTHON_USEDEP}]
+		')
+		dev-debug/gdb[xml]
+	)"
+
+QA_FLAGS_IGNORED="
+	usr/lib.*/rr/librrpage.so
+	usr/lib.*/rr/librrpage_32.so
+"
+
+RESTRICT="test" # toolchain and kernel version dependent
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.7.0-no-force-lto.patch
+)
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="SECCOMP"
+		linux-info_pkg_setup
+	fi
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -i 's:-Werror::' CMakeLists.txt || die #609192
+}
+
+src_test() {
+	if has usersandbox ${FEATURES} ; then
+		ewarn "Test suite fails under FEATURES=usersandbox (bug #632394). Skipping."
+		return 0
+	fi
+
+	cmake_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+		-Ddisable32bit=$(usex !multilib) #636786
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	python_fix_shebang "${ED}"/usr/bin/rr-collect-symbols.py
+	python_newscript scripts/zen_workaround.py rr-zen_workaround.py
+}