xfce-base/xfce4-panel: Bump to 4.20.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.18.6.tar.bz2 1595352 BLAKE2B e4f4eb2f3838cde69a2614021be184ba7281910e595cc868180eba5ce40898fb538cb82ef5317f8316273b6a926553e051730e4918f3d2d339e03729ac8c2a85 SHA512 a1c4597bbbb72d2f3ef90abe0082abe3404e0ea7fa6027e26ca50e31e03645464ce3e0a72f4d927e84c5775a775e3a70f70e25bd3d2e4358da869f9c474e6174
 DIST xfce4-panel-4.20.0.tar.bz2 2260815 BLAKE2B ab3d66465bf24757a9831ff71aebd4609a4a4b9e456899a34fa900836398a0c0727993b84769decb8c371c94344ad9f940eb15431824152e8acd9434125e58c8 SHA512 431ff1736a62bdee4a7a9a5e7b8aa9f0cf779ce5454503c33fc0ffb82b6cd4bbcbc5e1fc99c092e31f0f702f459cf31336eff914a41b618043f83d2a40c9b049
+DIST xfce4-panel-4.20.2.tar.bz2 2262583 BLAKE2B 73bb276bc14720c311855823bf18f32244a5e563296daf900760ed0513a67f4c8a96c469bbf6e7f5be1e236e264e0efb20fe25b47efe6c84b25ff337653da6a9 SHA512 a5dfa5576b638ad15dc9a8b24ab28786526e9785178bbbecd1d2ea1c21f70bb84c5bca1313e21a02bc7347b964d934de2fe406e1b2bc743bd7ea7ef20fcb9b5c

xfce-base/xfce4-panel/xfce4-panel-4.20.2.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-panel/start
+	https://gitlab.xfce.org/xfce/xfce4-panel/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+dbusmenu introspection vala wayland X"
+REQUIRED_USE="
+	|| ( wayland X )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-4.17.0:=
+	>=xfce-base/libxfce4ui-4.17.1:=
+	>=xfce-base/libxfce4util-4.17.2:=[introspection?,vala?]
+	>=xfce-base/libxfce4windowing-4.20.1:=[X?]
+	>=xfce-base/xfconf-4.13.2:=
+	dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
+	introspection? ( >=dev-libs/gobject-introspection-1.66:= )
+	wayland? (
+		>=dev-libs/wayland-1.20
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXext-1.0.0
+		x11-libs/libwnck:3
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable dbusmenu dbusmenu-gtk3)
+		$(use_enable vala)
+		$(use_enable wayland)
+		$(use_enable wayland gtk-layer-shell)
+		$(use_enable X x11)
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}