sci-libs/libsigrokdecode: add 0.6.0_pre20241001

Bug: https://bugs.gentoo.org/948044
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-libs/libsigrokdecode/Manifest

@@ -1 +1,2 @@
 DIST libsigrokdecode-0.5.3.tar.gz 892783 BLAKE2B 45bae2488e4872be3bb891813083ed540617ac88558bb6c2d971fbb0c05585d3fcb74192fc83ce7d67ee466bc04c61fbccf6f475e549b80c86fe5f0cc191c7c1 SHA512 23393504b68135ed4ae8e8a654df024620af02e84fa3955956c61899388812229108155b4ae8d946e61f33dc8a8807db090d608350548a7a717d966442b07b9e
+DIST libsigrokdecode-71f4514.zip 846498 BLAKE2B 5a44a51524ad5c2c476d32bd5dc5eaa8a20f4455d07318b3d388707985c3efde68bd5f9364ecf8faa60b245a8d04d61f2b87e584dc47161c15d8fda34f1996a2 SHA512 0e1fde37dc9579e7eaa4b917e63335d7bd3a9072a33dbc01ae23ebcd5bc0a20e1c30f2e0686e05210a887db4d1cf75a983aad38b8a29d132e7aa1f4c9083370f

sci-libs/libsigrokdecode/libsigrokdecode-0.6.0_pre20241001.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit autotools python-single-r1
+
+case ${PV} in
+*9999*)
+	EGIT_REPO_URI="https://github.com/sigrokproject/${PN}.git"
+	inherit git-r3
+	S="${WORKDIR}"/${P}
+	;;
+*_p*)
+	inherit unpacker
+	COMMIT="71f451443029322d57376214c330b518efd84f88"
+	SRC_URI="https://sigrok.org/gitweb/?p=${PN}.git;a=snapshot;h=${COMMIT};sf=zip -> ${PN}-${COMMIT:0:7}.zip"
+	S="${WORKDIR}"/${PN}-${COMMIT:0:7}
+	;;
+*)
+	SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	S="${WORKDIR}"/${P}
+	;;
+esac
+
+DESCRIPTION="Provide (streaming) protocol decoding functionality"
+HOMEPAGE="https://sigrok.org/wiki/Libsigrokdecode"
+
+LICENSE="GPL-3"
+if [[ ${PV} == *9999* ]]; then
+	SLOT="0/9999"
+else
+	SLOT="0/4"
+	KEYWORDS="~amd64 ~x86"
+fi
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.34.0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+[[ ${PV} == *_p* ]] && BDEPEND+=" app-arch/unzip"
+
+src_unpack() {
+	case ${PV} in
+	*9999*)
+		git-r3_src_unpack ;;
+	*_p*)
+		unpack_zip ${A} ;;
+	esac
+	default
+}
+
+src_prepare() {
+	default
+
+	# bug #794592
+	sed -e "s/\[SRD_PKGLIBS\],\$/& [python-${EPYTHON#python}-embed], [python-${EPYTHON#python}],/" \
+		-i configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf PYTHON3="${PYTHON}"
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	default
+	python_optimize "${D}"/usr/share/libsigrokdecode/decoders
+	find "${D}" -name '*.la' -type f -delete || die
+}