dev-python/kombu: Bump to 5.3.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/kombu/Manifest

@@ -1,2 +1,3 @@
 DIST kombu-5.3.2.tar.gz 431102 BLAKE2B d617868a851382055acb44313f928aa2f1458700c29ee008f6eb7226010537bfbda6b306907e4901db1e51300abee969d574842a65f049f50507376103dbc670 SHA512 2960b3a2c8ef067d2cd82c8930ff00ffa8ce17d40a3b73597d274a289dec4ea24a2f250b19f4f02198be8cb5da067b9b45b7d07f4b15632ef96e9919bab739ea
 DIST kombu-5.3.3.tar.gz 436079 BLAKE2B 4ebc4fa529ff232a871b3c0ec2c200c88186785eb7beaa2abb1ddd87f67b74708b7af10a38babac6bd29c465c5e89ac2ae7325216f1e68e50a02f6636b6d4e47 SHA512 9f34d9f57383b8791cf3c625562c273232d24a32aadb60a8fdac26c0c3afa968eeb1b9523dcb5f498360820828203e570fda4f98940521d753a93691ab16de44
+DIST kombu-5.3.4.tar.gz 437599 BLAKE2B 111f6e36fe7fd0715fd843f234c99144713ed73ad18d4100f1beedf7277ec4690788b115000c722bdd75081bffab0938879e799e2e5356f3a5b58c897222433b SHA512 5f0823a1295c4035076654723beb26c90cfd4708dcc72d09c4b72b4c84c295817e1bc95c6799557a0654b9cbae0f8ea421c340d5b914a5f75aa71de07f5388b4

dev-python/kombu/kombu-5.3.4.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-celery
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+	)
+	local EPYTEST_IGNORE=(
+		# obsolete Pyro4
+		t/unit/transport/test_pyro.py
+		# unpackaged azure
+		t/unit/transport/test_azurestoragequeues.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}