dev-libs/hidapi: add 0.15.0

Closes: https://bugs.gentoo.org/951683
Signed-off-by: Johannes Huber <johu@gmx.de>
Part-of: https://github.com/gentoo/gentoo/pull/42282
Closes: https://github.com/gentoo/gentoo/pull/42282
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/hidapi/Manifest

@@ -1 +1,2 @@
 DIST hidapi-0.14.0.tgz 348221 BLAKE2B 6472bfe5863d75a8901983a763191f3b6c18c25934b652b79f33141a6818619f816d35ed2480435254cecc51598d1e07e53c8c8c4f35a10cf28c1e4374bb450d SHA512 66a045144f90b41438898b82f0398e80223323ebfe6e4f197d2713696bb3ae60f36aea5a37a9999b34b12294783fd7e4c28c6e785462559cbe21276009da1eac
+DIST hidapi-0.15.0.tgz 363838 BLAKE2B 7fc962e1279d61839245d0bcc3dcd5b7876bbf0be1deeb32ef95797ec4c54ef7b5bdf364f8124c967b5f6b2ffd6f49da02dbd730789efef85aabe7bd15da1147 SHA512 a4ddd13a80a84956872fa52aa861b40e4959f301d8d91afe0feaf9dbd87394561e1fdd20cbf8cf47200845f80a8db8a934bc2e3025fe6f16435e37c17621e7b6

dev-libs/hidapi/hidapi-0.15.0.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+DESCRIPTION="A multi-platform library for USB and Bluetooth HID-Class devices"
+HOMEPAGE="https://github.com/libusb/hidapi"
+SRC_URI="https://github.com/libusb/hidapi/archive/${P}.tar.gz -> ${P}.tgz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="|| ( BSD GPL-3 HIDAPI )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc"
+
+DEPEND="
+	virtual/libusb:1[${MULTILIB_USEDEP}]
+	virtual/libudev:0[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( app-text/doxygen )"
+
+multilib_src_configure() {
+	append-lfs-flags
+
+	local mycmakeargs=(
+		# Doesn't do anything as of 0.14.0
+		-DHIDAPI_WITH_TESTS=OFF
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+
+	if use doc && multilib_is_native_abi; then
+		cd "${S}/doxygen" || die
+		doxygen Doxyfile || die
+	fi
+}
+
+multilib_src_install() {
+	cmake_src_install
+
+	if use doc && multilib_is_native_abi; then
+		local HTML_DOCS=( "${S}/doxygen/html/." )
+	fi
+	einstalldocs
+}