mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 06:48:18 -07:00
dev-dotnet/dotnet-sdk-bin: bump to 8.0.106
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
Maciej Barć
@@ -16,6 +16,12 @@ DIST dotnet-sdk-8.0.105-linux-musl-arm.tar.gz 209188121 BLAKE2B d4974b81d0c6c466
|
||||
DIST dotnet-sdk-8.0.105-linux-musl-arm64.tar.gz 209063416 BLAKE2B bd6d7ceffb7ab1ccef60b312c5e2eab073d8b5397534d867e41ce6942f5addcc96efe10fa959e45004b62fb728ab24e4b1443c3131531a5df62af60474617b53 SHA512 ea1cbb3fe35447418f552d51a359a4f133754240aeca91fea8e5ed97dcdd9b01a4cbfeb6354ec1a3f71c7fcdf82000c7f9492c42b66fc69caafd023927e6f658
|
||||
DIST dotnet-sdk-8.0.105-linux-musl-x64.tar.gz 213676181 BLAKE2B 8aa2513e2520c175ac80278af66bc5f943243f373b5d82b89af05a0e1174404e5cf79ecf7e75be0ba1bcb90b7f4886377eb833bf658d7fcac8377bad6765d299 SHA512 d8a8b2ea25b70139a4ac1356c210221243add6956a946fbc24c7195850624a4f25569e22024188dd718b1ff0fadbf775a6df97f8aa5ec2244159adfd81bb14dc
|
||||
DIST dotnet-sdk-8.0.105-linux-x64.tar.gz 213741300 BLAKE2B 17f6fe0d440fcb89d1b8959b869efc1adbd72dad6029a5d7e2f563ff41d9724402528e88758ac75f7ff6a0e1a36a354e5f46f3bae450fb6dacafaddadd330563 SHA512 60ff271ee7851ff9ab851f9dc3e3d0abc87ac9b982959abfc8f0a3b58301fb6a0ff7b9f07f8df18668e1e8182c688d0d661bb9cb1771a2d40a0015d02009fce8
|
||||
DIST dotnet-sdk-8.0.106-linux-arm.tar.gz 208974475 BLAKE2B f081fae8997e0d34e83de4a192ca7869c78d1e4eb31bc07d053c23b6577b65f33720428c362b12aeaa67a443f76a56410a0ee97e9682639c7cc9ca3693f9f85f SHA512 ebedfc205f9301890c78c4176d1a6f910890cf224e7ac34fd69f798d663550e36c3a2a057111304aaeecea31bfd496007ebbae4a51f33cd674588f42d8b3df9a
|
||||
DIST dotnet-sdk-8.0.106-linux-arm64.tar.gz 208853029 BLAKE2B b0fe93b920f168490ca40debb320746f20f0372fa9fdcd16a6092ebcbd8ae8eadade5e86bca2fe04d6211b2cbc6b49452e4e666b3c2d4a7b41b6b1a23ee32afc SHA512 e8f735d20d79b20d24ce5b2f7c25c60604cb6b694b6572488c654cbf14a4d99c269f64f4ca23ab78aefaedf14f35a0ae1f33adf6afac5556e2ebd22ec73e04eb
|
||||
DIST dotnet-sdk-8.0.106-linux-musl-arm.tar.gz 209248865 BLAKE2B 68fa57d4cebd7ff5903786fa8e1b7a7d66b5c9e75f9993b3b65692eade9fb67fa0c4fbaf48dc49d815c8043225962e218036811b68e71db2d7436a09b505dad5 SHA512 0d149ee7d5e3557d631ff96fff06e7bbf01cc80041d9a378cd8633f5304ba8351b3d25f7b889d68ae245329fd9cd86d9475cac5ca3a157e5fd98c18420857edf
|
||||
DIST dotnet-sdk-8.0.106-linux-musl-arm64.tar.gz 209116519 BLAKE2B 543cc6b7fe8e7f295bf72cc39dc92a68d1b5d24e77d7083853495f27dd9e993a635598448f9a3f9dd84232c8af70b623ea6c3d27fb277288a09bdc7c740d763c SHA512 605fd1210a69fe1e933b64cb0377bda7e7fcfab17854069e252d444431260292d1470dbe645acc68e7ebec52985893497bfde9ba25a03794dbff9987437b2b45
|
||||
DIST dotnet-sdk-8.0.106-linux-musl-x64.tar.gz 213814352 BLAKE2B 48bff3e97b53249fc33c79fa1630197e6dc51ec5c962060335b2a5bc2ac27ae451a83669ac364eb3c30c4e69e36a7659e52e165bb0b25511f0d2791e0d8a22be SHA512 ac5cbd009cb29624f6a686fe476ed9a6ad290aa22d9a613f2e14f35076f251e3e3ec6b7b1d1760daf5efff5e2d673654770bb9ab0761326a71dc7e190deb63ab
|
||||
DIST dotnet-sdk-8.0.106-linux-x64.tar.gz 213776097 BLAKE2B ee629c5b85e87306da989f8f9df4e00b46b57ff0014accfdd8de31c3ee548ec8886a602acb45a64a2db194807f403b440e7c2190e50daf0e002d43160e7d42d2 SHA512 06eecc146b16eef0654fb4fd17faec06c6dc1b7236acc7e4a33e4b13cbea1d725faeb9eda41a0c12e65ec4c89d6624971429ca223638387c66f1d3e4dcd1407b
|
||||
DIST dotnet-sdk-8.0.300-linux-arm.tar.gz 217482888 BLAKE2B 309027b54d43fd44bb05f73a612c10d91e9b5af46ee2d1f1cf1f60030668d06364bf442c44f900ac6e69f6dcdaa84f16a1974cd05a140fe7beaf615577168d67 SHA512 13fd4818d3cb64dcdbf23748d0e8afcdfb981c1d6f0a8721d41c3794c363dae615612838e0db1050fd8b218ccf8e27a2c97e5a0da61da0d384c008b08c1f066b
|
||||
DIST dotnet-sdk-8.0.300-linux-arm64.tar.gz 217385231 BLAKE2B 1080d581bb0b17b4bd7f4d49ab4ead7be2da885fb7b671034db879ecc29e88334f63da1caa663cb9aa1bbc122a1b961d0105c4e0941a38c8192425a866f0f2d5 SHA512 b38d34afe6d92f63a0e5b6fc37c88fbb5a1c73fba7d8df41d25432b64b2fbc31017198a02209b3d4343d384bc352834b9ee68306307a3f0fe486591dd2f70efd
|
||||
DIST dotnet-sdk-8.0.300-linux-musl-arm.tar.gz 217378627 BLAKE2B f68d287fba305dffcdd10e2d63f3743fe2f7132af6a7bed42f64be636a53890360d4a19a05122dd3ed0f438d6aaca0d36dc2dc1f91fc5103ee144ce446ffda50 SHA512 768bc41911895272ed8b8629d3ae36ccedb74c9982b94c8bee6575870cdce6bd9ffab26751f48cedd4b3c7921b3fb6d3416364bc4102f61983dd0b18e9aca104
|
||||
|
||||
158
dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.106.ebuild
Normal file
158
dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.106.ebuild
Normal file
@@ -0,0 +1,158 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
SDK_SLOT="$(ver_cut 1-2)"
|
||||
RUNTIME_SLOT="${SDK_SLOT}.6"
|
||||
|
||||
DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
|
||||
HOMEPAGE="https://dotnet.microsoft.com/
|
||||
https://github.com/dotnet/dotnet/"
|
||||
SRC_URI="
|
||||
amd64? (
|
||||
elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-x64.tar.gz )
|
||||
elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-x64.tar.gz )
|
||||
)
|
||||
arm? (
|
||||
elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm.tar.gz )
|
||||
elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm.tar.gz )
|
||||
)
|
||||
arm64? (
|
||||
elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm64.tar.gz )
|
||||
elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm64.tar.gz )
|
||||
)
|
||||
"
|
||||
S="${WORKDIR}"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
|
||||
# See bug https://bugs.gentoo.org/932377
|
||||
KEYWORDS="~amd64 ~arm ~arm64"
|
||||
|
||||
# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
|
||||
# bug https://bugs.gentoo.org/923430
|
||||
RESTRICT="splitdebug strip"
|
||||
|
||||
CURRENT_NUGETS_DEPEND="
|
||||
~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
|
||||
"
|
||||
EXTRA_NUGETS_DEPEND="
|
||||
~dev-dotnet/dotnet-runtime-nugets-6.0.31
|
||||
~dev-dotnet/dotnet-runtime-nugets-7.0.20
|
||||
"
|
||||
NUGETS_DEPEND="
|
||||
${CURRENT_NUGETS_DEPEND}
|
||||
${EXTRA_NUGETS_DEPEND}
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
app-crypt/mit-krb5:0/0
|
||||
dev-libs/icu
|
||||
dev-util/lttng-ust:0/2.12
|
||||
sys-libs/zlib:0/1
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/patchelf
|
||||
"
|
||||
IDEPEND="
|
||||
app-eselect/eselect-dotnet
|
||||
"
|
||||
PDEPEND="
|
||||
${NUGETS_DEPEND}
|
||||
"
|
||||
|
||||
QA_PREBUILT="*"
|
||||
|
||||
MUSL_BAD_LINKS=(
|
||||
apphost
|
||||
createdump
|
||||
dotnet
|
||||
libSystem.Globalization.Native.so
|
||||
libSystem.IO.Compression.Native.so
|
||||
libSystem.Native.so
|
||||
libSystem.Net.Security.Native.so
|
||||
libSystem.Security.Cryptography.Native.OpenSsl.so
|
||||
libclrgc.so
|
||||
libclrjit.so
|
||||
libcoreclr.so
|
||||
libcoreclrtraceptprovider.so
|
||||
libdbgshim.so
|
||||
libhostfxr.so
|
||||
libhostpolicy.so
|
||||
libmscordaccore.so
|
||||
libmscordbi.so
|
||||
libnethost.so
|
||||
singlefilehost
|
||||
)
|
||||
MUSL_BAD_SONAMES=(
|
||||
libc.musl-aarch64.so.1
|
||||
libc.musl-armv7.so.1
|
||||
libc.musl-x86_64.so.1
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
|
||||
if use elibc_musl ; then
|
||||
local musl_bad_link
|
||||
local musl_bad_link_path
|
||||
local musl_bad_soname
|
||||
|
||||
for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
|
||||
while read -r musl_bad_link_path ; do
|
||||
# Skip if file either does not end with ".so" or is not executable.
|
||||
# Using "case" here for easier matching in case we have to add
|
||||
# a special exception.
|
||||
case "${musl_bad_link_path}" in
|
||||
*.so )
|
||||
:
|
||||
;;
|
||||
* )
|
||||
if [[ ! -x "${musl_bad_link_path}" ]] ; then
|
||||
continue
|
||||
fi
|
||||
;;
|
||||
esac
|
||||
|
||||
einfo "Fixing musl libc link for ${musl_bad_link_path}"
|
||||
|
||||
for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
|
||||
patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
|
||||
done
|
||||
|
||||
patchelf --add-needed libc.so "${musl_bad_link_path}" || die
|
||||
done < <(find . -type f -name "${musl_bad_link}")
|
||||
done
|
||||
fi
|
||||
|
||||
# Remove static libraries, bug https://bugs.gentoo.org/825774
|
||||
find ./packs -type f -name "libnethost.a" -delete || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local dest="opt/${PN}-${SDK_SLOT}"
|
||||
dodir "${dest%/*}"
|
||||
|
||||
# Create a magic workloads file, bug #841896
|
||||
local featureband="$(( $(ver_cut 3) / 100 * 100 ))" # e.g. 404 -> 400
|
||||
local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
|
||||
|
||||
mkdir -p "${S}/${workloads}" || die
|
||||
touch "${S}/${workloads}/userlocal" || die
|
||||
|
||||
mv "${S}" "${ED}/${dest}" || die
|
||||
mkdir "${S}" || die
|
||||
|
||||
fperms 0755 "/${dest}"
|
||||
dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
eselect dotnet update ifunset
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
eselect dotnet update ifunset
|
||||
}
|
||||
Reference in New Issue
Block a user