dev-cpp/clucene: fix build w/ cmake 4

Closes: https://bugs.gentoo.org/951882
Signed-off-by: Johannes Huber <johu@gmx.de>
Part-of: https://github.com/gentoo/gentoo/pull/42290
Closes: https://github.com/gentoo/gentoo/pull/42290
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Johannes Huber
2025-05-28 11:04:46 +01:00
committed by Sam James
parent 5880cd4e9f
commit e06df280c7
2 changed files with 79 additions and 0 deletions
@@ -0,0 +1,66 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PN="${PN}"-core
MY_P="${MY_PN}"-"${PV}"
inherit cmake
DESCRIPTION="High-performance, full-featured text search engine based off of lucene in C++"
HOMEPAGE="https://clucene.sourceforge.net"
SRC_URI="https://downloads.sourceforge.net/project/${PN}/${MY_PN}-unstable/$(ver_cut 1-2)/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_PN}-${PV}"
LICENSE="|| ( Apache-2.0 LGPL-2.1 )"
SLOT="1"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="debug doc static-libs"
RESTRICT="test"
BDEPEND="doc? ( >=app-text/doxygen-1.4.2 )"
DOCS=(AUTHORS ChangeLog README README.PACKAGE REQUESTS)
PATCHES=(
"${FILESDIR}/${P}-fix-clang.patch"
"${FILESDIR}/${P}-contrib.patch"
"${FILESDIR}/${P}-pkgconfig.patch"
"${FILESDIR}/${P}-gcc6.patch"
"${FILESDIR}/${P}-gmtime.patch"
"${FILESDIR}/${P}-musl-pthread.patch"
"${FILESDIR}/${P}-libcxx.patch"
"${FILESDIR}/${P}-fix-binary-function.patch"
"${FILESDIR}/${P}-cmake4.patch"
)
src_prepare() {
cmake_src_prepare
# patch out installing bundled boost headers, we build against system one
sed -i \
-e '/ADD_SUBDIRECTORY (src\/ext)/d' \
CMakeLists.txt || die
# don't reference non-existent paths in .pc file (bug #950316)
sed -i \
-e 's%\(:\| -I\)${prefix}/include/CLucene/ext%%g' \
./src/core/libclucene-core.pc.cmake || die
rm -rf src/ext || die
}
src_configure() {
# Disabled threads: see upstream bug
# https://sourceforge.net/p/clucene/bugs/197/
local mycmakeargs=(
-DENABLE_ASCII_MODE=OFF
-DENABLE_PACKAGING=OFF
-DDISABLE_MULTITHREADING=OFF
-DBUILD_CONTRIBS_LIB=ON
-DLIB_DESTINATION="${EPREFIX}/usr/$(get_libdir)"
-DENABLE_DEBUG=$(usex debug)
-DENABLE_CLDOCS=$(usex doc)
-DBUILD_STATIC_LIBRARIES=$(usex static-libs)
)
cmake_src_configure
}
@@ -0,0 +1,13 @@
diff --git a/CMakeLists.txt b/CMakeLists.txt
index 4950ddbd..c98cab8e 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -17,7 +17,7 @@ MATH(EXPR CLUCENE_INT_VERSION "(${CLUCENE_VERSION_MAJOR} * 1000000) + (${CLUCENE
SET(CLUCENE_VERSION "${CLUCENE_VERSION_MAJOR}.${CLUCENE_VERSION_MINOR}.${CLUCENE_VERSION_REVISION}.${CLUCENE_VERSION_PATCH}")
#CMake 2.6+ is recommended to an improved Boost module
-CMAKE_MINIMUM_REQUIRED(VERSION 2.4.0 FATAL_ERROR)
+CMAKE_MINIMUM_REQUIRED(VERSION 3.10.0 FATAL_ERROR)
if(COMMAND cmake_policy)
cmake_policy(SET CMP0003 NEW)