dev-python/aws-sam-translator: Bump to 1.80.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-11-17 08:57:10 +01:00
parent 22121d0ef8
commit dbbad117da
2 changed files with 63 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST serverless-application-model-1.79.0.gh.tar.gz 5119260 BLAKE2B 2cf3db022fc483bc1575328a0ece762285632b7bcb18757aa1afdab77aab1d567a78b8bf9c3b79666e23f546b73406335323d8b5f0ed829fb40f338a769082df SHA512 285c2b5d1728e4758dce362690fad6d1508ad4c61402a0b67d775952cb1e8479ddbdd352b746cc9178d3074164f05ac0c73cfaac68775ae97749e3746efc1bb4
DIST serverless-application-model-1.80.0.gh.tar.gz 5120643 BLAKE2B de9868384b73faa5be3950db9e54308d1411f0f49ca0b758bbcbbebe4a83df5489968de394ba74b8ad065489d6a40e53ef2b317258510ffd8d1cc07bc4acc9e6 SHA512 0a82d8569c98ca85e528eff23fbe00121ea244ddb395bd6f8a3ddc1de5f09bf6d24c8ead9392cd0f880f8e075cce9cc6685c1d38bc291ad835709dc00c674a05
@@ -0,0 +1,62 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 multiprocessing
MY_P=serverless-application-model-${PV}
DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
HOMEPAGE="
https://github.com/aws/serverless-application-model/
https://pypi.org/project/aws-sam-translator/
"
SRC_URI="
https://github.com/aws/serverless-application-model/archive/v${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
RDEPEND="
<dev-python/boto3-2[${PYTHON_USEDEP}]
>=dev-python/boto3-1.19.5[${PYTHON_USEDEP}]
>=dev-python/jsonschema-3.2[${PYTHON_USEDEP}]
<dev-python/pydantic-3[${PYTHON_USEDEP}]
>=dev-python/pydantic-1.8[${PYTHON_USEDEP}]
<dev-python/typing-extensions-5[${PYTHON_USEDEP}]
>=dev-python/typing-extensions-4.4[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/parameterized[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all() {
# so much noise...
sed -i -e '/log_cli/d' pytest.ini || die
# deps are installed by ebuild, don't try to reinstall them via pip
truncate --size=0 requirements/*.txt || die
distutils-r1_python_prepare_all
}
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x AWS_DEFAULT_REGION=us-east-1
epytest -o addopts= -o filterwarnings= \
-p xdist -n "$(makeopts_jobs)" --dist=worksteal
}