mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-05 12:38:09 -07:00
x11-wm/mutter: drop 44.4
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
This commit is contained in:
Mart Raudsepp
@@ -1,4 +1,3 @@
|
||||
DIST mutter-44.4.tar.xz 2847392 BLAKE2B 2ecdb0d447c0426a7e02f4d3b3cdf8936a6c7a5fecad163bdba9428f018e0ceb2047b241422bc9de5e9d0fb08e88a04d572d1b404b48d6df214a7263292309ba SHA512 3f7b37be5531e270c071fc9784a6a284a3d715dfd1dfc854779126197d6e53c660836412ba08e6233747c7b016926114a57be5adb36a11c8ec9c81e333ce668c
|
||||
DIST mutter-45.2-r1-patchset.tar.xz 21864 BLAKE2B c09566f75a816f6599ac4bf99879cc0e3bb78220c56cc4bd64edabf00e533a5feb4decdaa75ef5ae7ade911ec266ba6dd4641f1cbcd2c3145c10d5a8d327d653 SHA512 dd953afb97c4cdd9e24b2eab6636472e526042eb768c23e0d5bd49cd3ceb3a5cebd3ff396d014bdf168de81f810cef754efbb1739350fc09f6d196461de41ea4
|
||||
DIST mutter-45.2.tar.xz 2884940 BLAKE2B c4107840b8bd0f75a9c76300f324bfff6aac3195f526ab88102c831df693cb8dfa5b55bb1590a54e68f41eab392e69bb833221480578a2fba4b1e4bdc5ed030d SHA512 2111ad0645d2da58dedb30d94e99b52045f38b31a9de7314a5d8b41a5525612d88d2fbaafd3658eb6f734c143ad12176367c26533237199d9a5c1ad3dea743c7
|
||||
DIST mutter-45.4.tar.xz 2886300 BLAKE2B 62fe0c08e92f8cab0bcf64a52a9d1bdf16754deae5fb00018f29c596ab2e26a5b75eee46f1c0206ae1773fe5b7ed48abc755b6070d35dc22536dcb11e8955e95 SHA512 3fdd44dfcb504a84d402065987fb8bdec84d639260c66c0cb2e88ef2deb56fadf2ae91bdeae782793728e54803a455ab38943b68693124d728b0c52ba8698e3c
|
||||
|
||||
@@ -1,235 +0,0 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
PYTHON_COMPAT=( python3_{10..11} )
|
||||
inherit gnome.org gnome2-utils meson python-any-r1 udev xdg
|
||||
|
||||
DESCRIPTION="GNOME compositing window manager based on Clutter"
|
||||
HOMEPAGE="https://gitlab.gnome.org/GNOME/mutter/"
|
||||
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/mutter.git"
|
||||
SRC_URI=""
|
||||
else
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
|
||||
fi
|
||||
|
||||
LICENSE="GPL-2+"
|
||||
SLOT="0/$(($(ver_cut 1) - 32))" # 0/libmutter_api_version - ONLY gnome-shell (or anything using mutter-clutter-<api_version>.pc) should use the subslot
|
||||
|
||||
IUSE="debug elogind gnome gtk-doc input_devices_wacom +introspection screencast sysprof systemd test udev wayland video_cards_nvidia"
|
||||
# native backend requires gles3 for hybrid graphics blitting support, udev and a logind provider
|
||||
REQUIRED_USE="
|
||||
gtk-doc? ( introspection )
|
||||
wayland? ( ^^ ( elogind systemd ) udev )
|
||||
test? ( wayland )"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
# gnome-settings-daemon is build checked, but used at runtime only for org.gnome.settings-daemon.peripherals.keyboard gschema
|
||||
# xorg-server is needed at build and runtime with USE=wayland for Xwayland
|
||||
# v3.32.2 has many excessive or unused *_req variables declared, thus currently the dep order ignores those and goes via dependency() call order
|
||||
DEPEND="
|
||||
>=media-libs/graphene-1.10.2[introspection?]
|
||||
x11-libs/gdk-pixbuf:2
|
||||
>=x11-libs/pango-1.46[introspection?]
|
||||
>=x11-libs/cairo-1.14[X]
|
||||
>=dev-libs/fribidi-1.0.0
|
||||
>=gnome-base/gsettings-desktop-schemas-42.0[introspection?]
|
||||
>=dev-libs/glib-2.75.1:2
|
||||
gnome-base/gnome-settings-daemon
|
||||
>=dev-libs/json-glib-0.12.0[introspection?]
|
||||
>=x11-libs/libxkbcommon-0.4.3
|
||||
x11-libs/libICE
|
||||
>=app-accessibility/at-spi2-core-2.46:2[introspection?]
|
||||
sys-apps/dbus
|
||||
>=x11-misc/colord-1.4.5:=
|
||||
>=media-libs/lcms-2.6:2
|
||||
>=media-libs/harfbuzz-2.6.0:=
|
||||
|
||||
gnome? ( gnome-base/gnome-desktop:4= )
|
||||
|
||||
>=media-libs/libcanberra-0.26
|
||||
|
||||
media-libs/libglvnd[X]
|
||||
|
||||
wayland? (
|
||||
>=dev-libs/wayland-protocols-1.31
|
||||
>=dev-libs/wayland-1.21.0
|
||||
|
||||
x11-libs/libdrm
|
||||
media-libs/mesa[gbm(+)]
|
||||
>=dev-libs/libinput-1.18.0:=
|
||||
|
||||
elogind? ( sys-auth/elogind )
|
||||
x11-base/xwayland
|
||||
video_cards_nvidia? ( gui-libs/egl-wayland )
|
||||
)
|
||||
udev? (
|
||||
>=virtual/libudev-232-r1:=
|
||||
>=dev-libs/libgudev-232
|
||||
)
|
||||
systemd? ( sys-apps/systemd )
|
||||
x11-libs/libSM
|
||||
input_devices_wacom? ( >=dev-libs/libwacom-0.13:= )
|
||||
>=x11-libs/startup-notification-0.7
|
||||
screencast? ( >=media-video/pipewire-0.3.21:= )
|
||||
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
|
||||
test? ( >=x11-libs/gtk+-3.19.8:3[X,introspection?] )
|
||||
sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 >=dev-util/sysprof-3.46.0 )
|
||||
"
|
||||
# for now upstream has "have_x11 = true" in the meson.build, but sooner or later upstream is going to make X optional.
|
||||
# X? (
|
||||
DEPEND+="
|
||||
>=gui-libs/gtk-4.0.0:4[X,introspection?]
|
||||
>=x11-libs/libX11-1.7.0
|
||||
>=x11-libs/libXcomposite-0.4
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
>=x11-libs/libXfixes-3
|
||||
>=x11-libs/libXi-1.7.4
|
||||
x11-libs/libXtst
|
||||
x11-libs/libxkbfile
|
||||
x11-misc/xkeyboard-config
|
||||
>=x11-libs/libxkbcommon-0.4.3[X]
|
||||
x11-libs/libXrender
|
||||
>=x11-libs/libXrandr-1.5.0
|
||||
x11-libs/libxcb:=
|
||||
x11-libs/libXinerama
|
||||
x11-libs/libXau
|
||||
"
|
||||
# )"
|
||||
|
||||
RDEPEND="${DEPEND}
|
||||
gnome-extra/zenity
|
||||
|
||||
!<gui-libs/gtk-4.6.4:4
|
||||
"
|
||||
DEPEND="${DEPEND}
|
||||
x11-base/xorg-proto
|
||||
sysprof? ( >=dev-util/sysprof-common-3.38.0 )
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/wayland-scanner
|
||||
dev-util/gdbus-codegen
|
||||
dev-util/glib-utils
|
||||
>=sys-devel/gettext-0.19.8
|
||||
virtual/pkgconfig
|
||||
gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
|
||||
test? (
|
||||
${PYTHON_DEPS}
|
||||
$(python_gen_any_dep '
|
||||
>=dev-python/python-dbusmock-0.28[${PYTHON_USEDEP}]
|
||||
')
|
||||
app-text/docbook-xml-dtd:4.5
|
||||
x11-misc/xvfb-run
|
||||
)
|
||||
wayland? (
|
||||
>=sys-kernel/linux-headers-4.4
|
||||
x11-libs/libxcvt
|
||||
)
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-43.0-Disable-anonymous-file-test.patch
|
||||
|
||||
)
|
||||
|
||||
python_check_deps() {
|
||||
if use test; then
|
||||
python_has_version ">=dev-python/python-dbusmock-0.28[${PYTHON_USEDEP}]"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
sed -i -e "s:#!/usr/bin/bash:#!$(command -v bash):" src/tests/x11-test.sh || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
# Mutter X11 renderer only supports gles2 and GLX, thus do NOT pass
|
||||
#
|
||||
# -Dopengl_libname=libOpenGL.so.0
|
||||
#
|
||||
# while we build the x11 renderer, as we currently enable gles2 only
|
||||
# with USE=wayland and x11 renderer wouldn't find the needed GLX symbols
|
||||
# in a configuration where wayland is disabled, as libOpenGL doesn't
|
||||
# include them.
|
||||
#
|
||||
# See
|
||||
# - https://bugs.gentoo.org/835786
|
||||
# - https://forums.gentoo.org/viewtopic-p-8695669.html
|
||||
|
||||
-Dbuildtype=$(usex debug debug plain)
|
||||
-Dopengl=true
|
||||
$(meson_use wayland gles2)
|
||||
#gles2_libname
|
||||
-Degl=true
|
||||
-Dglx=true
|
||||
$(meson_use wayland)
|
||||
$(meson_use wayland xwayland)
|
||||
$(meson_use systemd)
|
||||
$(meson_use wayland native_backend)
|
||||
$(meson_use screencast remote_desktop)
|
||||
$(meson_use gnome libgnome_desktop)
|
||||
$(meson_use udev)
|
||||
-Dudev_dir=$(get_udevdir)
|
||||
$(meson_use input_devices_wacom libwacom)
|
||||
-Dsound_player=true
|
||||
-Dpango_ft2=true
|
||||
-Dstartup_notification=true
|
||||
-Dsm=true
|
||||
$(meson_use introspection)
|
||||
$(meson_use gtk-doc docs)
|
||||
$(meson_use test cogl_tests)
|
||||
$(meson_use wayland core_tests) # core tests require wayland; overall -Dtests option is honored on top, so no extra conditional needed
|
||||
-Dnative_tests=false
|
||||
$(meson_use test clutter_tests)
|
||||
$(meson_use test tests)
|
||||
-Dkvm_tests=false
|
||||
-Dtty_tests=false
|
||||
$(meson_use sysprof profiler)
|
||||
-Dinstalled_tests=false
|
||||
|
||||
#verbose # Let upstream choose default for verbose mode
|
||||
#xwayland_path
|
||||
# TODO: relies on default settings, but in Gentoo we might have some more packages we want to give Xgrab access (mostly virtual managers and remote desktops)
|
||||
#xwayland_grab_default_access_rules
|
||||
)
|
||||
|
||||
if use wayland && use video_cards_nvidia; then
|
||||
emesonargs+=(
|
||||
-Degl_device=true
|
||||
-Dwayland_eglstream=true
|
||||
)
|
||||
else
|
||||
emesonargs+=(
|
||||
-Degl_device=false
|
||||
-Dwayland_eglstream=false
|
||||
)
|
||||
fi
|
||||
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
gnome2_environment_reset # Avoid dconf that looks at XDG_DATA_DIRS, which can sandbox fail if flatpak is installed
|
||||
glib-compile-schemas "${BUILD_DIR}"/data
|
||||
GSETTINGS_SCHEMA_DIR="${BUILD_DIR}"/data meson_src_test --setup=CI
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use udev && udev_reload
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use udev && udev_reload
|
||||
xdg_pkg_postrm
|
||||
gnome2_schemas_update
|
||||
}
|
||||
Reference in New Issue
Block a user