net-libs/libwebsockets: add 4.5.4

Signed-off-by: Mike Pagano <mpagano@gentoo.org>
2026-09-17 02:39:08 -07:00 · 2026-03-05 18:24:32 -05:00
parent ecd4879bcf
commit e0661fda9b
2 changed files with 89 additions and 0 deletions
--- a/net-libs/libwebsockets/Manifest
+++ b/net-libs/libwebsockets/Manifest
@@ -1,2 +1,3 @@
 DIST libwebsockets-4.4.1.tar.gz 19997574 BLAKE2B ecc71d595503dd211e6341c84c1fed8adf29b055cbcd7a06fbb0f807d6cfc3814bb0b7df51f78c3f535b6f3dbb8e57b3fdfb6c2b6b706801ef540f6bcaabc207 SHA512 86f85066ce0e9f7f29af5b7c7be803bd19f1a7e6afd8bcdd7c3afc1a66735324317852d7b19bbe9a5af69e759ec532dd28bebffa256f3e1c30ade7ead41a4275
 DIST libwebsockets-4.5.2.tar.gz 20158648 BLAKE2B 1464d2ab9ef0a34085362693d285f559e436b850fc1408ddf5ae9d6a21b6e16876e1eb5cc8507daa90deafeb11fa561aa7b6a16f26eb5ff468146e4dac57d390 SHA512 8427ade9325051b486321b9d0b07b136428ed28f34972a3cc0b0440a9f1efab7b34ee82b6b778eb39669dea08d47976eef04a99f8e15ba03cb6b3c1dc28cb9f9
+DIST libwebsockets-4.5.4.tar.gz 20162918 BLAKE2B 70d1a64326a3743a9b5d2fd872586b27040d96ab05a52c90bbd358a9b01a2d40b81232a426522156071a93fc81d056aa43a301fc6d43cc80cac020002925dc02 SHA512 825cd7a9497b48cb50f7570fcc83a8fcaa8afad2b9653e72cb3eeb58583e4a724024fc06fe9f7a9035bdf233f5741bd8e4e0e5da89c5a0bf37b88515af62ab22
--- a/net-libs/libwebsockets/libwebsockets-4.5.4.ebuild
+++ b/net-libs/libwebsockets/libwebsockets-4.5.4.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/20" # libwebsockets.so.20
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="access-log caps cgi client dbus extensions generic-sessions http-proxy http2 ipv6
+	+lejp libev libevent libuv mbedtls peer-limits server-status smtp socks5
+	sqlite3 ssl threads zip"
+
+REQUIRED_USE="
+	access-log? ( http2 )
+	generic-sessions? ( smtp sqlite3 )
+	http-proxy? ( client )
+	mbedtls? ( ssl )
+	smtp? ( libuv )
+	socks5? ( client http-proxy )
+	?? ( libev libevent )"
+
+RDEPEND="
+	virtual/zlib:=
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	http-proxy? ( net-libs/libhubbub )
+	libev? ( dev-libs/libev )
+	libevent? ( dev-libs/libevent:= )
+	libuv? ( dev-libs/libuv:= )
+	sqlite3? ( dev-db/sqlite:= )
+	ssl? (
+		!mbedtls? ( dev-libs/openssl:0= )
+		mbedtls? ( net-libs/mbedtls:3= )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+		-DDISABLE_WERROR=ON
+		-DLWS_BUILD_HASH="unknown"
+		-DLWS_HAVE_LIBCAP=$(usex caps)
+		-DLWS_IPV6=$(usex ipv6)
+		-DLWS_ROLE_DBUS=$(usex dbus)
+		-DLWS_WITHOUT_CLIENT=$(usex !client)
+		-DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+		-DLWS_WITH_ACCESS_LOG=$(usex access-log)
+		-DLWS_WITH_CGI=$(usex cgi)
+		-DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+		-DLWS_WITH_HTTP2=$(usex http2)
+		-DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+		-DLWS_WITH_HUBBUB=$(usex http-proxy)
+		-DLWS_WITH_LEJP=$(usex lejp)
+		-DLWS_WITH_LIBEV=$(usex libev)
+		-DLWS_WITH_LIBEVENT=$(usex libevent)
+		-DLWS_WITH_LIBUV=$(usex libuv)
+		-DLWS_WITH_MBEDTLS=$(usex mbedtls)
+		-DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+		-DLWS_WITH_SERVER_STATUS=$(usex server-status)
+		-DLWS_WITH_SMTP=$(usex smtp)
+		-DLWS_WITH_SOCKS5=$(usex socks5)
+		-DLWS_WITH_SQLITE3=$(usex sqlite3)
+		-DLWS_WITH_SSL=$(usex ssl)
+		-DLWS_WITH_STATIC=OFF
+		-DLWS_WITH_STRUCT_JSON=$(usex lejp)
+		-DLWS_WITH_THREADPOOL=$(usex threads)
+		-DLWS_WITH_ZIP_FOPS=$(usex zip)
+		-DLWS_WITHOUT_EXTENSIONS=$(usex !extensions)
+		-DLWS_WITHOUT_TESTAPPS=ON
+	)
+	use mbedtls && mycmakeargs+=(
+		-DLWS_MBEDTLS_INCLUDE_DIRS="/usr/include/mbedtls3"
+		-DMBEDTLS_LIBRARY="mbedtls-3.so"
+		-DMBEDX509_LIBRARY="mbedx509-3.so"
+		-DMBEDCRYPTO_LIBRARY="mbedcrypto-3.so"
+	)
+
+	cmake_src_configure
+}