net-libs/libtorrent-rasterbar: Version bump (v1.1.14)

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

net-libs/libtorrent-rasterbar/Manifest

@@ -1,2 +1,3 @@
 DIST libtorrent-rasterbar-1.1.13.tar.gz 3896007 BLAKE2B b94f843437be348b10082f19d0b416f909daf15078b1461ab6724ee086d3194f6c378c305174676a3399fc3e6cb23133faaa334ac5dfc9457fb597c65dad7d36 SHA512 021fc54353fdf5063d55ccdc2057dada292bb0008fb92e93e8d94dd89f529630f290fcdc4f4d095e3192522c57fe0f0da260b5ef8e8e15a8c6ac05728f5f7160
+DIST libtorrent-rasterbar-1.1.14.tar.gz 4040571 BLAKE2B 38ea1a71e46bf18c9beeb869280e4949b199ab58c32f41e63f1c15c7c32db0d256b741ea707350e9e153695b9cc28e0a95385944bf76dbd5eb2055e66bb0f919 SHA512 b640ada016f8e68a3fb0e033dd33ab79b345b0f691aa722c4256b8cd8524c6e55067ccd1f11584984bbb82c0f64151f0b5223bd2b8431b899ffca46d2d31fff5
 DIST libtorrent-rasterbar-1.2.3.tar.gz 3591081 BLAKE2B 9766a21c948997b35c6d209940a2d2cfd76b130f1a9d1f611e07d3eeb27f634a3c5eca12c92261139200084b9678913d85f6a56f98ab6894e5def761615c39ad SHA512 11a81c9f4b968ed360740553f8d856a2fad4eb2f6962f6403394e0a4a6b198ef6f04ce92d11fc6bed9aa979c84efd03fb396027dfe6603f394104b4302e04d82

net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.1.14.ebuild

@@ -0,0 +1,106 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+PYTHON_REQ_USE="threads"
+DISTUTILS_OPTIONAL=true
+DISTUTILS_IN_SOURCE_BUILD=true
+
+inherit distutils-r1 flag-o-matic
+
+MY_PV=$(ver_rs 1-2 '_')
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="https://libtorrent.org"
+SRC_URI="https://github.com/arvidn/libtorrent/releases/download/libtorrent-${MY_PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/9"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug +dht doc examples libressl python +ssl static-libs test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=[threads]
+	virtual/libiconv
+	examples? ( !net-p2p/mldonkey )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+"
+
+src_prepare() {
+	default
+
+	# bug 578026
+	# prepend -L${S}/... to ensure bindings link against the lib we just built
+	sed -i -e "s|^|-L${S}/src/.libs |" bindings/python/link_flags.in || die
+
+	# prepend -I${S}/... to ensure bindings use the right headers
+	sed -i -e "s|^|-I${S}/src/include |" bindings/python/compile_flags.in || die
+
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	append-cxxflags -std=c++11 # bug 634506
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug disk-stats)
+		$(use_enable debug logging)
+		$(use_enable dht)
+		$(use_enable examples)
+		$(use_enable ssl encryption)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		--with-libiconv
+	)
+	econf "${myeconfargs[@]}"
+
+	if use python; then
+		python_configure() {
+			econf "${myeconfargs[@]}" \
+				--enable-python-binding \
+				--with-boost-python="boost_${EPYTHON/./}"
+		}
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	default
+
+	python_compile() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_compile
+	}
+	use python && distutils-r1_src_compile
+}
+
+src_install() {
+	use doc && HTML_DOCS+=( "${S}"/docs )
+
+	default
+
+	python_install() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_install
+	}
+	use python && distutils-r1_src_install
+
+	find "${D}" -name '*.la' -delete || die
+}