app-containers/containers-storage: add 1.40.2

Signed-off-by: Zac Medico <zmedico@gentoo.org>

app-containers/containers-storage/Manifest

@@ -1 +1,2 @@
 DIST containers-storage-1.39.0.tar.gz 3670784 BLAKE2B ad46a33fd51bb95385ed1572a30136bc117bd1d72adb2cbcde2d864fe4ac51dde02b45a8457366d84b889bfcfd62f74c249fc7b5505ca316da08bc03af5c866d SHA512 c3b59361755150adc4a13995a200879175ff1ddf402ce3191311b9e525995ccb73cb8e9c9bc485388cb7517783cd9f9e3a7916c03087dbd5d0be170198b1c861
+DIST containers-storage-1.40.2.tar.gz 3686775 BLAKE2B 980f714e86bb198687b351876e1bb55a6a115e5aa1c73b1c54f63f57ee75727a3b720322b62300c21de30982b5028c82f6ca94d9457e35f9e88d67de96a2f16f SHA512 f4ff23e26d9103debc1709cbbbc6e715d2b9378a3bd7c2e72393841b2eb499ffce525526aa53bd1f7985cda87962a98f1d0b4601610f7cee8c9c879957575ad2

app-containers/containers-storage/containers-storage-1.40.2.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+SRC_URI="https://github.com/containers/storage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+	default
+
+	sed -e 's|: install\.tools|:|' -i Makefile || die
+
+	[[ -f hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+		"hack/btrfs_tag.sh" || die; }
+
+	[[ -f hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+	export -n GOCACHE GOPATH XDG_CACHE_HOME #678856
+	emake GOMD2MAN=go-md2man FFJSON= containers-storage docs
+}
+
+src_install() {
+	dobin "${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	env -u GOFLAGS unshare -m emake local-test-unit || die
+}