dev-python/wcmatch: Bump to 7.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/wcmatch/Manifest

@@ -1 +1,2 @@
 DIST wcmatch-7.1.tar.gz 105744 BLAKE2B 0add1c68025c92ac57d6ea64d82bddb20bace60de5d319fb16e16802f208d788d876695bfcd186b80630039f544565c631d36e1c7327dee5d8c799eff8c80ce2 SHA512 79d62d85f13d245e38d0fe92a275e24058b86af8aaf9a926bfd950dad4ec47e40e763c18b08d3eb4ddd925832ae9910f13407094070442b41dbe2fe4ad11fb39
+DIST wcmatch-7.2.tar.gz 105087 BLAKE2B a28bd9d02468f3ca83d606ee7f7d5c9b6b8883cf6e0c04b711765aefafce189f7f524a490c6831a739b579be66af5f4b1c7b6373da22e170211e611677c5788f SHA512 6fdc0a3cb6d66b323c509a5ee34c1e8df9a46a93fd1fc0921dfdbc17ac604934fdad3df5e8f253aa6a880bea2e81bb26ec097b9503c920433c5827ea91b327d8

dev-python/wcmatch/wcmatch-7.2.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	~dev-python/mkdocs_pymdownx_material_extras-1.0.7
+	dev-python/mkdocs-material
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-minify-plugin
+	dev-python/pyspelling
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Wildcard/glob file name matcher"
+HOMEPAGE="
+	https://github.com/facelessuser/wcmatch/
+	https://pypi.org/project/wcmatch/"
+SRC_URI="https://github.com/facelessuser/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/backrefs-4.1[${PYTHON_USEDEP}]
+	>=dev-python/bracex-2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="test? (
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-vcs/git
+)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# no such file or dir ~homedir
+	sed -i -e 's:test_tilde_user:_&:' \
+		tests/test_glob.py || die
+
+	# mkdocs-git-revision-date-localized-plugin needs git repo
+	if use doc; then
+		git init || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -m 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}