net-misc/remmina: bump to 1.3.2

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

net-misc/remmina/Manifest

@@ -1,4 +1,5 @@
 DIST Remmina-1.2.31.2.tar.gz 1247378 BLAKE2B 923b131ea2b4cff57d952bcfc2cdac58ad849ce3220dc6e3084b3905f9fe1203443fe0bb2f8a3fa910e7f367299b1b8c1b2373e8b337da7c4ff99ced1951492b SHA512 e66bd77e3b3e8374773e6029a727d814ada09b90a5620452e8ecce19e6f4327aa2e50b8956b292abce2e9329deec79370665a6a6aecbc2d33557381ce5b8db3b
 DIST Remmina-v1.2.31.3.tar.gz 1248295 BLAKE2B da748ceea5aa50702b060075c8e5c4aefe11ca1ebbc301b2951df76208da5998746631ef4c57f5692678e948839a8869a183b777f7046d416a55e5ac5b0d76d1 SHA512 f95c4dcebd833b590fbf0b418854bae66541743bc77cda4b0b97e1e49b158927fa859907619fd532b0660fc30eee80be472e02c38a2afe33e477c4a903a99e28
 DIST Remmina-v1.3.1.tar.gz 1341006 BLAKE2B a4938558e2b3595a62514789a6f748f0e526a20dae23f21c835b6c11a3f321fe564fbc77fa4ea7def97875ada169b73692861707d432b81c3ad51d5630633e67 SHA512 91146a75563f169b39f7aa57fbd846cef1965a0e7c11931acda4bc461407cf3644a1f363b1f46421e5a6ccd1d43d6a89cdb38420dd98fea5ddad1a52ae65d41e
+DIST Remmina-v1.3.2.tar.gz 1362006 BLAKE2B fa6c4f84b6987850944906fac97340c7b17b44b076dadc73143924e35916f8306f8b053e734d1a388e97821b1bcf9eb8109cf787a8d3f4e02f0885fa06a338e6 SHA512 076759acbcb5191b01dda777137eb239a38124d20141e85556b23e3380e5d0a39ff187a4928605ca089d53c6cadd268d0de735795db84672ffa55ea247196ea8
 DIST remmina-1.2.0_rc24.tar.gz 1052140 BLAKE2B 57b3d2ed8a765f98f1ffd3c79df076d07e00329bf95dfddb9094d8bc62838b0f6742b404b4deef0a037bd88259751799e1842fb97313337e11b8f0faed8ad302 SHA512 aab421c580e434ca673be063f3662f1d9128cc83aaee6f9bc6acf6996af0379af6fb99cc63273941c40c6b989653b972de6c43b575ca06bf56ec7c266590c17e

net-misc/remmina/remmina-1.3.2.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils xdg-utils
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt examples gnome-keyring libressl nls spice ssh rdp telepathy vnc zeroconf"
+
+CDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	ayatana? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc2 )
+	gnome-keyring? ( app-crypt/libsecret )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	zeroconf? ( net-dns/avahi[gtk3] )
+"
+DEPEND="${CDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="${CDEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex ayatana)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_AVAHI=$(usex zeroconf)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}