net-im/dino: add 0.5.1

Signed-off-by: 1vybridge <openrc@posteo.de>
Part-of: https://github.com/gentoo/gentoo/pull/44823
Closes: https://github.com/gentoo/gentoo/pull/44823
Signed-off-by: Florian Schmaus <flow@gentoo.org>

net-im/dino/Manifest

@@ -1 +1,2 @@
 DIST dino-0.5.0.tar.gz 1002577 BLAKE2B 3f1cd3f8d16549dbb0af3a4827fc4657b7881a0a327942ff8fde415475c7821c5cd9426486c4ed9b37cfe4fd0019e079c960d071caa7f186b83df44854f7779c SHA512 9cb6db27e6afd42204990c836019bc84a2a61af839d59cf8378520308d3016e6ac674ea4abd3044dfdf18e21e8431ef3cc85ad70d02c89d95c4dc702b32e05d2
+DIST dino-0.5.1.tar.gz 1004784 BLAKE2B 770e47110316ea032f45220e41d179ed70b214d9c6429907880f977079765a909e9de50a6d14e8b1b5b8846e2cd9456c322805aaf95fef3709a3a0f582fa52ea SHA512 72b4d38963a8498a31cad0b3cee88856f1dfcf7b63669fead45c427377ff530a8a045bd88dbd35ce8f2b1b6265716389d0c40d97386a1105344e76e3c102f1f1

net-im/dino/dino-0.5.1.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson vala xdg readme.gentoo-r1
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+MY_REPO_URI="https://github.com/dino/dino"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="${MY_REPO_URI}.git"
+	inherit git-r3
+else
+	SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +notification-sound +omemo +rtp test"
+RESTRICT="!test? ( test )"
+
+# webrtc-audio-processing order follows upstream meson...
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/libgee:0.8=
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.2.0:1[vala]
+	media-libs/graphene
+	net-libs/glib-networking
+	net-libs/gnutls:=
+	>=net-libs/libnice-0.1.22-r1
+	net-libs/libomemo-c
+	net-libs/libsrtp:2=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	gpg? ( app-crypt/gpgme:= )
+	http? ( net-libs/libsoup:3.0 )
+	notification-sound? ( media-libs/libcanberra:0[sound(+)] )
+	omemo? (
+		dev-libs/libgcrypt:=
+		media-gfx/qrencode:=
+	)
+	rtp? (
+		media-libs/gst-plugins-base:1.0
+		media-libs/gstreamer:1.0
+		|| (
+			media-libs/webrtc-audio-processing:1
+			>=media-libs/webrtc-audio-processing-0.2:0
+			media-libs/webrtc-audio-processing:2
+		)
+	)
+"
+DEPEND="${RDEPEND}
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+"
+BDEPEND="
+	sys-devel/gettext
+	$(vala_depend)
+"
+
+src_configure() {
+	vala_setup
+	local emesonargs=(
+		$(meson_feature gpg plugin-openpgp)
+		$(meson_feature http plugin-http-files)
+		$(meson_feature notification-sound plugin-notification-sound)
+		$(meson_feature omemo plugin-omemo)
+		$(meson_feature rtp plugin-rtp)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala/xmpp-vala-test || die
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}