mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
dev-python/spyder: add version 5.2.2
Package-Manager: Portage-3.0.30, Repoman-3.0.3 Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
This commit is contained in:
Andrew Ammerlaan
@@ -2,6 +2,7 @@ DIST spyder-4.2.5.tar.gz 11539071 BLAKE2B 9d7a98da018aae934803d640995fe2dfa6bbb2
|
||||
DIST spyder-5.0.5.tar.gz 20606379 BLAKE2B 52f05ffcf0b6aabdac23a055af1c674c6aa80a7d4f3608779df1d46e0e51de63a71b4e97db286dc92e071cbb44a0dc827aa750d8ca538e6764b5e780f493d615 SHA512 17654ee76eb51c5f5b9f494d009af3d7813f869f27f22ceb8ad8ca96dcedcbcd6b86c7a3895bb63eba3cc60e4a57ab94128abb8d21f05c4672b8bb8d545fe1ff
|
||||
DIST spyder-5.1.5.tar.gz 23849672 BLAKE2B a0a4db5105d4ecbb76bf3c996ea8ea17142bc4f9dfca989098ffdee32b620c711b343746e5dc5dce0c6c0a092a20b47d6bb28181c363f81af394bb8bccb5b6e2 SHA512 2204fe46ad3e4e14bebb51ef6a53074b657f6d970553decd0b2f9d0a7fba71b2f14b4efc3248bb4fb944860e85851e4a8add475ff12c6466e864be75b8cc38bb
|
||||
DIST spyder-5.2.1.tar.gz 23903864 BLAKE2B 04b8a81e04bf2f7c6f8a53bc417aeb3708cf67eeeb1bdf7f0b9879dc1848c7c1f48ad8f7bbbce21bef7d12f257f33c69325af77268e9c89d1f4558148fe26929 SHA512 0c2dcdc3a123af48d9d4db35ead0dd773dca7d3c39b763c732709f767d0efa89eed0284a6df2352d8cf2dc202aaccaffa70390e8b3b0b7cb961ff0a8c5ae0244
|
||||
DIST spyder-5.2.2.tar.gz 23913924 BLAKE2B 40bf968212f4b5d343b59ce6fd069f1e6a0d7f8bccbd3ff6eb76960638e9d4ff8f232a764673a75dcea9d8048ed6a5c36d3bd52719c6773cc26e922f5597e35a SHA512 e88a1332da503fcbd55496b7600a7b7dbfa5aa8d2d248b2f4a6cb4e394c07a38b6681db3ac7c0997ff87984a561f1d794a5bec6492f7c7c131c5cfee55c445b2
|
||||
DIST spyder-docs-5eb83118155a3765de4a0f863b936bcbe73bb7aa.tar.gz 85362596 BLAKE2B 7294dcd0f169958da132b141379b9b1cf497095981a86416fb98d98f98e30a425fe2e628a523785f932bbc06a2ba1ecddb45bae0df009887db928f879e08cdef SHA512 45f45546b83afb3036348e89ee3eded4d8ecee36ce58fe697da14677fbff8fa2dfe170be7385ecf10e1989817780c07b5676d545ee34e87a8f252929ad72882e
|
||||
DIST spyder-docs-78b25754c69a20643258821146e398ad5535c920.tar.gz 69167467 BLAKE2B d2815d552002f329b5fac59329fba3b3b0cd592bcbdacc0878966919e44dbab29548533661e60a1b9b8fd763d57d1e4c2f761782ace1b0a814a5f0cec1f66af9 SHA512 10764367fd5f830d7a3620b9d9e7ec4ab74539c1f48326c0c40f7caff74a50401addc7609fe1558c57dac4649d0a214c0d2d77cecd100bd8574151134e49634d
|
||||
DIST spyder-docs-a3a579ce6e7e42c9d9bbd88ac4e76650b7093e5c.tar.gz 88791917 BLAKE2B bdcf52965b592f4a88ee988afcca71ed73b0499397c8c0b7ff36c38d4408f4b76ff285b3d9739d1c126322fdd8c1c6b93f3017edcaf30563da02d8f509d09fe4 SHA512 2717dad17db836330820578c9082505b7f1126fef2a76284d03a443f3317e3a9a294f69e50f075a29580c4ad1bfbd23dcd02fcef93f32645ae5d52ecfb0b8f10
|
||||
|
||||
199
dev-python/spyder/spyder-5.2.2.ebuild
Normal file
199
dev-python/spyder/spyder-5.2.2.ebuild
Normal file
@@ -0,0 +1,199 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..10} )
|
||||
DISTUTILS_USE_SETUPTOOLS=rdepend
|
||||
|
||||
inherit optfeature xdg distutils-r1
|
||||
|
||||
# Commit of documentation to fetch
|
||||
DOCS_PV="cd0c65d943595da438410559811a5809bf0227a3"
|
||||
|
||||
DESCRIPTION="The Scientific Python Development Environment"
|
||||
HOMEPAGE="
|
||||
https://www.spyder-ide.org/
|
||||
https://github.com/spyder-ide/spyder/
|
||||
https://pypi.org/project/spyder/
|
||||
"
|
||||
SRC_URI="
|
||||
https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
|
||||
https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz
|
||||
"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
|
||||
# The test suite often hangs or does not work. Technically spyder requires
|
||||
# pyqt5<13, which we do not have in ::gentoo any more. Likely this is the reason
|
||||
# many of the tests fail or hang. RESTRICTing because IMO it is not worth the
|
||||
# several hours I spend every single version bump checking which tests do and
|
||||
# do not work. Spyder itself works fine with pyqt5>13.
|
||||
RESTRICT="test"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
|
||||
>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
|
||||
>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
|
||||
>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
|
||||
>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/python-lsp-black-1.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
|
||||
~dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
|
||||
>=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/qtconsole-5.2.1[${PYTHON_USEDEP}]
|
||||
<dev-python/qtconsole-5.3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/QtPy-1.5.0[${PYTHON_USEDEP},svg,webengine]
|
||||
>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
|
||||
>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
|
||||
>=dev-python/spyder-kernels-2.2.0[${PYTHON_USEDEP}]
|
||||
<dev-python/spyder-kernels-2.3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
|
||||
"
|
||||
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/cython[${PYTHON_USEDEP}]
|
||||
dev-python/flaky[${PYTHON_USEDEP}]
|
||||
dev-python/matplotlib[tk,${PYTHON_USEDEP}]
|
||||
dev-python/pandas[${PYTHON_USEDEP}]
|
||||
dev-python/pillow[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-mock[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-ordering[${PYTHON_USEDEP}]
|
||||
<dev-python/pytest-qt-4[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-xvfb[${PYTHON_USEDEP}]
|
||||
dev-python/pyyaml[${PYTHON_USEDEP}]
|
||||
dev-python/scipy[${PYTHON_USEDEP}]
|
||||
dev-python/sympy[${PYTHON_USEDEP}]
|
||||
)"
|
||||
|
||||
# Based on the courtesy of Arfrever
|
||||
# This patch removes a call to update-desktop-database during build
|
||||
# This fails because access is denied to this command during build
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-5.0.0-build.patch"
|
||||
"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
|
||||
)
|
||||
|
||||
DOCS=(
|
||||
"AUTHORS.txt"
|
||||
"Announcements.md"
|
||||
"CHANGELOG.md"
|
||||
"CODE_OF_CONDUCT.md"
|
||||
"CONTRIBUTING.md"
|
||||
"NOTICE.txt"
|
||||
"README.md"
|
||||
"RELEASE.md"
|
||||
)
|
||||
|
||||
distutils_enable_tests pytest
|
||||
distutils_enable_sphinx docs/doc \
|
||||
dev-python/sphinx-panels \
|
||||
dev-python/pydata-sphinx-theme \
|
||||
dev-python/sphinx-multiversion
|
||||
|
||||
python_prepare_all() {
|
||||
# move docs into workdir
|
||||
mv ../spyder-docs-${DOCS_PV}* docs || die
|
||||
|
||||
# these dependencies are packaged separately:
|
||||
# dev-python/spyder-kernels,
|
||||
# dev-python/python-lsp-server,
|
||||
# dev-python/qdarkstyle
|
||||
rm -r external-deps/* || die
|
||||
# runs against things packaged in external-deps dir
|
||||
rm conftest.py || die
|
||||
|
||||
# Do not depend on pyqt5<5.13, this dependency is carried by QtPy[pyqt5]
|
||||
# Do not depend on pyqtwebengine<5.13, this dependency is carried by QtPy[webengine]
|
||||
# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
|
||||
# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
|
||||
# The explicit version requirements only make things more complicated, if e.g.
|
||||
# pyls-spyder gains compatibility with a newer version of python-lsp-server
|
||||
# in a new release it will take time for this information to propagate into
|
||||
# the next spyder release. So just remove the dependency and let the other
|
||||
# ebuilds handle the version requirements to speed things up and prevent
|
||||
# issues such as Bug 803269.
|
||||
sed -i \
|
||||
-e '/pyqt5/d' \
|
||||
-e '/pyqtwebengine/d' \
|
||||
-e '/python-lsp-server/d' \
|
||||
-e '/parso/d' \
|
||||
-e '/jedi/d' \
|
||||
-e '/pylint/d' \
|
||||
requirements/conda.txt || die
|
||||
sed -i \
|
||||
-e "/'pyqt5[ 0-9<=>.,]*',/d" \
|
||||
-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
|
||||
-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
|
||||
-e "/'parso[ 0-9<=>.,]*',/d" \
|
||||
-e "/'jedi[ 0-9<=>.,]*',/d" \
|
||||
-e "/'pylint[ 0-9<=>.,]*',/d" \
|
||||
setup.py || die
|
||||
sed -i \
|
||||
-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
|
||||
-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
|
||||
-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
|
||||
-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
|
||||
-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
|
||||
spyder/dependencies.py || die
|
||||
|
||||
# do not check deps, fails because we removed pyqt5 dependency above
|
||||
sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
|
||||
spyder/tests/test_dependencies_in_sync.py || die
|
||||
|
||||
# can't check for update, need network
|
||||
rm spyder/workers/tests/test_update.py || die
|
||||
|
||||
# skip online test
|
||||
rm spyder/widgets/github/tests/test_github_backend.py || die
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
# Calling pytest directly makes the tests freeze after completing even if successful
|
||||
# Exit code is nonzero even upon success, so can't add || die here test results
|
||||
# should be checked for success manually
|
||||
python_test() {
|
||||
"${EPYTHON}" runtests.py
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
|
||||
optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
|
||||
optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
|
||||
optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
|
||||
optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
|
||||
optfeature "Run Cython files in the IPython console" dev-python/cython
|
||||
optfeature "The hdf5/h5py plugin" dev-python/h5py
|
||||
optfeature "The line profiler plugin" dev-python/spyder-line-profiler
|
||||
optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
|
||||
# spyder-autopep8 does not have a release (yet)
|
||||
# and are not compatible with >=spyder-4.0.0 at the moment
|
||||
# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
|
||||
optfeature "Vim key bindings" dev-python/spyder-vim
|
||||
optfeature "Unittest support" dev-python/spyder-unittest
|
||||
optfeature "Jupyter notebook support" dev-python/spyder-notebook
|
||||
optfeature "System terminal inside spyder" dev-python/spyder-terminal
|
||||
# spyder-reports not yet updated to >=spyder-4.0.0
|
||||
# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
|
||||
}
|
||||
Reference in New Issue
Block a user