net-misc/exabgp: Version bump to 4.2.17

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

net-misc/exabgp/Manifest

@@ -1,2 +1,3 @@
 DIST exabgp-4.2.11.tar.gz 2931753 BLAKE2B e5241619db24e2e82dfb42bc613d6b2c28efac205d2bedf732a665a5a9eff1b384833cb1fec3e68a285fc01269c2eaca55b311650e59bcda13d8f024e5294dc3 SHA512 61c143e90fd81323b03682ad46f2861576ab0328e2030259eff15bb9ef965477c514fb355112cbaf3dc138fb9f5582b6e1e1efb8d0d4313a9b9924ced156a155
 DIST exabgp-4.2.16.tar.gz 2933071 BLAKE2B bc66ece537cb175811233d26f3445e1bb3f7d4f8950bf0839ced014430db17a4df614661448f275fb3a890bb2af6b2459f938f830c82f03a586829e7fe31caca SHA512 06731612df6f0f6623e8ad58c3b52fc4b5dee6b4bb3bb29cee272a4061ef087e2f98739a75cd07ae51e66fb633069926899882e6bab801010ad1db3333666471
+DIST exabgp-4.2.17.tar.gz 2933104 BLAKE2B 5751888232479c24aa4f66ef357821178c7a5564c0522adb8abf26057eb222ecfbb33caa6d9b71219b79fa309a0c4051b6098015c2362ad9c02e59326ee2bfac SHA512 2000856f540dcaed12dfaf54b689f6b04670f0ec8f19ec7a811ea8e54663afec68a7ae97ed79a001cc09ed42e6a1c5bd2d94ae0c3e3c8bde2da446cf00d66374

net-misc/exabgp/exabgp-4.2.17.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit tmpfiles systemd distutils-r1
+
+DESCRIPTION="The BGP swiss army knife of networking"
+HOMEPAGE="https://github.com/Exa-Networks/exabgp"
+SRC_URI="https://github.com/Exa-Networks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/exabgp
+	acct-user/exabgp
+"
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/exabgp-4.2.7-paths.patch"
+	"${FILESDIR}/exabgp-4.2.10-ip-path.patch"
+	"${FILESDIR}/exabgp-4.2.11-healthcheck-allow-disable-metric.patch"
+	"${FILESDIR}/exabgp-4.2.11-healthcheck-fix-log-crash.patch"
+	"${FILESDIR}/exabgp-4.2.11-less-verbose-logging.patch"
+)
+
+python_test() {
+	./qa/bin/parsing || die "tests fail with ${EPYTHON}"
+	nosetests -v ./qa/tests/*_test.py || die "tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newinitd "${FILESDIR}/${PN}.initd-r2" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+
+	newtmpfiles "${FILESDIR}/exabgp.tmpfiles" ${PN}.conf
+	systemd_dounit etc/systemd/*
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+	keepdir /etc/exabgp
+
+	doman doc/man/*.?
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+}