mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
gnome-base/nautilus: add 47.5
Upstream disable tracker tests due to they also hitting issues
with their sandbox system:
4834a4b3bf
Bug: https://bugs.gentoo.org/835087
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Pacho Ramos
@@ -1,3 +1,4 @@
|
||||
DIST nautilus-46.2.tar.xz 3238060 BLAKE2B 6a3d79632a70d1bee969d5c71dbc2b64ae2365eff2fdc0dbe8f6030d20488c3bf3321750e0613f676912ee324a33136de805ae841a0841e7aef071582d7e2092 SHA512 6613342d7904a5516bd0035b72b6071cebcb1aba6083f0bbcb4e939acf74b9bb1a407090b91a2a8b73f00eb236d0d3a4a8e288681bfc63a31672b85326019150
|
||||
DIST nautilus-47.1.tar.xz 3262924 BLAKE2B e5e889445a8ce0518a052aa3917da12d3b53da739c72b8fa22a9687bb5c90998f023b2e8ca334729bf0fd3bb70015afb318bb1d03185947dd8ee349dc58e5d46 SHA512 132139aa3d39d220ec5edf112bda97a0dd0c5f5978f7390f897679b78d30efeab63e6330ef1f9593c193f28d96919621ff4fe5a66992ee1f10b69ab9a240255b
|
||||
DIST nautilus-47.4.tar.xz 3249448 BLAKE2B 4f8dc9076ba5654f5fab63b353678d5b56862ec8380c3b2f93850c8b3e64f79bee05c2214f34851afffd049d9121f0adf4aa4866d591aa916b5aa80f6563cf85 SHA512 5fc1a11229dec9d5578f118d853c687a495659617f7c88a6abbd5cca64ae0d06466ddebd1193b20c93c2ecfd965993291395e7550df2f9fffba628894d5dbc41
|
||||
DIST nautilus-47.5.tar.xz 3249756 BLAKE2B 21ef0db9076392b0068841257ee5304b53164f86b4fdd22c638dfa5ec1505331e3933cd1a3e0468f7f14e41aa9ce0c18a64c69f7e1ef82fc753e1b16fa8b1468 SHA512 671fb689e05cae704db1f9031a6cb49ef566150541346e86278e634b0c63f51c955468f47a880f036df71fcb72a8ac1e5bc1d6f028e0e14935386d7d2a5709cb
|
||||
|
||||
117
gnome-base/nautilus/nautilus-47.5.ebuild
Normal file
117
gnome-base/nautilus/nautilus-47.5.ebuild
Normal file
@@ -0,0 +1,117 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit gnome.org gnome2-utils meson readme.gentoo-r1 virtualx xdg
|
||||
|
||||
DESCRIPTION="Default file manager for the GNOME desktop"
|
||||
HOMEPAGE="https://apps.gnome.org/Nautilus/"
|
||||
|
||||
LICENSE="GPL-3+ LGPL-2.1+"
|
||||
SLOT="0"
|
||||
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
||||
|
||||
IUSE="+cloudproviders doc gnome +gstreamer +introspection +previewer selinux"
|
||||
REQUIRED_USE="doc? ( introspection )"
|
||||
|
||||
DEPEND="
|
||||
>=dev-libs/glib-2.79.0:2
|
||||
>=media-libs/gexiv2-0.14.2
|
||||
>=x11-libs/gdk-pixbuf-2.30.0:2
|
||||
gstreamer? ( media-libs/gstreamer:1.0
|
||||
media-libs/gst-plugins-base:1.0 )
|
||||
>=app-arch/gnome-autoar-0.4.4
|
||||
>=gnome-base/gnome-desktop-43:4=
|
||||
>=gnome-base/gsettings-desktop-schemas-42
|
||||
>=gui-libs/gtk-4.15.2:4[introspection?]
|
||||
>=gui-libs/libadwaita-1.6_beta:1
|
||||
>=dev-libs/libportal-0.7:=[gtk]
|
||||
>=x11-libs/pango-1.28.3
|
||||
selinux? ( >=sys-libs/libselinux-2.0 )
|
||||
>=app-misc/tinysparql-3.0:3
|
||||
cloudproviders? ( >=net-libs/libcloudproviders-0.3.1 )
|
||||
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
|
||||
"
|
||||
# Uses org.freedesktop.Tracker.Miner.Files gsettings schema from localsearch
|
||||
RDEPEND="${DEPEND}
|
||||
>=app-misc/localsearch-3.0:3=
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-util/gdbus-codegen-2.51.2
|
||||
dev-util/glib-utils
|
||||
doc? (
|
||||
app-text/docbook-xml-dtd:4.1.2
|
||||
dev-util/gi-docgen
|
||||
)
|
||||
>=sys-devel/gettext-0.19.8
|
||||
virtual/pkgconfig
|
||||
test? ( sys-apps/dbus )
|
||||
"
|
||||
PDEPEND="
|
||||
gnome? ( x11-themes/adwaita-icon-theme )
|
||||
previewer? ( >=gnome-extra/sushi-0.1.9 )
|
||||
>=gnome-base/gvfs-1.14[gtk(+)]
|
||||
" # Need gvfs[gtk] for recent:/// support; always built (without USE=gtk) since gvfs-1.34
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/43.0-optional-gstreamer.patch # Allow controlling audio-video-properties build
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
xdg_environment_reset
|
||||
|
||||
# Disable -Werror
|
||||
sed -e '/-Werror=/d' -i meson.build || die
|
||||
|
||||
if use previewer; then
|
||||
DOC_CONTENTS="nautilus uses gnome-extra/sushi to preview media files.
|
||||
To activate the previewer, select a file and press space; to
|
||||
close the previewer, press space again."
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_use doc docs)
|
||||
-Dextensions=true # image file properties, also required for -Dgstreamer=true
|
||||
$(meson_use introspection)
|
||||
-Dpackagekit=false
|
||||
$(meson_use selinux)
|
||||
$(meson_use cloudproviders)
|
||||
-Dtests=$(usex test all none)
|
||||
|
||||
$(meson_use gstreamer) # gstreamer audio-video-properties extension
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
use previewer && readme.gentoo_create_doc
|
||||
meson_src_install
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# Avoid dconf that looks at XDG_DATA_DIRS, which can sandbox fail if flatpak is installed
|
||||
gnome2_environment_reset
|
||||
# GIO_USE_VOLUME_MONITOR=unix due to https://gitlab.gnome.org/GNOME/gvfs/-/issues/629#note_1467280
|
||||
GIO_USE_VOLUME_MONITOR=unix XDG_SESSION_TYPE=x11 virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
|
||||
if use previewer; then
|
||||
readme.gentoo_print_elog
|
||||
else
|
||||
elog "To preview media files, emerge nautilus with USE=previewer"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_pkg_postrm
|
||||
gnome2_schemas_update
|
||||
}
|
||||
Reference in New Issue
Block a user