sys-apps/s6-rc: 0.4.0.0 version bump

This commit is contained in:
Samuel Holland
2018-01-10 15:34:23 -06:00
committed by William Hubbs
parent d18a87af36
commit da884271f3
2 changed files with 71 additions and 0 deletions
+1
View File
@@ -5,3 +5,4 @@ DIST s6-rc-0.2.0.0.tar.gz 90133 BLAKE2B 2168ecdc28c38673bdf71e73391f6253332da6eb
DIST s6-rc-0.2.0.1.tar.gz 90345 BLAKE2B df5516e49ca3852a8046190d335dba74e20c5d106aca03d81010e41b3a8b56893d1f3339d9188211c009d1e77461fa1d6bce91cd8f1070e93209da59ac898f27 SHA512 d067f1b409146923531f5191e8c9d17c8e846cf4815fac11f08089fe983a55a1d11bba942a036d2d8f48d26390e1350f273bcd8705abcfbff33b9da2984cb8ef
DIST s6-rc-0.2.1.2.tar.gz 90978 BLAKE2B f237704f2ce8ac00ba4b46bbc0bbfe2066592604abadf6c9a518ee9da5dae056b0467c3ddb215c40a647b726beaf5e7da3cb282c45ac66bab7fc4a09558c9fed SHA512 33951996cf1fc1e497c26a90254a916e992c69128134cbc64ed41c76e74c04e55c91036e2c7e836f3eda650fbcd670c52722b5b2d12ec4a3887101eb20c3347f
DIST s6-rc-0.3.0.0.tar.gz 93183 BLAKE2B 0096fe268393192867b1e2d45f9a46c0a76184783e16dbf066891a84a3f6177aec40a4cc78c276126c4588d7d57e4c5a2fa609b1b0276a12a595b99bc7440497 SHA512 d29755f84975b6b2811f55a88cd2b9f1f8383c80ec8aa19e778f74eedf0ae6cb17e55ad96c46bfea7dc3c586a6f10c783db80e8742d2a2e36d3d0062c0f10c06
DIST s6-rc-0.4.0.0.tar.gz 96417 BLAKE2B fea4cfbadd82e8e775e4ba2cc1168fc3932f2f23335efa73f254fb17176954cf4d0c10e16bcecf4d62e9ebe05cb213e370042f86e40cb5a4a5583768fe313a83 SHA512 81ed2b09ab980e9d531e6b919f25fe9819f6144e7e639d488362fd872aead73244a03d83da9abd4cb64c10226c5e6fd163c517dcd59566b32a26841b4814ac21
+70
View File
@@ -0,0 +1,70 @@
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit versionator
DESCRIPTION="service manager for the s6 supervision suite"
HOMEPAGE="https://www.skarnet.org/software/s6-rc/"
SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
LICENSE="ISC"
SLOT="0/$(get_version_component_range 1-2)"
KEYWORDS="~amd64 ~x86"
IUSE="static static-libs"
DEPEND=">=sys-devel/make-3.81
static? (
>=dev-lang/execline-2.3.0.4[static-libs]
>=dev-libs/skalibs-2.6.3.0[static-libs]
>=sys-apps/s6-2.6.2.0[static-libs]
)
!static? (
>=dev-lang/execline-2.3.0.4[static=]
>=dev-libs/skalibs-2.6.3.0
>=sys-apps/s6-2.6.2.0[static=]
)
"
RDEPEND="
>=dev-lang/execline-2.3.0.4:=[!static?]
>=sys-apps/s6-2.6.2.0:=[!static?]
!static? (
>=dev-libs/skalibs-2.6.3.0:=
)
"
DOCS="examples"
HTML_DOCS="doc/*"
src_prepare() {
default
# Remove QA warning about LDFLAGS addition
sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
# configure overrides gentoo's -fstack-protector default
sed -i "/^tryflag CFLAGS -fno-stack-protector$/d" "${S}/configure" || die
}
src_configure() {
econf \
--bindir=/bin \
--dynlibdir=/$(get_libdir) \
--libdir=/usr/$(get_libdir)/${PN} \
--with-dynlib=/$(get_libdir) \
--with-lib=/usr/$(get_libdir)/execline \
--with-lib=/usr/$(get_libdir)/s6 \
--with-lib=/usr/$(get_libdir)/skalibs \
--with-sysdeps=/usr/$(get_libdir)/skalibs \
$(use_enable !static shared) \
$(use_enable static allstatic) \
$(use_enable static static-libc) \
$(use_enable static-libs static)
}
pkg_postinst() {
ewarn "Databases from ${PN}-0.3.0.0 or earlier must be manually upgraded!"
ewarn "See the upgrade notes at ${EPREFIX}/usr/share/doc/${P}/html/upgrade.html"
ewarn "and the documentation for the s6-rc-format-upgrade utility."
}