xfce-base/thunar: Bump to 1.8.12

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/thunar/Manifest

@@ -1,2 +1,3 @@
 DIST Thunar-1.8.9.tar.bz2 2375302 BLAKE2B e98659633b448e1d231e466c72741de71ce448ecf413a4f29df47acd78c9353a8cbc374961b6bb09d4d9d6ff4b98b81d575e987059999a742e30038a7c549604 SHA512 8e1bff80692ee22393a0c0cfa09178aa14cc476a058f406cab7ca873778ac4673cbac2d271f525a51e0120f1b17f8872c58407e8d7b77c6e67b721f4e5318f80
 DIST thunar-1.8.11.tar.bz2 2362727 BLAKE2B 75146010df503146413d0d669d24f2e36e23f50952acb06e8670ee41a1dbf21ccb1992e9dbd2296d0ce46d120d81a0e2838e972b7e869977e2d4a8697a4e89eb SHA512 13576616fc556dae9be97f2390e85c12c01b78d86a59e5e8700b67dca7a2e70fe5f1e5716d3d77d22e158e7573a89e096aa8098ccccb78e7bd8e81cb319a6809
+DIST thunar-1.8.12.tar.bz2 2367685 BLAKE2B 259e7a2c9aeb66673a7b5e6d7147d5257d64b7143c79981ee65097568505969426ea4b20e7ef754fcc6f03e19f632b078115d2db524f2a6eeec1f1e3253e14e4 SHA512 cd27b26796602ea8623c368cd6c8bb53136c09e4a02c37775bed9918c801741e0adb5784151fbf4b93785967a637ffb8b1214b0721f9457de683ebd7718a8767

xfce-base/thunar/thunar-1.8.12.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit xdg-utils
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.42
+	>=x11-libs/gdk-pixbuf-2.14
+	>=x11-libs/gtk+-3.22:3
+	>=xfce-base/exo-0.12:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( dev-libs/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "If you were using an older Xfce version and Thunar fails to start"
+	elog "with a message similar to:"
+	elog "  Failed to register: Timeout was reached"
+	elog "you may need to reset your xfce4 session:"
+	elog "  rm ~/.cache/sessions/xfce4-session-*"
+	elog "See https://bugs.gentoo.org/698914."
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}