dev-util/pkgcheck: add 0.10.13

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin
2022-08-15 22:05:58 +03:00
parent d8f9916fe7
commit dfe82dcfc3
2 changed files with 99 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST pkgcheck-0.10.11.tar.gz 474106 BLAKE2B 2a3e330d54e421a48e5cd89044b9af37334bf461f47487b8dd62e7fd1c766d162766d0a6c1319c50c3fd6965b56377536743903c265782b2fbef050d4f805d3a SHA512 b47814822599417d0f7030ac444fd4b2bab1f1bea21abc2a4fe1dd679185afd7d5f823aefff1b6830036de5c7db6232c0b6fc6d33f9c2535d88a711e6d49132c
DIST pkgcheck-0.10.12.tar.gz 477880 BLAKE2B 9d71e6d3312f2c11a722f12c854a14523174b91ca1cf8ea89f6da3463e8aeab1744b083a31eca675e40069b57f4b2b24a83efa0d692d90cd00b9e9c4ec452a02 SHA512 e146dd0533b769078102ff27f90120c459ceb614aed4365a43a36e1a24d1230890c9da7a756b3fcce528806ca1fca10d8d8c283dcc464a7c98368bac0d98a26f
DIST pkgcheck-0.10.13.tar.gz 490572 BLAKE2B 4ca1bf820e45819fa48173ee7a8a2accefe4701b4b79dddc601b66c9c5d51f90cb5e65b7702f22c6082ec481f5bd69ff9cf6299cd9e0dcca05b82c2a1002ae78 SHA512 3be0f16607b2ed52d985a568058ed2fe3bc2d0d96719245a8b708a69c16d5b9dca12485f9c343909c0c88a13f9ee5b2d7126778222a8477bd17f396d84399fd4
+98
View File
@@ -0,0 +1,98 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
DISTUTILS_IN_SOURCE_BUILD=1
inherit elisp-common distutils-r1 optfeature
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://github.com/pkgcore/pkgcheck.git"
inherit git-r3
else
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
fi
DESCRIPTION="pkgcore-based QA utility for ebuild repos"
HOMEPAGE="https://github.com/pkgcore/pkgcheck"
LICENSE="BSD MIT"
SLOT="0"
IUSE="emacs"
if [[ ${PV} == *9999 ]]; then
RDEPEND="
~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
else
RDEPEND="
>=dev-python/snakeoil-0.9.12[${PYTHON_USEDEP}]
>=sys-apps/pkgcore-0.12.13[${PYTHON_USEDEP}]"
fi
RDEPEND+="
dev-libs/tree-sitter
dev-libs/tree-sitter-bash
dev-python/chardet[${PYTHON_USEDEP}]
dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/pathspec[${PYTHON_USEDEP}]
>=dev-python/tree-sitter-0.19.0[${PYTHON_USEDEP}]
emacs? (
>=app-editors/emacs-24.1:*
app-emacs/ebuild-mode
app-emacs/flycheck
)
"
BDEPEND="
${RDEPEND}
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-vcs/git
)
"
SITEFILE="50${PN}-gentoo.el"
distutils_enable_tests setup.py
export USE_SYSTEM_TREE_SITTER_BASH=1
src_compile() {
distutils-r1_src_compile
if use emacs ; then
pushd "${S}"/contrib/emacs >/dev/null || die
elisp-compile *.el
popd >/dev/null || die
fi
}
src_test() {
local -x PYTHONDONTWRITEBYTECODE=
distutils-r1_src_test
}
python_install_all() {
local DOCS=( NEWS.rst )
[[ ${PV} == *9999 ]] || doman man/*
distutils-r1_python_install_all
if use emacs ; then
elisp-install ${PN} "${S}"/contrib/emacs/*.el{,c}
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
fi
}
pkg_postinst() {
use emacs && elisp-site-regen
optfeature "Network check support" dev-python/requests
optfeature "Perl module version check support" dev-perl/Gentoo-PerlMod-Version
}
pkg_postrm() {
use emacs && elisp-site-regen
}