mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
sys-apps/portage: version bump to 2.3.44
#630292 - parallel pngfix #661834 - rsync: fix _commit_download to drop privileges #661838 - webrsync: support sync-openpgp-key-path #661906 - git: fix key refresh failure to trigger abort Package-Manager: Portage-2.3.44, Repoman-2.3.10
This commit is contained in:
Zac Medico
@@ -5,4 +5,5 @@ DIST portage-2.3.40-bug-656942-bug-657436-937d0156aa06.patch 15214 BLAKE2B 0351f
|
||||
DIST portage-2.3.40-bug-657436-937d0156aa06-1fc628eead43.patch 4131 BLAKE2B 1b051097ef4fb073d22b9ef3472077b4845190ec3839886f462cacbee0996dc4c036549c4beab09025e1bb42f421e5032144e90197e3aa5de08dd7d8d1c50fbb SHA512 5910469816b69afb7a0078dd3b35a5304e2c806ac03ff3949603cf4162900fd9dd1df15661b91a2181528e8406679e525308822a0f6ddf4799c79fa9652c27a9
|
||||
DIST portage-2.3.40.tar.bz2 995122 BLAKE2B 3bfadee6cf57dace32bb4a365850650e13664202f3b16bf75821ff6226e85da823785ac87875fa82bd5cf1b953d638773819495f73f471c06ffd6926518df1ac SHA512 ded128c1941664fab6bc95f05115ec08900fddaedd1b6f12afa48da024531ee8939134d49759e09995c76a95e41beafdbf5528a5b62d3bf21c826ab1ac0cd1c5
|
||||
DIST portage-2.3.43.tar.bz2 998958 BLAKE2B 28874db4dc989e550aa4a54a91b8ad303f17b2444d6e23a539672c4742ec62c4228f6070f0d36a31b90d1d32998bc4825de706e5a6635bb7051e5b592f8e3eac SHA512 b8f3ab4f700cc72364b38153451a32a371d0b222feacfb206017be7182596cbc83b7e036025d07399e8b32cf3e3889dbc6ba8d26a64fbfc4253f1506da3c8252
|
||||
DIST portage-2.3.44.tar.bz2 1008301 BLAKE2B de370ce9f455e6f778dece3be78703f23852caa9185d79b54e6fc35939923f2a28c91aa372a4ae601872b7933970b536e935ea1f8cb8604bf1547dced3d70c33 SHA512 e491998958439dc27fed6e6f9a3b87867c881cae6ec1fe9515db3277fb2f6f866b6ea6298bae5bf6553591ebe75719a5f379ae92e4aede440ac620ce4af9160d
|
||||
DIST portage-2.3.8.tar.bz2 938062 BLAKE2B 3f7bedf6268131a3b3539d53c8a7bb069b533b3a78e5eec521b6201439c8ee5e66996e798fe295561d0a94bfcd32adf414d4f8b5e7a93035cea09749406e64a3 SHA512 4b4b2de20323799b9b0f7a8812f939aa9a96d2744a0f65ad5287ba49744c491b55169cdb21f2885317a6a7c960d2070775ffd798f247b44eebc677c33c271eb8
|
||||
|
||||
285
sys-apps/portage/portage-2.3.44.ebuild
Normal file
285
sys-apps/portage/portage-2.3.44.ebuild
Normal file
@@ -0,0 +1,285 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=5
|
||||
|
||||
PYTHON_COMPAT=(
|
||||
pypy
|
||||
python3_4 python3_5 python3_6 python3_7
|
||||
python2_7
|
||||
)
|
||||
PYTHON_REQ_USE='bzip2(+),threads(+)'
|
||||
|
||||
inherit distutils-r1 systemd
|
||||
|
||||
DESCRIPTION="Portage is the package management and distribution system for Gentoo"
|
||||
HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd"
|
||||
SLOT="0"
|
||||
IUSE="build doc epydoc gentoo-dev +ipc +native-extensions +rsync-verify selinux xattr"
|
||||
|
||||
DEPEND="!build? ( $(python_gen_impl_dep 'ssl(+)') )
|
||||
>=app-arch/tar-1.27
|
||||
dev-lang/python-exec:2
|
||||
>=sys-apps/sed-4.0.5 sys-devel/patch
|
||||
doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
|
||||
epydoc? ( >=dev-python/epydoc-2.0[$(python_gen_usedep 'python2*')] )"
|
||||
# Require sandbox-2.2 for bug #288863.
|
||||
# For xattr, we can spawn getfattr and setfattr from sys-apps/attr, but that's
|
||||
# quite slow, so it's not considered in the dependencies as an alternative to
|
||||
# to python-3.3 / pyxattr. Also, xattr support is only tested with Linux, so
|
||||
# for now, don't pull in xattr deps for other kernels.
|
||||
# For whirlpool hash, require python[ssl] (bug #425046).
|
||||
# For compgen, require bash[readline] (bug #445576).
|
||||
# app-portage/gemato goes without PYTHON_USEDEP since we're calling
|
||||
# the executable.
|
||||
RDEPEND="
|
||||
>=app-arch/tar-1.27
|
||||
dev-lang/python-exec:2
|
||||
!build? (
|
||||
>=sys-apps/sed-4.0.5
|
||||
app-shells/bash:0[readline]
|
||||
>=app-admin/eselect-1.2
|
||||
$(python_gen_cond_dep 'dev-python/pyblake2[${PYTHON_USEDEP}]' \
|
||||
python{2_7,3_4,3_5} pypy)
|
||||
rsync-verify? (
|
||||
>=app-portage/gemato-12.1[${PYTHON_USEDEP}]
|
||||
app-crypt/openpgp-keys-gentoo-release
|
||||
>=app-crypt/gnupg-2.2.4-r2[ssl(-)]
|
||||
)
|
||||
)
|
||||
elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
|
||||
elibc_glibc? ( >=sys-apps/sandbox-2.2 )
|
||||
elibc_musl? ( >=sys-apps/sandbox-2.2 )
|
||||
elibc_uclibc? ( >=sys-apps/sandbox-2.2 )
|
||||
>=app-misc/pax-utils-0.1.17
|
||||
selinux? ( >=sys-libs/libselinux-2.0.94[python,${PYTHON_USEDEP}] )
|
||||
xattr? ( kernel_linux? (
|
||||
>=sys-apps/install-xattr-0.3
|
||||
$(python_gen_cond_dep 'dev-python/pyxattr[${PYTHON_USEDEP}]' \
|
||||
python2_7 pypy)
|
||||
) )
|
||||
!<app-admin/logrotate-3.8.0
|
||||
!<app-portage/repoman-2.3.10"
|
||||
PDEPEND="
|
||||
!build? (
|
||||
>=net-misc/rsync-2.6.4
|
||||
userland_GNU? ( >=sys-apps/coreutils-6.4 )
|
||||
)"
|
||||
# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
|
||||
# NOTE: FEATURES=installsources requires debugedit and rsync
|
||||
|
||||
REQUIRED_USE="epydoc? ( $(python_gen_useflags 'python2*') )"
|
||||
|
||||
SRC_ARCHIVES="https://dev.gentoo.org/~zmedico/portage/archives"
|
||||
|
||||
prefix_src_archives() {
|
||||
local x y
|
||||
for x in ${@}; do
|
||||
for y in ${SRC_ARCHIVES}; do
|
||||
echo ${y}/${x}
|
||||
done
|
||||
done
|
||||
}
|
||||
|
||||
TARBALL_PV=${PV}
|
||||
SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
|
||||
$(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)"
|
||||
|
||||
pkg_setup() {
|
||||
use epydoc && DISTUTILS_ALL_SUBPHASE_IMPLS=( python2.7 )
|
||||
}
|
||||
|
||||
python_prepare_all() {
|
||||
distutils-r1_python_prepare_all
|
||||
|
||||
if use gentoo-dev; then
|
||||
einfo "Disabling --dynamic-deps by default for gentoo-dev..."
|
||||
sed -e 's:\("--dynamic-deps", \)\("y"\):\1"n":' \
|
||||
-i lib/_emerge/create_depgraph_params.py || \
|
||||
die "failed to patch create_depgraph_params.py"
|
||||
|
||||
einfo "Enabling additional FEATURES for gentoo-dev..."
|
||||
echo 'FEATURES="${FEATURES} ipc-sandbox network-sandbox strict-keepdir"' \
|
||||
>> cnf/make.globals || die
|
||||
fi
|
||||
|
||||
if use native-extensions; then
|
||||
printf "[build_ext]\nportage-ext-modules=true\n" >> \
|
||||
setup.cfg || die
|
||||
fi
|
||||
|
||||
if ! use ipc ; then
|
||||
einfo "Disabling ipc..."
|
||||
sed -e "s:_enable_ipc_daemon = True:_enable_ipc_daemon = False:" \
|
||||
-i lib/_emerge/AbstractEbuildProcess.py || \
|
||||
die "failed to patch AbstractEbuildProcess.py"
|
||||
fi
|
||||
|
||||
if use xattr && use kernel_linux ; then
|
||||
einfo "Adding FEATURES=xattr to make.globals ..."
|
||||
echo -e '\nFEATURES="${FEATURES} xattr"' >> cnf/make.globals \
|
||||
|| die "failed to append to make.globals"
|
||||
fi
|
||||
|
||||
if use build || ! use rsync-verify; then
|
||||
sed -e '/^sync-rsync-verify-metamanifest/s|yes|no|' \
|
||||
-i cnf/repos.conf || die "sed failed"
|
||||
fi
|
||||
|
||||
if [[ -n ${EPREFIX} ]] ; then
|
||||
einfo "Setting portage.const.EPREFIX ..."
|
||||
sed -e "s|^\(SANDBOX_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/bin/sandbox\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(FAKEROOT_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/bin/fakeroot\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(BASH_BINARY[[:space:]]*=[[:space:]]*\"\)\(/bin/bash\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(MOVE_BINARY[[:space:]]*=[[:space:]]*\"\)\(/bin/mv\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(PRELINK_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/sbin/prelink\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(EPREFIX[[:space:]]*=[[:space:]]*\"\).*|\\1${EPREFIX}\"|" \
|
||||
-i lib/portage/const.py || \
|
||||
die "Failed to patch portage.const.EPREFIX"
|
||||
|
||||
einfo "Prefixing shebangs ..."
|
||||
while read -r -d $'\0' ; do
|
||||
local shebang=$(head -n1 "$REPLY")
|
||||
if [[ ${shebang} == "#!"* && ! ${shebang} == "#!${EPREFIX}/"* ]] ; then
|
||||
sed -i -e "1s:.*:#!${EPREFIX}${shebang:2}:" "$REPLY" || \
|
||||
die "sed failed"
|
||||
fi
|
||||
done < <(find . -type f -print0)
|
||||
|
||||
einfo "Adjusting make.globals ..."
|
||||
sed -e "s|\(/usr/portage\)|${EPREFIX}\\1|" \
|
||||
-e "s|^\(PORTAGE_TMPDIR=\"\)\(/var/tmp\"\)|\\1${EPREFIX}\\2|" \
|
||||
-i cnf/make.globals || die "sed failed"
|
||||
|
||||
einfo "Adjusting repos.conf ..."
|
||||
sed -e "s|^\(location = \)\(/usr/portage\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(sync-openpgp-key-path = \)\(.*\)|\\1${EPREFIX}\\2|" \
|
||||
-i cnf/repos.conf || die "sed failed"
|
||||
if use prefix-guest ; then
|
||||
sed -e "s|^\(main-repo = \).*|\\1gentoo_prefix|" \
|
||||
-e "s|^\\[gentoo\\]|[gentoo_prefix]|" \
|
||||
-e "s|^\(sync-uri = \).*|\\1rsync://rsync.prefix.bitzolder.nl/gentoo-portage-prefix|" \
|
||||
-i cnf/repos.conf || die "sed failed"
|
||||
fi
|
||||
|
||||
einfo "Adding FEATURES=force-prefix to make.globals ..."
|
||||
echo -e '\nFEATURES="${FEATURES} force-prefix"' >> cnf/make.globals \
|
||||
|| die "failed to append to make.globals"
|
||||
fi
|
||||
|
||||
cd "${S}/cnf" || die
|
||||
if [ -f "make.conf.example.${ARCH}".diff ]; then
|
||||
patch make.conf.example "make.conf.example.${ARCH}".diff || \
|
||||
die "Failed to patch make.conf.example"
|
||||
else
|
||||
eerror ""
|
||||
eerror "Portage does not have an arch-specific configuration for this arch."
|
||||
eerror "Please notify the arch maintainer about this issue. Using generic."
|
||||
eerror ""
|
||||
fi
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
local targets=()
|
||||
use doc && targets+=( docbook )
|
||||
use epydoc && targets+=( epydoc )
|
||||
|
||||
if [[ ${targets[@]} ]]; then
|
||||
esetup.py "${targets[@]}"
|
||||
fi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
esetup.py test
|
||||
}
|
||||
|
||||
python_install() {
|
||||
# Install sbin scripts to bindir for python-exec linking
|
||||
# they will be relocated in pkg_preinst()
|
||||
distutils-r1_python_install \
|
||||
--system-prefix="${EPREFIX}/usr" \
|
||||
--bindir="$(python_get_scriptdir)" \
|
||||
--docdir="${EPREFIX}/usr/share/doc/${PF}" \
|
||||
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
|
||||
--portage-bindir="${EPREFIX}/usr/lib/portage/${EPYTHON}" \
|
||||
--sbindir="$(python_get_scriptdir)" \
|
||||
--sysconfdir="${EPREFIX}/etc" \
|
||||
"${@}"
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
local targets=()
|
||||
use doc && targets+=(
|
||||
install_docbook
|
||||
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
|
||||
)
|
||||
use epydoc && targets+=(
|
||||
install_epydoc
|
||||
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
|
||||
)
|
||||
|
||||
# install docs
|
||||
if [[ ${targets[@]} ]]; then
|
||||
esetup.py "${targets[@]}"
|
||||
fi
|
||||
|
||||
systemd_dotmpfilesd "${FILESDIR}"/portage-ccache.conf
|
||||
|
||||
# Due to distutils/python-exec limitations
|
||||
# these must be installed to /usr/bin.
|
||||
local sbin_relocations='archive-conf dispatch-conf emaint env-update etc-update fixpackages regenworld'
|
||||
einfo "Moving admin scripts to the correct directory"
|
||||
dodir /usr/sbin
|
||||
for target in ${sbin_relocations}; do
|
||||
einfo "Moving /usr/bin/${target} to /usr/sbin/${target}"
|
||||
mv "${ED}usr/bin/${target}" "${ED}usr/sbin/${target}" || die "sbin scripts move failed!"
|
||||
done
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
# comment out sanity test until it is fixed to work
|
||||
# with the new PORTAGE_PYM_PATH
|
||||
#if [[ $ROOT == / ]] ; then
|
||||
## Run some minimal tests as a sanity check.
|
||||
#local test_runner=$(find "${ED}" -name runTests)
|
||||
#if [[ -n $test_runner && -x $test_runner ]] ; then
|
||||
#einfo "Running preinst sanity tests..."
|
||||
#"$test_runner" || die "preinst sanity tests failed"
|
||||
#fi
|
||||
#fi
|
||||
|
||||
# elog dir must exist to avoid logrotate error for bug #415911.
|
||||
# This code runs in preinst in order to bypass the mapping of
|
||||
# portage:portage to root:root which happens after src_install.
|
||||
keepdir /var/log/portage/elog
|
||||
# This is allowed to fail if the user/group are invalid for prefix users.
|
||||
if chown portage:portage "${ED}"var/log/portage{,/elog} 2>/dev/null ; then
|
||||
chmod g+s,ug+rwx "${ED}"var/log/portage{,/elog}
|
||||
fi
|
||||
|
||||
if has_version ">=${CATEGORY}/${PN}-2.3.1" && \
|
||||
has_version "<${CATEGORY}/${PN}-2.3.3"; then
|
||||
SYNC_DEPTH_UPGRADE=true
|
||||
else
|
||||
SYNC_DEPTH_UPGRADE=false
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if ${SYNC_DEPTH_UPGRADE}; then
|
||||
ewarn "Please note that this release no longer respects sync-depth for"
|
||||
ewarn "git repositories. There have been too many problems and"
|
||||
ewarn "performance issues. See bugs 552814, 559008"
|
||||
fi
|
||||
einfo ""
|
||||
einfo "This release of portage NO LONGER contains the repoman code base."
|
||||
einfo "Repoman has its own ebuild and release package."
|
||||
einfo "For repoman functionality please emerge app-portage/repoman"
|
||||
einfo "Please report any bugs you may encounter."
|
||||
einfo ""
|
||||
}
|
||||
Reference in New Issue
Block a user