dev-python/python3-xapp: add 3.0.2

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Closes: https://bugs.gentoo.org/967385
Part-of: https://github.com/gentoo/gentoo/pull/45857
Signed-off-by: Sam James <sam@gentoo.org>

dev-python/python3-xapp/Manifest

@@ -1 +1,2 @@
 DIST python3-xapp-2.4.2.tar.gz 21482 BLAKE2B bacea6a626efa8ee60a4f91923e48e0e9e49d08ca0c9a5998b724284edc353912099f2deafc6eb7cf6a42a983f97f8cc03fe86c18338c89823f103e413685637 SHA512 04f995986eabaf613d166ae31bd36eda2b3563ea58aded64b132940430db9d59f9525eb562b0ad8d7649844adbaf28332c4f51fa633610b102feae97bc1bfc9f
+DIST python3-xapp-3.0.2.tar.gz 39265 BLAKE2B 33850fdc4e288470af57fa6b5abb27c3984b938ebc80fec4965f0271856a2c239a2ef4f720f31ea013938bdc9022754e114171a98ce80d86e54a5baeafdfab59 SHA512 83e9a3ac6526ffe55543a45f687656cf86e6dc77497610f52012115a8b830e0f8706a82896a0b11b66d5fb26274f06d7fe4d80cd5f9ab6304f513fd2ab2ee2a8

dev-python/python3-xapp/python3-xapp-3.0.2.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit meson python-r1
+
+DESCRIPTION="Python bindings for x11-libs/xapp"
+HOMEPAGE="https://github.com/linuxmint/python3-xapp"
+SRC_URI="https://github.com/linuxmint/python3-xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# There are no tests, and src_test() needs to be overridden
+# using python_foreach_impl otherwise theres an error.
+RESTRICT="test"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		>=x11-libs/xapp-3.2.2[introspection,${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	dev-python/psutil[${PYTHON_USEDEP}]
+	x11-themes/xapp-symbolic-icon-theme
+"
+
+src_configure() {
+	configuring() {
+		meson_src_configure \
+			-Dpython_target="${EPYTHON}"
+	}
+	python_foreach_impl configuring
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_install() {
+	installing() {
+		meson_src_install
+		python_optimize
+	}
+	python_foreach_impl installing
+}