dev-libs/libmirage: Bump to 3.3.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-libs/libmirage/Manifest

@@ -1 +1,2 @@
 DIST libmirage-3.3.2.tar.xz 274492 BLAKE2B e2abd9497e48649939b990a60fc11f79002fd67160c42f8d729ac74a4fdf657437133f338db9e7f3311b35d7da1197152348a9c84c8fac07760b8bccd1bc4d04 SHA512 e9cc7e97d2271159a26fda92dda8197a518608dce1d467ca081edc6aa28bf669dcb783abfaaab1d2ec4c58e3cc20608bbbe31459db23ccd6106a11c147aa92ce
+DIST libmirage-3.3.3.tar.xz 274956 BLAKE2B b095b4e208da80de810fad4c39ac05f36ce9e77937b0faf3df68e7b093da1252c32b078235d1d5f4c2143d22dbb379228ad0d528316ceba6ec45b92d119eac18 SHA512 52cc4d07356926f6a5791d86d32971ebdbb9aff5e1ff62c6a2ec22cf3a3428775857485cdefff3c9220bf647d1250780cb7b10862fbaa7fe7bb3b7a71f38b9e7

dev-libs/libmirage/libmirage-3.3.3.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="CD and DVD image access library"
+HOMEPAGE="https://cdemu.sourceforge.io"
+SRC_URI="https://download.sourceforge.net/cdemu/libmirage/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0/12"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt doc +introspection"
+
+DEPEND="
+	>=app-arch/bzip2-1:=
+	>=app-arch/xz-utils-5:=
+	>=dev-libs/glib-2.38:2
+	>=media-libs/libchdr-0.2:=
+	>=media-libs/libsamplerate-0.1:=
+	>=media-libs/libsndfile-1.0:=
+	virtual/zlib:=
+	crypt? ( dev-libs/libgcrypt:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
+"
+
+DOCS=( AUTHORS README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DGTKDOC_ENABLED="$(usex doc)"
+		-DINTROSPECTION_ENABLED="$(usex introspection)"
+		-DPOST_INSTALL_HOOKS=OFF # avoid sandbox violation, #487304
+		-DLIBGCRYPT_ENABLED=$(usex crypt)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}