xfce-extra/xfce4-notifyd: Bump to 0.9.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-notifyd/Manifest

@@ -1 +1,2 @@
 DIST xfce4-notifyd-0.8.2.tar.bz2 684013 BLAKE2B ffb5e6ae171db83abeeebd375cbabb73b9a4f0e7d9135593ad2a3bf4c76b2080ce40134922ad1e4d11456166cc9a00cbfda6ee571c0934afc314451153dc6d75 SHA512 8da4bc1f81c1baa91367ba508be87e2bac71180734062cdcb308076acf97a5ccb52382b7e1bd031750253dda6a69882eb92f4679220bb042426092a47eb8c7e0
+DIST xfce4-notifyd-0.9.1.tar.bz2 728342 BLAKE2B 85052d0c1041141a187ee35a51bd348390df9d9b4a9923a4bce3a9c8c8e3e43e38f45542b0ac78ad63b3db124e926b2a5a48e3b1c64a51ac7a3624c41adfb618 SHA512 5bec8a5578a2fc120edb20cf587eb795f86de9da99d20d05bc527356802c23b0d5b07888ae0603624db04e8f94c9ab489333df73c44d57e87aea82e515e18890

xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.1.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Notification daemon for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/apps/notifyd/start
+	https://gitlab.xfce.org/apps/xfce4-notifyd/
+"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="sound wayland X"
+
+DEPEND="
+	>=dev-db/sqlite-3.34:3
+	>=dev-libs/glib-2.68.0:2
+	>=sys-apps/dbus-1.0
+	>=x11-libs/gtk+-3.22:3[wayland?,X?]
+	>=x11-libs/libnotify-0.7
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfce4-panel-4.14.0:=
+	>=xfce-base/xfconf-4.10:=
+	sound? (
+		>=media-libs/libcanberra-0.30[gtk3]
+	)
+	wayland? (
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+
+		# just service files
+		--enable-systemd
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}