mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
sys-libs/glibc: Revision bump to patchlevel 10
Only additional fixes for arm64 and hppa included. Package-Manager: Portage-2.3.11, Repoman-2.3.3
This commit is contained in:
Andreas K. Hüttel
@@ -16,6 +16,7 @@ DIST glibc-2.23-patches-8.tar.bz2 304199 SHA256 6110777176abfb8d287d82804d98e007
|
||||
DIST glibc-2.23.tar.xz 13455260 SHA256 94efeb00e4603c8546209cefb3e1a50a5315c86fa9b078b6fad758e187ce13e9 SHA512 b82953388cd028e174cb08f082557bbce0dad8b67b17d31b29f90102fd52a51e03d591448ecb64882a1c1d5303afffc7f6ede85cee4c784a9284fbc9b4ad26cf WHIRLPOOL 7c7e3bf55a89a04bac917b9ca5a1cbb1613f22c427d2766f114b5a36f9635856005b823852ef5d3b73462b577fe4e5865e68e7b64633d48a95fa1e5eaa831a71
|
||||
DIST glibc-2.24-patches-10.tar.bz2 73586 SHA256 d479033b63ff796fea56fb1bde390c442021acd856994b15c983b4a89e46fbbe SHA512 fc9191a85da53a2515bbaab228648936682e04267284049468e0c82284f618ab2907b9247baca701e16edc50640199ff6d8e2a6a93ccbd5a9d3b0eb73cc484ca WHIRLPOOL 7afe94307900a70de2f5e028d8ec9e0f4b06b661ec6493217e51a13d750f891e10b45c0f66d86fa83c16cc3ce539bb257039b33bc3e363469cd03502d956d75e
|
||||
DIST glibc-2.24.tar.xz 13554048 SHA256 99d4a3e8efd144d71488e478f62587578c0f4e1fa0b4eed47ee3d4975ebeb5d3 SHA512 a4cb28a2c51a0cc029ed69da7cba11931a615ba897235590b4f7fad2eaabec9042f8250eaac2a5860997437a69ab13304f10a634000e52c0336b5593b7969adb WHIRLPOOL be82b47fc73f7e780e8e73a5f58b313d8e861d5ea8c4320f95ef0d8c1e125ff011d61dcfc0380be0e83868bd8c3299de1ea662da7fc8d709050e89b2c126e3eb
|
||||
DIST glibc-2.25-patches-10.tar.bz2 63495 SHA256 e406fb1d3aad7996773e5f67dc30ec57cc19bf486c70d9a37d306aaa39c641f7 SHA512 c325bede04eb3a2ec08290a905f8897b19155fc77e709531fb96db0c34e1f93ab12fd72af14ed447bd25e35b8006389324cfad283c7bebe19ffbd4a2ca4b01ff WHIRLPOOL 83ba1afaf8615dc54a4668f388f887ef26bf184b6e55ea13570717a77b7ef2028728f3f6f69775d76e371aa930fd2e44f6fc3602bdbfee6acfc563da8dd4bc06
|
||||
DIST glibc-2.25-patches-8.tar.bz2 47110 SHA256 1dc41664153369886d240a1851b15bf0c3c3739c8319e6d68cb0c2f85fc98901 SHA512 41d772c47770a63502c863f3c9bb05164e0ceab69fb7b7f355c25685ae4285d73e9ab0e3836162bd11852339055329d0bdc7238f3191fde39a50ce0d9a60454c WHIRLPOOL c6e0443d75e2e4607226caa4df1ce2b10ef21ec2564b447e2a287888d1f593d51f334a6e1ab942f5d1602d02c6fee87ce4ef9a7db3409de6063bc377a470a42d
|
||||
DIST glibc-2.25-patches-9.tar.bz2 67901 SHA256 cbd8af837aa0776940fd41e34874e930a7f25d78cdd212e138dd9a85e1349519 SHA512 b4f0be5b20834aff102394df23084cc0adf1ab674e6ce050550f6b6658cf0eab57f7685cac079b1a19388dba927a36b8ca31f58af3dddc559d7230674ffd59b5 WHIRLPOOL 81c18056fe26a79c7a7598da1181ba02e83daf7d9e9883a3c1195804a35fe22a79d7cc4a8411f2f4a4ce6430e506978199f59b61d3ed0a70b4e4f7dd05ecfafe
|
||||
DIST glibc-2.25.tar.xz 13873900 SHA256 067bd9bb3390e79aa45911537d13c3721f1d9d3769931a30c2681bfee66f23a0 SHA512 5b7a2418d5b8a1b6a907c6c7fb6477ee2a473151cb45e03d0d4cdd9a33497c90b1ee39e2e7e885e2b25743dcd3747336ef114b4a73eb001da1fd79f29e0f9a6e WHIRLPOOL dc2fafaa4a0e5581268338453838a03ed0c5e7a2af844e8fb7086ab8d3ae48efbdbe6f25db1d089ae669cd2f8b0412f690d965506753d86f8525da2df59b7953
|
||||
|
||||
151
sys-libs/glibc/glibc-2.25-r6.ebuild
Normal file
151
sys-libs/glibc/glibc-2.25-r6.ebuild
Normal file
@@ -0,0 +1,151 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="5"
|
||||
|
||||
inherit toolchain-glibc
|
||||
|
||||
DESCRIPTION="GNU libc6 (also called glibc2) C library"
|
||||
HOMEPAGE="https://www.gnu.org/software/libc/libc.html"
|
||||
|
||||
LICENSE="LGPL-2.1+ BSD HPND ISC inner-net rc PCRE"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
|
||||
RESTRICT="strip" # strip ourself #46186
|
||||
EMULTILIB_PKG="true"
|
||||
|
||||
# Configuration variables
|
||||
RELEASE_VER=""
|
||||
case ${PV} in
|
||||
9999*)
|
||||
EGIT_REPO_URIS="git://sourceware.org/git/glibc.git"
|
||||
EGIT_SOURCEDIRS="${S}"
|
||||
inherit git-2
|
||||
;;
|
||||
*)
|
||||
RELEASE_VER=${PV}
|
||||
;;
|
||||
esac
|
||||
GCC_BOOTSTRAP_VER="4.7.3-r1"
|
||||
# patches live at https://sources.gentoo.org/cgi-bin/viewvc.cgi/gentoo/src/patchsets/glibc/
|
||||
PATCH_VER="10" # Gentoo patchset
|
||||
: ${NPTL_KERN_VER:="2.6.32"} # min kernel version nptl requires
|
||||
|
||||
IUSE="audit caps debug gd hardened multilib nscd +rpc selinux systemtap profile suid vanilla crosscompile_opts_headers-only"
|
||||
|
||||
# Here's how the cross-compile logic breaks down ...
|
||||
# CTARGET - machine that will target the binaries
|
||||
# CHOST - machine that will host the binaries
|
||||
# CBUILD - machine that will build the binaries
|
||||
# If CTARGET != CHOST, it means you want a libc for cross-compiling.
|
||||
# If CHOST != CBUILD, it means you want to cross-compile the libc.
|
||||
# CBUILD = CHOST = CTARGET - native build/install
|
||||
# CBUILD != (CHOST = CTARGET) - cross-compile a native build
|
||||
# (CBUILD = CHOST) != CTARGET - libc for cross-compiler
|
||||
# CBUILD != CHOST != CTARGET - cross-compile a libc for a cross-compiler
|
||||
# For install paths:
|
||||
# CHOST = CTARGET - install into /
|
||||
# CHOST != CTARGET - install into /usr/CTARGET/
|
||||
|
||||
export CBUILD=${CBUILD:-${CHOST}}
|
||||
export CTARGET=${CTARGET:-${CHOST}}
|
||||
if [[ ${CTARGET} == ${CHOST} ]] ; then
|
||||
if [[ ${CATEGORY} == cross-* ]] ; then
|
||||
export CTARGET=${CATEGORY#cross-}
|
||||
fi
|
||||
fi
|
||||
|
||||
is_crosscompile() {
|
||||
[[ ${CHOST} != ${CTARGET} ]]
|
||||
}
|
||||
|
||||
# Why SLOT 2.2 you ask yourself while sippin your tea ?
|
||||
# Everyone knows 2.2 > 0, duh.
|
||||
SLOT="2.2"
|
||||
|
||||
# General: We need a new-enough binutils/gcc to match upstream baseline.
|
||||
# arch: we need to make sure our binutils/gcc supports TLS.
|
||||
COMMON_DEPEND="
|
||||
nscd? ( selinux? (
|
||||
audit? ( sys-process/audit )
|
||||
caps? ( sys-libs/libcap )
|
||||
) )
|
||||
suid? ( caps? ( sys-libs/libcap ) )
|
||||
selinux? ( sys-libs/libselinux )
|
||||
systemtap? ( dev-util/systemtap )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=app-misc/pax-utils-0.1.10
|
||||
!<sys-apps/sandbox-1.6
|
||||
!<sys-apps/portage-2.1.2"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
!sys-kernel/ps3-sources
|
||||
sys-apps/gentoo-functions
|
||||
!sys-libs/nss-db"
|
||||
|
||||
if [[ ${CATEGORY} == cross-* ]] ; then
|
||||
DEPEND+=" !crosscompile_opts_headers-only? (
|
||||
>=${CATEGORY}/binutils-2.24
|
||||
>=${CATEGORY}/gcc-4.7
|
||||
)"
|
||||
[[ ${CATEGORY} == *-linux* ]] && DEPEND+=" ${CATEGORY}/linux-headers"
|
||||
else
|
||||
DEPEND+="
|
||||
>=sys-devel/binutils-2.24
|
||||
>=sys-devel/gcc-4.7
|
||||
virtual/os-headers"
|
||||
RDEPEND+=" vanilla? ( !sys-libs/timezone-data )"
|
||||
PDEPEND+=" !vanilla? ( sys-libs/timezone-data )"
|
||||
fi
|
||||
|
||||
upstream_uris() {
|
||||
echo mirror://gnu/glibc/$1 ftp://sourceware.org/pub/glibc/{releases,snapshots}/$1 mirror://gentoo/$1
|
||||
}
|
||||
gentoo_uris() {
|
||||
local devspace="HTTP~vapier/dist/URI HTTP~dilfridge/distfiles/URI HTTP~tamiko/distfiles/URI HTTP~slyfox/distfiles/URI"
|
||||
devspace=${devspace//HTTP/https://dev.gentoo.org/}
|
||||
echo mirror://gentoo/$1 ${devspace//URI/$1}
|
||||
}
|
||||
SRC_URI=$(
|
||||
[[ -z ${EGIT_REPO_URIS} ]] && upstream_uris ${P}.tar.xz
|
||||
[[ -n ${PATCH_VER} ]] && gentoo_uris ${P}-patches-${PATCH_VER}.tar.bz2
|
||||
)
|
||||
SRC_URI+=" ${GCC_BOOTSTRAP_VER:+multilib? ( $(gentoo_uris gcc-${GCC_BOOTSTRAP_VER}-multilib-bootstrap.tar.bz2) )}"
|
||||
|
||||
src_unpack() {
|
||||
[[ -n ${GCC_BOOTSTRAP_VER} ]] && use multilib && unpack gcc-${GCC_BOOTSTRAP_VER}-multilib-bootstrap.tar.bz2
|
||||
|
||||
toolchain-glibc_src_unpack
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
toolchain-glibc_src_prepare
|
||||
|
||||
cd "${S}"
|
||||
|
||||
epatch "${FILESDIR}"/2.19/${PN}-2.19-ia64-gcc-4.8-reloc-hack.patch #503838
|
||||
|
||||
if use hardened ; then
|
||||
# We don't enable these for non-hardened as the output is very terse --
|
||||
# it only states that a crash happened. The default upstream behavior
|
||||
# includes backtraces and symbols.
|
||||
einfo "Installing Hardened Gentoo SSP and FORTIFY_SOURCE handler"
|
||||
cp "${FILESDIR}"/2.20/glibc-2.20-gentoo-stack_chk_fail.c debug/stack_chk_fail.c || die
|
||||
cp "${FILESDIR}"/2.25/glibc-2.25-gentoo-chk_fail.c debug/chk_fail.c || die
|
||||
|
||||
if use debug ; then
|
||||
# Allow SIGABRT to dump core on non-hardened systems, or when debug is requested.
|
||||
sed -i \
|
||||
-e '/^CFLAGS-backtrace.c/ iCPPFLAGS-stack_chk_fail.c = -DSSP_SMASH_DUMPS_CORE' \
|
||||
-e '/^CFLAGS-backtrace.c/ iCPPFLAGS-chk_fail.c = -DSSP_SMASH_DUMPS_CORE' \
|
||||
debug/Makefile || die
|
||||
fi
|
||||
fi
|
||||
|
||||
case $(gcc-fullversion) in
|
||||
4.8.[0-3]|4.9.0)
|
||||
eerror "You need to switch to a newer compiler; gcc-4.8.[0-3] and gcc-4.9.0 miscompile"
|
||||
eerror "glibc. See https://bugs.gentoo.org/547420 for details."
|
||||
die "need to switch compilers #547420"
|
||||
;;
|
||||
esac
|
||||
}
|
||||
Reference in New Issue
Block a user