mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
mail-client/mutt: version bump to 1.8.1
Package-Manager: Portage-2.3.3, Repoman-2.3.1
This commit is contained in:
Fabian Groffen
@@ -4,7 +4,9 @@ DIST mutt-1.5.24-gentoo-patches-r1.tar.bz2 118546 SHA256 411ad728404f4e7743b82bb
|
||||
DIST mutt-1.5.24.tar.gz 3897115 SHA256 a292ca765ed7b19db4ac495938a3ef808a16193b7d623d65562bb8feb2b42200 SHA512 f7fe7edf9d1701a8e92761b1f5e6ef2e3a3b513af7898872cbe36a8800714cb76945788a60d2008820c57bc5344a4147e2686f690da42cfc8a912e3a432452b1 WHIRLPOOL 35408cabab100e688f8c6d0d598f79144b7c72fb31f41a720acb9a6381e7ca94d66e640fe1178b911cfb16dfde4c982362c4c78ea203aef3a3dbcba09dcdc023
|
||||
DIST mutt-1.7.2.tar.gz 4025880 SHA256 1553501687cd22d5b8aaee4dc5a7d9dcf6cc61d7956f6aabaadd252d10cd5ff9 SHA512 5f13cbdf802bca80668b2f54bc66201d01bfe34c7f377b1bad88f8fa0e0c695264ff0bf6b64ae9bb6f5a3e22b6f096d2dd99fa36724937609f6f46e6a74da74e WHIRLPOOL c3a6bac41e31d79ae06ddfba1e9d8868e0cd4b54b04b3ca61ed5330f61ab56c7cf88273ae937c9de134fde01a31aebd70242afee6987177f152a5acd6d9d26b4
|
||||
DIST mutt-1.8.0.tar.gz 4116223 SHA256 45841eda12804b460260adff8f3f39cc977744e832486a3c49e182eda967adab SHA512 20120baa1d6c528281ba02faf8f19a3cbe3fce5bb5907a3513d3ec98592cd63db2b5f02884002c45dc18a4947d5cf2ac30e2ca4e059ad7a37ca0b22734e3bf1d WHIRLPOOL 5a47aa961a3172b8ff731ce2ad19eb6cece6f31fc18cad8bb6cba821670a3a5c17196447c2711bc7be9f40826c8d6b25c3081bd0b8366f1921487f05c5ca641b
|
||||
DIST mutt-1.8.1.tar.gz 4118443 SHA256 0be55a8cae6db2ef7ce831a70cbf6b2d8a0de558a08814933a67855ef07b0dad SHA512 5d695212560266aa16f2a547305bc6cd1a1ee7b10bfac9c45b5a8f7b5dfc16b8c288f5229bdf38167a77c44952bf353d93def5b928001ec4982e018f8c1a3e7a WHIRLPOOL b99615eb4485e26f60ce3eb5fe5201fc0c3d7bbd5067a4001209e9f746b09596016df9a28dab28913945f54c0b4a17cc869b47cb72726d1a377bdf9c18c89c69
|
||||
DIST mutt-gentoo-1.7.2-patches-r1.tar.xz 143816 SHA256 6358ee38ff32a35a0bc6449cba13b5cab406148fc068f2faa81aca16a6b5d158 SHA512 21703bc808ae510e26ede38e1dda5d7c74cad15823154584a83209e9dbf68bf6350961e66729cf2ede78bde003f3b92567d42f9f8f89ed53643dcfa536625b7e WHIRLPOOL 8b6b19da9ced5bf27d86b3143c878c8a392ffa1a3505d7f07d6a5ba5f76289f08447266be0b717179062cff3ba52155538be39f02f5af67fe4d84f9dc2a9d36c
|
||||
DIST mutt-gentoo-1.7.2-patches-r2.tar.xz 152992 SHA256 ac6f017f5d4b14d44a8d5d71e7cdeac59ba381a35ddff2db329e1d0a1af23720 SHA512 b96c658e151ee6b47a46b91311d9b9de002ae8ba6438d6e628f75722e9e66de5010b6ee6691f26ed0b9ba60aa4d96eee23bff39b7e6a27621e69d33701fafb01 WHIRLPOOL 3bb959a58eea74e9286146f0436a499a923c9d451d3d5fe6cef18bf9aa2038a5ce2f9c6514f5fe0c0297a5791fe1de135744eb7149b1c741cd1665a18c8224eb
|
||||
DIST mutt-gentoo-1.7.2-patches-r3.tar.xz 157048 SHA256 6355352d77b4297f4c1a6c2ff3e5877ed03b735ecb9b032dd0ac82e732a748e5 SHA512 31e71b8d444c93a4db13fea2bfb04dca12e252ea57a6cc77aea74213025ba57fdae207aa1d3a0ef3d0f22617edf090ddd6141d7aa87e03bd896dc4bc98bc3b99 WHIRLPOOL cec7f3b335a5f673a0b6b78a2b807a4432bcfb4df52a28665b74fcf367257d33fcb7a3e594be15453574cf6a22ef63a2bbdffa9124a529229abb71456070bf3d
|
||||
DIST mutt-gentoo-1.8.0-patches-r1.tar.xz 116584 SHA256 73d23e90b8486d41ee2734d0734e7176bc78945d10f2eb8593923e6739115459 SHA512 8ddb181d6a2d31e128106769b330eec140e1305271bd6d316dd0a8b1cf7a4b339430a4d948711d1470251d1d3804239cbbfa36521b9b6e187d378d87e92d5c9a WHIRLPOOL 2417c7ff86987a027a256ac6e19bd90ad1cd2e0f2ab094208f61304779e3497a35ec4c6ed01cec20312bfd0075691d9d9b9699d91a74640d97047b01b6cf9508
|
||||
DIST mutt-gentoo-1.8.1-patches-r0.tar.xz 133328 SHA256 0790e607db777f910206929f54234ee533e03905a82aa4c8afb9009ae0c7c165 SHA512 90e3d00f9496fd394ccb43c3f50f0593c3b4167e7cdf0ceb75a4d84c5c4851032b79453df1259af70e1cfa716f96636e484b08215aa029ec9cc7a22797a1f086 WHIRLPOOL bf64b16bcbcc7a61de54e363ac8aa014ba10fc46481b6304312175d15afc3aa7c8d1ad131e1fdac2ef660a5f701985d36939e93208b54adedc2919532e57da4a
|
||||
|
||||
252
mail-client/mutt/mutt-1.8.1.ebuild
Normal file
252
mail-client/mutt/mutt-1.8.1.ebuild
Normal file
@@ -0,0 +1,252 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="6"
|
||||
|
||||
inherit eutils flag-o-matic autotools
|
||||
|
||||
PATCHREV="r0"
|
||||
PATCHSET="gentoo-${PVR}/${PATCHREV}"
|
||||
|
||||
DESCRIPTION="A small but very powerful text-based mail client"
|
||||
HOMEPAGE="http://www.mutt.org/"
|
||||
MUTT_G_PATCHES="mutt-gentoo-${PV}-patches-${PATCHREV}.tar.xz"
|
||||
SRC_URI="ftp://ftp.mutt.org/pub/mutt/${P}.tar.gz
|
||||
https://bitbucket.org/${PN}/${PN}/downloads/${P}.tar.gz
|
||||
https://dev.gentoo.org/~grobian/distfiles/${MUTT_G_PATCHES}"
|
||||
IUSE="berkdb crypt debug doc gdbm gnutls gpg +hcache idn imap kerberos libressl lmdb mbox nls nntp notmuch pop qdbm sasl selinux sidebar slang smime smtp ssl tokyocabinet vanilla"
|
||||
REQUIRED_USE="
|
||||
hcache? ( ^^ ( berkdb gdbm lmdb qdbm tokyocabinet ) )
|
||||
imap? ( ssl )
|
||||
pop? ( ssl )
|
||||
nntp? ( ssl )
|
||||
smime? ( ssl !gnutls )
|
||||
smtp? ( ssl )
|
||||
sasl? ( || ( imap pop smtp nntp ) )
|
||||
kerberos? ( || ( imap pop smtp nntp ) )"
|
||||
SLOT="0"
|
||||
LICENSE="GPL-2"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
|
||||
CDEPEND="
|
||||
app-misc/mime-types
|
||||
|
||||
berkdb? ( >=sys-libs/db-4:= )
|
||||
gdbm? ( sys-libs/gdbm )
|
||||
lmdb? ( dev-db/lmdb:= )
|
||||
qdbm? ( dev-db/qdbm )
|
||||
tokyocabinet? ( dev-db/tokyocabinet )
|
||||
|
||||
ssl? (
|
||||
gnutls? ( >=net-libs/gnutls-1.0.17:= )
|
||||
!gnutls? (
|
||||
libressl? ( dev-libs/libressl:= )
|
||||
!libressl? ( >=dev-libs/openssl-0.9.6:0= )
|
||||
)
|
||||
)
|
||||
|
||||
nls? ( virtual/libintl )
|
||||
sasl? ( >=dev-libs/cyrus-sasl-2 )
|
||||
kerberos? ( virtual/krb5 )
|
||||
idn? ( net-dns/libidn )
|
||||
gpg? ( >=app-crypt/gpgme-0.9.0:= )
|
||||
notmuch? ( net-mail/notmuch:= )
|
||||
slang? ( sys-libs/slang )
|
||||
!slang? ( >=sys-libs/ncurses-5.2:0= )
|
||||
"
|
||||
DEPEND="${CDEPEND}
|
||||
net-mail/mailbase
|
||||
doc? (
|
||||
dev-libs/libxml2
|
||||
dev-libs/libxslt
|
||||
app-text/docbook-xsl-stylesheets
|
||||
|| ( www-client/lynx www-client/w3m www-client/elinks )
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
selinux? ( sec-policy/selinux-mutt )
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
local PATCHDIR="${WORKDIR}"/mutt-gentoo-${PV}-patches
|
||||
|
||||
if use !vanilla ; then
|
||||
# apply patches
|
||||
export EPATCH_FORCE="yes"
|
||||
export EPATCH_SUFFIX="patch"
|
||||
# http://hg.code.sf.net/p/gentoomutt/code/file/gentoo-1.8
|
||||
# http://hg.code.sf.net/p/gentoomuttpatches/code/file/mutt-1.8
|
||||
local patches=(
|
||||
patches-mutt
|
||||
bugs-gentoo
|
||||
features-common
|
||||
features-extra
|
||||
gentoo
|
||||
)
|
||||
local patchset
|
||||
for patchset in "${patches[@]}" ; do
|
||||
[[ -d "${PATCHDIR}/${patchset}" ]] || continue
|
||||
einfo "Applying ${PATCHSET} patchset ${patchset}"
|
||||
EPATCH_SOURCE="${PATCHDIR}"/${patchset} epatch \
|
||||
|| die "patchset ${patchset} failed"
|
||||
done
|
||||
# add some explanation as to why not to go upstream
|
||||
sed -i \
|
||||
-e '/ReachingUs = N_(/aThis release of Mutt is heavily enriched with patches.\\nFor this reason, any bugs are better reported at https://bugs.gentoo.org/\\nor re-emerge with USE=vanilla and try to reproduce your problem.\\n\\' \
|
||||
main.c || die "Failed to add bug instructions"
|
||||
fi
|
||||
|
||||
local upatches=
|
||||
# allow user patches
|
||||
eapply_user && upatches=" with user patches"
|
||||
|
||||
# patch version string for bug reports
|
||||
local patchset=
|
||||
use vanilla || patchset=", ${PATCHSET}"
|
||||
sed -i -e 's|"Mutt %s (%s)"|"Mutt %s (%s'"${patchset}${upatches}"')"|' \
|
||||
muttlib.c || die "failed patching in Gentoo version"
|
||||
|
||||
# many patches touch the buildsystem, we always need this
|
||||
AT_M4DIR="m4" eautoreconf
|
||||
|
||||
# the configure script contains some "cleverness" whether or not to setgid
|
||||
# the dotlock program, resulting in bugs like #278332
|
||||
sed -i -e 's/@DOTLOCK_GROUP@//' \
|
||||
Makefile.in || die "sed failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myconf=(
|
||||
"$(use_enable crypt pgp)"
|
||||
"$(use_enable debug)"
|
||||
"$(use_enable doc)"
|
||||
"$(use_enable gpg gpgme)"
|
||||
"$(use_enable nls)"
|
||||
"$(use_enable notmuch)"
|
||||
"$(use_enable sidebar)"
|
||||
"$(use_enable smime)"
|
||||
|
||||
"$(use_enable imap)"
|
||||
"$(use_enable pop)"
|
||||
"$(use_enable nntp)"
|
||||
"$(use_enable smtp)"
|
||||
|
||||
$(use ssl && use gnutls && echo --with-gnutls --without-ssl)
|
||||
$(use ssl && use !gnutls && echo --without-gnutls --with-ssl )
|
||||
$(use !ssl && echo --without-gnutls --without-ssl)
|
||||
|
||||
"$(use_with idn)"
|
||||
"$(use_with kerberos gss)"
|
||||
"$(use_with sasl)"
|
||||
"$(use slang && echo --with-slang=${EPREFIX}/usr)"
|
||||
"$(use_with !slang curses ${EPREFIX}/usr)"
|
||||
|
||||
"--enable-compressed"
|
||||
"--enable-external-dotlock"
|
||||
"--enable-nfs-fix"
|
||||
"--sysconfdir=${EPREFIX}/etc/${PN}"
|
||||
"--with-docdir=${EPREFIX}/usr/share/doc/${PN}-${PVR}"
|
||||
"--with-regex"
|
||||
"--with-exec-shell=${EPREFIX}/bin/sh"
|
||||
)
|
||||
|
||||
if [[ ${CHOST} == *-solaris* ]] ; then
|
||||
# arrows in index view do not show when using wchar_t
|
||||
myconf+=( "--without-wc-funcs" )
|
||||
fi
|
||||
|
||||
# REQUIRED_USE should have selected only one of these
|
||||
local hcaches=(
|
||||
"berkdb:bdb"
|
||||
"gdbm"
|
||||
"lmdb"
|
||||
"qdbm"
|
||||
"tokyocabinet"
|
||||
)
|
||||
local ucache hcache lcache
|
||||
for hcache in "${hcaches[@]}" ; do
|
||||
if use ${hcache%%:*} ; then
|
||||
ucache=${hcache}
|
||||
break
|
||||
fi
|
||||
done
|
||||
if [[ -n ${ucache} ]] ; then
|
||||
myconf+=( "--enable-hcache" )
|
||||
else
|
||||
myconf+=( "--disable-hcache" )
|
||||
fi
|
||||
for hcache in "${hcaches[@]}" ; do
|
||||
[[ ${hcache} == ${ucache} ]] \
|
||||
&& myconf+=( "--with-${hcache#*:}" ) \
|
||||
|| myconf+=( "--without-${hcache#*:}" )
|
||||
done
|
||||
|
||||
if use mbox; then
|
||||
myconf+=( "--with-mailpath=${EPREFIX}/var/spool/mail" )
|
||||
else
|
||||
myconf+=( "--with-homespool=Maildir" )
|
||||
fi
|
||||
|
||||
econf "${myconf[@]}" || die "configure failed"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake DESTDIR="${D}" install || die "install failed"
|
||||
if use mbox; then
|
||||
insinto /etc/mutt
|
||||
newins "${FILESDIR}"/Muttrc.mbox Muttrc
|
||||
else
|
||||
insinto /etc/mutt
|
||||
doins "${FILESDIR}"/Muttrc
|
||||
fi
|
||||
|
||||
# A newer file is provided by app-misc/mime-types. So we link it.
|
||||
rm "${ED}"/etc/${PN}/mime.types
|
||||
dosym /etc/mime.types /etc/${PN}/mime.types
|
||||
|
||||
# A man-page is always handy, so fake one
|
||||
if use !doc; then
|
||||
emake -C doc DESTDIR="${D}" muttrc.man || die
|
||||
# make the fake slightly better, bug #413405
|
||||
sed -e 's#@docdir@/manual.txt#http://www.mutt.org/doc/devel/manual.html#' \
|
||||
-e 's#in @docdir@,#at http://www.mutt.org/,#' \
|
||||
-e "s#@sysconfdir@#${EPREFIX}/etc/${PN}#" \
|
||||
-e "s#@bindir@#${EPREFIX}/usr/bin#" \
|
||||
doc/mutt.man > mutt.1
|
||||
cp doc/muttbug.man flea.1
|
||||
cp doc/muttrc.man muttrc.5
|
||||
doman mutt.1 flea.1 muttrc.5
|
||||
else
|
||||
# nuke manpages that should be provided by an MTA, bug #177605
|
||||
rm "${ED}"/usr/share/man/man5/{mbox,mmdf}.5 \
|
||||
|| ewarn "failed to remove files, please file a bug"
|
||||
fi
|
||||
|
||||
if use !prefix ; then
|
||||
fowners root:mail /usr/bin/mutt_dotlock
|
||||
fperms g+s /usr/bin/mutt_dotlock
|
||||
fi
|
||||
|
||||
dodoc BEWARE COPYRIGHT ChangeLog NEWS OPS* PATCHES README* TODO VERSION
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ -z ${REPLACING_VERSIONS} ]] ; then
|
||||
echo
|
||||
elog "If you are new to mutt you may want to take a look at"
|
||||
elog "the Gentoo QuickStart Guide to Mutt E-Mail:"
|
||||
elog " https://wiki.gentoo.org/wiki/Mutt"
|
||||
echo
|
||||
else
|
||||
local ver
|
||||
local preconddate=
|
||||
for ver in ${REPLACING_VERSIONS} ; do
|
||||
[[ ${ver} == "1.5"* || ${ver} == "1.6"* ]] && preconddate=true
|
||||
done
|
||||
if [[ -n ${preconddate} ]] ; then
|
||||
echo
|
||||
elog "The SmartTime functionality has been replaced with"
|
||||
elog "CondDate feature. To mimic SmartTime, use this CondDate formatter:"
|
||||
elog "%<[12m?%<[7d?%<[12H?%[%H:%M ]&%[%a-%d]>&%[%d-%b]>&%[%b-%y]>"
|
||||
echo
|
||||
fi
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user