mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
dev-db/percona-xtrabackup: add 8.0.30.23
Closes: https://bugs.gentoo.org/805905 Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
@@ -5,3 +5,4 @@ DIST percona-xtrabackup-2.4.15.tar.gz 57357749 BLAKE2B fcc64736230636a3a5584a300
|
||||
DIST percona-xtrabackup-2.4.24.tar.gz 61985764 BLAKE2B 99531853b7e125bfe1d133d3dd902f3f68d50a6c127c09ac87652d70aee5c4d764ba7b102879bea0eb67c0a2f1a94633889786c0a7a1f6bc3f9ed54fe51a217d SHA512 de25639a6e204d2e4018c922ccbd5119c5696d03e0b445f81968b15c2179a46ae8844014e78aa89f6a0a3cd5aef20adc744c979926366673f78c347d6a4e0201
|
||||
DIST percona-xtrabackup-8.0.26-18.tar.gz 294169182 BLAKE2B 250437badd9bcaea92b0f254fad27a775014f17215e764114bba3d1cf0882135127738a4db78349cb9d519e6a9b5bc015f04747ad8ebfc09245ebad3aa890400 SHA512 0cceb6758364c31167ef0b47176e1950273e80e5266b91e12353287dfae6e3a87382b29a466920e5e58add1f461295199a70bb070a225458ed8a7de844e012ea
|
||||
DIST percona-xtrabackup-8.0.29-22.tar.gz 332851436 BLAKE2B 922e4b308efdb307b998e78e3764e611052afa46f53c69456a721c201f5bda2470fd2ba3164cd0eaf865c3455d3b5175c9bb63f4cb3a60d16ae00222695b88f9 SHA512 5ebf62acdf7dc35080f1ec12f9d84177eb10de6784f47d3504027f418cecf4e3c232381d896a3eac30554bdc5d9271e80666a99e2ed3cc8b457c28456dcda2b5
|
||||
DIST percona-xtrabackup-8.0.30-23.tar.gz 338259133 BLAKE2B 3b73731497013aea6abae7d83cd96914cb5300dd867f6066514c71d68f8a1420227e33512a5f2faf082029ccd2c871394acbf43fb58c029472cbeb5605f354fc SHA512 acada88f3509526259281b7f9805fcabb31c5924eb50c5ed761b0813f89adda046b060a57825b6a49178171daec8b4388e99202ef9c9def4b2b0932e73b4d535
|
||||
|
||||
@@ -0,0 +1,97 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
CMAKE_MAKEFILE_GENERATOR="emake"
|
||||
|
||||
inherit cmake
|
||||
|
||||
# TODO: just keep it unbundled...?
|
||||
MY_BOOST_VERSION="1.77.0"
|
||||
MY_PV=$(ver_rs 3 '-')
|
||||
MY_PV="${MY_PV//_pre*}"
|
||||
MY_PN="Percona-XtraBackup"
|
||||
MY_P="${PN}-${MY_PV}"
|
||||
MY_MAJOR_PV=$(ver_cut 1-2)
|
||||
|
||||
DESCRIPTION="Hot backup utility for MySQL based servers"
|
||||
HOMEPAGE="https://www.percona.com/software/mysql-database/percona-xtrabackup"
|
||||
SRC_URI="https://www.percona.com/downloads/${MY_PN}-${MY_MAJOR_PV}/${MY_PN}-${MY_PV}/source/tarball/${PN}-${MY_PV}.tar.gz
|
||||
https://boostorg.jfrog.io/artifactory/main/release/${MY_BOOST_VERSION}/source/boost_$(ver_rs 1- _ ${MY_BOOST_VERSION}).tar.bz2"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
|
||||
DEPEND="
|
||||
app-arch/lz4:0=
|
||||
app-editors/vim-core
|
||||
dev-libs/icu:=
|
||||
dev-libs/libaio
|
||||
dev-libs/libedit
|
||||
dev-libs/libev
|
||||
dev-libs/libevent:0=
|
||||
dev-libs/libfido2:=
|
||||
dev-libs/libgcrypt:0=
|
||||
dev-libs/libgpg-error
|
||||
dev-libs/openssl:0=
|
||||
dev-libs/protobuf:=
|
||||
dev-libs/rapidjson
|
||||
dev-libs/re2:=
|
||||
dev-python/sphinx
|
||||
net-misc/curl
|
||||
sys-libs/zlib:="
|
||||
|
||||
RDEPEND="
|
||||
${DEPEND}
|
||||
!dev-db/percona-xtrabackup-bin
|
||||
dev-perl/DBD-mysql"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-8.0.26-remove-rpm.patch
|
||||
)
|
||||
|
||||
S="${WORKDIR}/percona-xtrabackup-${MY_PV}"
|
||||
|
||||
src_prepare() {
|
||||
cmake_src_prepare
|
||||
|
||||
local bundled_boost_version=$(sed -En '/^SET\(BOOST_PACKAGE_NAME /{s/[^0-9.]//gp}' cmake/boost.cmake)
|
||||
if [[ ${MY_BOOST_VERSION//./} != ${bundled_boost_version} ]] ; then
|
||||
eerror "Source Boost version: ${bundled_boost_version}"
|
||||
eerror "Ebuild Boost version: ${MY_BOOST_VERSION}"
|
||||
die "Ebuild needs to fix MY_BOOST_VERSION!"
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
CMAKE_BUILD_TYPE="RelWithDebInfo"
|
||||
|
||||
local mycmakeargs=(
|
||||
-DCMAKE_C_FLAGS_RELWITHDEBINFO=-DNDEBUG
|
||||
-DCMAKE_CXX_FLAGS_RELWITHDEBINFO=-DNDEBUG
|
||||
-DBUILD_SHARED_LIBS=OFF
|
||||
-DCOMPILATION_COMMENT="Gentoo Linux ${PF}"
|
||||
-DINSTALL_PLUGINDIR=$(get_libdir)/${PN}/plugin
|
||||
-DWITH_BOOST="${WORKDIR}/boost_$(ver_rs 1- _ ${MY_BOOST_VERSION})"
|
||||
-DWITH_MAN_PAGES=ON
|
||||
-DWITH_SYSTEM_LIBS=ON
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local p="${BUILD_DIR}/storage/innobase/xtrabackup"
|
||||
|
||||
dobin "${p}"/xbcloud_osenv
|
||||
dobin "${BUILD_DIR}"/runtime_output_directory/{xbcloud,xbcrypt,xbstream,xtrabackup}
|
||||
|
||||
# cannot use dolib.so because helper would append libdir to target dir
|
||||
insinto /usr/$(get_libdir)/${PN}/plugin
|
||||
insopts -m 0755
|
||||
doins "${BUILD_DIR}"/plugin_output_directory/{keyring_file.so,keyring_vault.so}
|
||||
|
||||
doman "${p}"/doc/source/build/man/*
|
||||
}
|
||||
Reference in New Issue
Block a user