games-puzzle/angrydd: EAPI7->8, revamp ebuild, enable py3.10

Updated deps for pygame-2 (sdl2-image[png] + sdl2-mixer[vorbis])

Also remove HOMEPAGE, 404 with no replacement found.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

games-puzzle/angrydd/angrydd-1.0.1_p13-r1.ebuild

@@ -1,56 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{8,9} )
-
-inherit desktop python-single-r1
-
-DESCRIPTION="Angry, Drunken Dwarves, a falling blocks game similar to Puzzle Fighter"
-HOMEPAGE="https://www.sacredchao.net/~piman/angrydd/"
-SRC_URI="
-	https://www.sacredchao.net/~piman/angrydd/${P/_p*}.tar.gz
-	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV/_p*}-${PV/*_p}.debian.tar.xz
-"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-IUSE=""
-REQUIRED_USE=${PYTHON_REQUIRED_USE}
-
-RDEPEND="${PYTHON_DEPS}
-	$(python_gen_cond_dep '
-		dev-python/pygame[${PYTHON_USEDEP}]
-	')
-"
-DEPEND="${RDEPEND}"
-BDEPEND=""
-
-S="${WORKDIR}/${P/_p*}"
-
-src_prepare() {
-	default
-	eapply -p1 "${WORKDIR}"/debian/patches/*.patch
-	python_fix_shebang .
-}
-
-src_install() {
-	emake \
-		DESTDIR="${D}" \
-		PREFIX="/usr/share/" \
-		TO="${PN}" \
-		install
-	rm -rf "${ED}/usr/share/games" "${ED}/usr/share/share" || die
-
-	python_optimize "${ED}/usr/share/${PN}"
-
-	dodir /usr/bin
-	dosym "../share/${PN}/angrydd.py" "/usr/bin/${PN}"
-	doman angrydd.6
-	dodoc README TODO HACKING
-
-	doicon angrydd.png
-	make_desktop_entry angrydd "Angry, Drunken Dwarves"
-}

games-puzzle/angrydd/angrydd-1.0.1_p13-r2.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit desktop python-single-r1
+
+DESCRIPTION="Angry, Drunken Dwarves, a falling blocks game similar to Puzzle Fighter"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="
+	mirror://gentoo/${P/_p*}.tar.gz
+	mirror://debian/pool/main/${P::1}/${PN}/${PN}_${PV/_p*}-${PV/*_p}.debian.tar.xz"
+S="${WORKDIR}/${P/_p*}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/pygame[${PYTHON_USEDEP}]')
+	media-libs/sdl2-image[png]
+	media-libs/sdl2-mixer[vorbis]"
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${WORKDIR}"/debian/patches
+)
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr/share TO=${PN} install
+
+	dosym -r /usr/share/${PN}/${PN}.py /usr/bin/${PN}
+	doman angrydd.6
+	einstalldocs
+
+	python_fix_shebang "${ED}"/usr/share/${PN}
+	python_optimize "${ED}"/usr/share/${PN}
+
+	doicon ${PN}.png
+	make_desktop_entry ${PN} "Angry, Drunken Dwarves"
+
+	rm -r "${ED}"/usr/share/{games,share} || die
+}