games-simulation/corsix-th: Revive package following last-rites

This was dropped due to lack of ffmpeg 3 support. This has since been
fixed and it supports ffmpeg 4 too. Last-riting could have been
avoided if the videos USE flag had been added and masked.

I'd like to add a theme-hospital-data package but not today.

Bug: https://bugs.gentoo.org/592700
Package-Manager: Portage-2.3.48, Repoman-2.3.10

games-simulation/corsix-th/Manifest

@@ -0,0 +1 @@
+DIST corsix-th-0.62.tar.gz 3461932 BLAKE2B 5497cc944e51d80216f2b159249268a056193ef48837aa887d9ab8e7fd2e3134ae6f9517a6b2bd9293a97543dcc91dd76d5ce22e212f13dd7c02a79318c7ede6 SHA512 64fe4a6124cbf2e76934f2c081641119ded7292ce89124dee26c99c1d99f1979f9c520e73a403f0de751072bfd049a809773d6a919b7240b8a6e6b7aa1361bf0

games-simulation/corsix-th/corsix-th-0.62.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils desktop eapi7-ver gnome2-utils
+
+MY_PN="CorsixTH"
+MY_PV="$(ver_rs 2 -)"
+
+DESCRIPTION="Open source clone of Theme Hospital"
+HOMEPAGE="http://corsixth.com"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="libav +midi +sound +truetype +videos"
+
+RDEPEND=">=dev-lang/lua-5.1:0
+	>=dev-lua/luafilesystem-1.5
+	>=dev-lua/lpeg-0.9
+	>=dev-lua/luasocket-3.0_rc1-r4
+	media-libs/libsdl2[opengl,video]
+	sound? ( media-libs/sdl2-mixer[midi?] )
+	truetype? ( >=media-libs/freetype-2.5.3:2 )
+	videos? (
+		!libav? ( >=media-video/ffmpeg-2.2.3:0= )
+		libav? ( >=media-video/libav-11.1:0= )
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_AUDIO="$(usex sound)"
+		-DWITH_FREETYPE2="$(usex truetype)"
+		-DWITH_LIBAV="$(usex libav)"
+		-DWITH_MOVIES="$(usex videos)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc {changelog,CONTRIBUTING}.txt
+
+	newicon -s scalable CorsixTH/Original_Logo.svg ${PN}.svg
+	make_desktop_entry ${PN} "${MY_PN}"
+}
+
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }

games-simulation/corsix-th/metadata.xml

@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<longdescription lang="en">
+		A reimplementation of the 1997 Bullfrog business sim Theme
+		Hospital. As well as faithfully recreating the original,
+		CorsixTH adds support for modern operating systems (Windows,
+		Mac OSX and Linux), high resolutions and much more.
+	</longdescription>
+	<use>
+		<flag name="midi">Adds support for background MIDI music via SDL_mixer</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">CorsixTH/CorsixTH</remote-id>
+	</upstream>
+</pkgmetadata>