dev-util/pkgcheck: add 0.10.44

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-util/pkgcheck/Manifest

@@ -1,2 +1,3 @@
 DIST pkgcheck-0.10.42.tar.gz 422183 BLAKE2B 88afbf4b4a9ea9accb447e17eb4b16ae5960fadef8d14f4c30478e06df43aaa226066e5bf9ea90122f21b0a21caf4908e44069d41254726de8c90b302dacc60b SHA512 a2a30fd2757216a865dce76dd05190706e15ccd2682337e757461184abf3ac5e4ee450d6007820248c55052c1591c534cda94ea06cc29171c876a56ac25de5f8
 DIST pkgcheck-0.10.43.tar.gz 430787 BLAKE2B 4d1d1b2bd5dbd9a05c026796c4053ee3b26b98ac857978cd7820cea2d4b0ad9bbdb001baaed46e8574ebbd9b39497c9448e3381d96d748cad76560e58a094d32 SHA512 73987234d6404dfa61f7019b380e76b729200f92b168ca38de1d7f8e6c968c42d471e4090bee94d4e7abbab6dcae6888db953f075c8345eca03714e521d714d2
+DIST pkgcheck-0.10.44.tar.gz 433078 BLAKE2B 51efce2b4e1ecb76a7773e057afc844d64029ec66cef0254c0cc7c286d8e76b3252466b00b60f73de07f60067c82ff2bf06a125d62074faab9c23986d21be154 SHA512 41c9f618bd6f3cc71beece63f2cd77f9e51ab8ba66a6b668fbfc1bf2429e99b4b1819e1565ddc03245751d7cfe204c8923750e19196b70f7daf02058e1e9fac6

dev-util/pkgcheck/pkgcheck-0.10.44.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{12..15} )
+inherit elisp-common distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgcheck.git
+		https://github.com/pkgcore/pkgcheck.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+	inherit pypi
+fi
+
+DESCRIPTION="pkgcore-based QA utility for ebuild repos"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck"
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="emacs"
+
+if [[ ${PV} == *9999 ]]; then
+	RDEPEND="
+		~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+		~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+	RDEPEND="
+		>=dev-python/snakeoil-0.11.6[${PYTHON_USEDEP}]
+		>=sys-apps/pkgcore-0.12.42[${PYTHON_USEDEP}]"
+fi
+RDEPEND+="
+	app-arch/zstd
+	>=dev-libs/tree-sitter-bash-0.25.1[python,${PYTHON_USEDEP}]
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pathspec[${PYTHON_USEDEP}]
+	>=dev-python/tree-sitter-0.25.2[${PYTHON_USEDEP}]
+	emacs? (
+		>=app-editors/emacs-24.1:*
+		app-emacs/ebuild-mode
+		app-emacs/flycheck
+	)
+"
+BDEPEND="${RDEPEND}
+	>=dev-python/flit-core-3.8[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+EPYTEST_PLUGINS=( pkgcore )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin dependencies
+	sed -i -e 's:~=:>=:' pyproject.toml || die
+}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if use emacs ; then
+	   pushd "${S}"/contrib/emacs >/dev/null || die
+	   elisp-compile *.el
+	   popd >/dev/null || die
+	fi
+}
+
+python_install_all() {
+	local DOCS=( NEWS.rst )
+	[[ ${PV} == *9999 ]] || doman build/sphinx/man/*
+	distutils-r1_python_install_all
+
+	if use emacs ; then
+		elisp-install ${PN} "${S}"/contrib/emacs/*.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+
+	optfeature "Network check support" dev-python/requests
+	optfeature "Perl module version check support" dev-perl/Gentoo-PerlMod-Version
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}