media-gfx/eog: bump to 3.23.91

Package-Manager: Portage-2.3.3, Repoman-2.3.1

media-gfx/eog/Manifest

@@ -1 +1,2 @@
 DIST eog-3.20.5.tar.xz 4622880 SHA256 e6e7c5a1aaf2508065e19f0669eb6c1028e8e04c7d3504b9027bd1e009731b3b SHA512 b4256cfe5f42921efd58d7ce09fa2a82d0328e1fe4cd94e953cc161c23b5079d05b89106ec78c670079d0b6ff0f31eeff25d67c259a600dbb4a0afe25b5d93a1 WHIRLPOOL 2d629c11659c356bfae05a6a60f2f424a675a4bc3a2fb02a5a747bbd3aab2e76b8ab64eec9a8a46dad4ac3fd4104abe244578aea25a3dc95c740b353b0f62bcc
+DIST eog-3.23.91.tar.xz 4630232 SHA256 d3b18a7b5b197f9855b04d54618ff6247090ab57a6a2c8422f51d3f36011f8dd SHA512 b2980b3d7cf5e449214e1d6dfe0461640d4d458deb42a7a069462483f8906d3d757cdedf37889c951171ff994c74531fe7b03b1ddc05aac4a02df2a0980a48c9 WHIRLPOOL da9001b6ed25665274cbc819334882b14100343a7508b7213c14013ad9140ebe405f7e3eaf37f4f00351c3e44ea01338901293e7686bc718d179984cdf490afa

media-gfx/eog/eog-3.23.91.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="debug +exif +introspection +jpeg lcms +svg tiff xmp"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+RDEPEND="
+	>=dev-libs/glib-2.42.0:2[dbus]
+	>=dev-libs/libpeas-0.7.4:=[gtk]
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=x11-libs/gtk+-3.22.0:3[introspection,X]
+	>=x11-misc/shared-mime-info-0.20
+
+	>=x11-libs/gdk-pixbuf-2.30.0:2[jpeg?,tiff?]
+	x11-libs/libX11
+
+	exif? ( >=media-libs/libexif-0.6.14 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	svg? ( >=gnome-base/librsvg-2.36.2:2 )
+	xmp? ( media-libs/exempi:2 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.16
+	>=dev-util/intltool-0.50.1
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	gnome2_src_configure \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable introspection) \
+		$(use_with jpeg libjpeg) \
+		$(use_with exif libexif) \
+		$(use_with lcms cms) \
+		$(use_with xmp) \
+		$(use_with svg librsvg)
+}