dev-lang/eisl: bump to 5.66

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

dev-lang/eisl/Manifest

@@ -1 +1,2 @@
 DIST eisl-5.62.gh.tar.gz 3065107 BLAKE2B 5c2e875d8964ff77d9674e6c2cd318bf33469d65662dd3242ed7b3e9de0e53ab3ae0e1fb717d5f5879744b4e1784da1bd430d22ae56a877ce08d9421c0200502 SHA512 2b7c07d7d354df0376be1a2605f2e6740975f5f86363f01b64c1539d18b6ef41f207ef6889bd676e43232d3debac4618ba4cb1049f2ddc8cead221dd7e4bfd35
+DIST eisl-5.66.gh.tar.gz 4491453 BLAKE2B 7a7cb6ebd488376c8fc0fff3faf500295eddad78b544e94c36412fa5e95a82c40fdb4e824f04d864a0fbb3e0d79dcbe1b35f6342e4da8690b2b89d2c5c32fcf5 SHA512 728bf5a6f0c9654914e1e12b48431cb271a472abb03aa0a7fad059cf61ea5194a9dd56fca05ae3cdac862f276c0eeccd36b5de5805711a989e69cbe0f13f19c3

dev-lang/eisl/eisl-5.66.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+inherit toolchain-funcs
+
+DESCRIPTION="Interpreter and compiler compatible with the ISLisp standard"
+HOMEPAGE="https://github.com/sasagawa888/eisl/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/sasagawa888/${PN}"
+else
+	SRC_URI="https://github.com/sasagawa888/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+RESTRICT="test"
+
+DOCS=( README{,-ja}.md documents )
+
+RDEPEND="
+	sys-libs/ncurses:=
+"
+DEPEND="
+	${RDEPEND}
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.61-makefile.patch" )
+
+src_compile() {
+	# bug https://bugs.gentoo.org/939771
+	# don't clean and compile in one invocation with --shuffle possible
+	local target=""
+	for target in clean edlis eisl ; do
+		emake CC="$(tc-getCC)" FLAGS="${LDFLAGS}" "${target}"
+	done
+}
+
+src_test() {
+	# Tests run cppcheck (and fail).
+	:
+}
+
+src_install() {
+	dobin edlis eisl
+
+	# Compilation of ISLisp files on installation fails.
+	# Do not compile them and mimic "make install".
+	insinto "/usr/share/${PN}"
+	doins -r ./library/
+	doins ./fast.h ./ffi.h
+
+	einstalldocs
+}