media-libs/vulkan-layers: add 1.4.304.0

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

media-libs/vulkan-layers/Manifest

@@ -1,2 +1,3 @@
 DIST vulkan-layers-1.3.290.0.tar.gz 5270142 BLAKE2B cdd22f6dd3b4da9433cba1c0d0ace16961bad2d61279efca3a0d7e5ad885766f25377036f3418ba3ed4e93beeff717b8b45fc772e9e2ad8750a8aac0aec731d2 SHA512 9f1d512b4bafbcef586789e933f903c383bbb9644d0a978a390da16e03ee2395c39c9c7b622e437e1c74880409df0a3cfc3a44b066cc0efeaee8d1edb9349d26
 DIST vulkan-layers-1.3.296.0.tar.gz 5529046 BLAKE2B 42d321cff2cf7f6c0377b5deff298df60811026a4121dc3315610d53059e5db435494c138dfef5844d71e51536572bd8601dc496e88362f3c68ae0562680ac4f SHA512 457edee35a347456391c9b36bdf5d457f05210b6a8889d0623498582d3385bed474fbd7dae66406d20f70d96238ca752414eaa844b86b431ec7f8cf721d46d08
+DIST vulkan-layers-1.4.304.0.tar.gz 5940153 BLAKE2B 68e4f944383c4f4a574c83735c36b8521fbde4ecaf346cf99c1b925358b4178bacaca75bb5b5fb0684ed15255c331c777bdea44ae7a62def20998971f2d968d9 SHA512 1b13ab2d196b5a9c5e85d0d8679ba0ca03b0c0c18f456ac9fb4314cd283b834883d4a89421a32627e266022dbd1b6684955799906c874e8c325c404738d49a4c

media-libs/vulkan-layers/vulkan-layers-1.4.304.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-ValidationLayers
+PYTHON_COMPAT=( python3_{10..13} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="wayland X"
+
+RDEPEND="~dev-util/spirv-tools-${PV}[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-cpp/robin-hood-hashing-3.11.5-r2
+	~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}]
+	~dev-util/spirv-headers-${PV}
+	~dev-util/vulkan-headers-${PV}
+	~dev-util/vulkan-utility-libraries-${PV}:=[${MULTILIB_USEDEP}]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+
+QA_SONAME="/usr/lib[^/]*/libVkLayer_khronos_validation.so"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=OFF
+	)
+	cmake_src_configure
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name \*.a -delete || die
+}