mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
dev-python/translate-toolkit: Bump to 3.14.4
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
@@ -1,3 +1,4 @@
|
||||
DIST translate-3.14.1.gh.tar.gz 1174769 BLAKE2B 3be39dbf964307ebaaca651f06683ecf67e3aaad9ea3774a68190f117867e8a5dc8ba732242fc5e34d53e629474bc038e2dbb2b8383fb914c0aa8325a6a3ac39 SHA512 4052c2062934720b347723a88f2a9fb187c03c064efa88a95992860b196637ed805e2c00986f0337253f56b3ce9f7e064ef33c12f9ba3da4af01b10257449c30
|
||||
DIST translate-3.14.2.gh.tar.gz 1175450 BLAKE2B db13e59036bd75a62847c68c4e2633a17152def48ccfd1d36531a0325b4b5d819711dab1cb3cfc23abc2e7201b348836434428ed155e6e593273ff8750038faa SHA512 7ae64bd93459b29e6a341ea8ded2993e02e277dbba48a0638eda28fff4dfcc9b490d0a669e277cb75c395f385e5a54feb0665919c27b1ab7c5cffd0add109d27
|
||||
DIST translate-3.14.3.gh.tar.gz 1174793 BLAKE2B 9aad67c2bc390083dcacca53a41b99adeff679db4d576c054d8298da0e5114e5204128c94ee924cf4e5851378b3cec7b99d52b2dd12c5ece86562d45d05c205d SHA512 6f584ea46aceb4080eda2b05e3fbe51d76667d8afcac8da4e0b7644965aa833617db031329e315cbb18c6194e289a9054f127814372e97535bc40d765d65316e
|
||||
DIST translate-3.14.4.gh.tar.gz 1174947 BLAKE2B 1a4f9b4b146145ef215ca0118c328c5c6153461b3f6899c665d1c69762bfe543ffffb7e590229b6d5ada5c5373b46484d4ebf6fbc4d9cac4b908174fde358d04 SHA512 4cb4b94f02858348c7e2e66cc3b0efa495084fbf03fb659ec701349f693c27647b11f2aefefca7b585b2c6e68a699149e85cedccbcf796e57edf825925e4f7d2
|
||||
|
||||
119
dev-python/translate-toolkit/translate-toolkit-3.14.4.ebuild
Normal file
119
dev-python/translate-toolkit/translate-toolkit-3.14.4.ebuild
Normal file
@@ -0,0 +1,119 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
PYTHON_REQ_USE="sqlite"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
MY_P=translate-${PV}
|
||||
DESCRIPTION="Toolkit to convert between many translation formats"
|
||||
HOMEPAGE="
|
||||
https://github.com/translate/translate/
|
||||
https://pypi.org/project/translate-toolkit/
|
||||
"
|
||||
SRC_URI="
|
||||
https://github.com/translate/translate/archive/${PV}.tar.gz
|
||||
-> ${MY_P}.gh.tar.gz
|
||||
"
|
||||
S="${WORKDIR}"/${MY_P}
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="+html +ical +ini +subtitles +yaml"
|
||||
|
||||
RDEPEND="
|
||||
app-text/iso-codes
|
||||
>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
|
||||
dev-python/cheroot[${PYTHON_USEDEP}]
|
||||
>=dev-python/levenshtein-0.12.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
|
||||
dev-python/ruamel-yaml[${PYTHON_USEDEP}]
|
||||
>=dev-python/cwcwidth-0.1.9[${PYTHON_USEDEP}]
|
||||
sys-devel/gettext
|
||||
html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
|
||||
ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
|
||||
ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
|
||||
subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
|
||||
yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
|
||||
"
|
||||
# Technically, the test suite also has undeclared dependency
|
||||
# on dev-python/snapshottest but all the tests using it are broken
|
||||
# anyway, so we skip them.
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/phply[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
src_test() {
|
||||
# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
|
||||
# correctly, so we need to reassemble all data files in a single directory
|
||||
local -x XDG_DATA_HOME=${T}/share
|
||||
cp -r translate/share "${T}/" || die
|
||||
cp -r "${ESYSROOT}/usr/share"/gaupol "${XDG_DATA_HOME}"/ || die
|
||||
|
||||
distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local EPYTEST_DESELECT=(
|
||||
# Fails with network-sandbox (and even with it off but w/ softer fail)
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
|
||||
# all tests based on snapshottest are broken and I'm too tired
|
||||
# to figure this out
|
||||
tests/translate/tools/test_pocount.py::test_{cases,output}
|
||||
tests/translate/tools/test_junitmsgfmt.py::test_output
|
||||
)
|
||||
local EPYTEST_IGNORE=(
|
||||
# unpackaged fluent.*
|
||||
tests/translate/storage/test_fluent.py
|
||||
# changes directory and does not change it back, sigh
|
||||
tests/odf_xliff/test_odf_xliff.py
|
||||
)
|
||||
|
||||
if ! use ini; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/convert/test_ini2po.py
|
||||
translate/convert/test_po2ini.py
|
||||
)
|
||||
fi
|
||||
|
||||
if ! use subtitles; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/storage/test_subtitles.py
|
||||
)
|
||||
fi
|
||||
|
||||
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
||||
epytest
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
insinto /usr
|
||||
doins -r translate/share
|
||||
|
||||
if ! use html; then
|
||||
rm "${ED}"/usr/bin/{html2po,po2html} || die
|
||||
fi
|
||||
if ! use ical; then
|
||||
rm "${ED}"/usr/bin/{ical2po,po2ical} || die
|
||||
fi
|
||||
if ! use ini; then
|
||||
rm "${ED}"/usr/bin/{ini2po,po2ini} || die
|
||||
fi
|
||||
if ! use subtitles; then
|
||||
rm "${ED}"/usr/bin/{sub2po,po2sub} || die
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user