dev-java/openjdk-jre-bin: bump to 8.265_p01

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -2,3 +2,4 @@ DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.7_10.tar.gz 42917723 BLAKE2B c5635b37
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.8_10.tar.gz 42904191 BLAKE2B cfd04b2a422e95465cd2938449f7632d29fe655eadadf5745045db6eb74625dffa0e02d8713a93e0bc8fa7da6dc57116fbbd9217a9b30723becd5b9eaceefccd SHA512 55ab4c6122422f4765542df747bce5c65bc78e0e5f4fff4b7efc95342d81eb34d72dbdc13c820781c626f92a2c3687161d0c7edfbe4f83c455c75fcecf8ae3d0
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u252b09.tar.gz 41104123 BLAKE2B 52a9f288054c4a96ed5d70c2c9c6cf14ceb32262ec3a38f547286518ccc14a4695d330adc19e272436c0a7154771cddd9b0672b05beb6d5013c44c69be0ad25a SHA512 b1b0627e8495b11e0ef3e4ecb387d92537bb97b3f3045213658d48b6f2dffa0bc975b1bc92e84c487152b43d1f0ee0449730bf84dd62d98d13354bf73d3a0a20
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u262b10.tar.gz 41755965 BLAKE2B b417d12ba18f58fec1e692a567bd5c0551fcbe023370fe52c2e525692d0d2151d4c296f86e6f4e3b1178e8f933ec6ddb9559e358c5d080cc2dba94ce38680ab5 SHA512 63d65c576d40b798dbbf2c6923151d07ba74312d8e8b6dc722d4358c38855a3a5c9e9e7c267569d390065c4dcc7f4bcfddc3f78e8388b4faef1a61501e2b7b8c
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u265b01.tar.gz 41757024 BLAKE2B 39c184654dd5c4c17c617a48e962a392e3a4aaebe56a4286b6e5b0e980345b7260effbc54e2b197f8b747c57856e5260a048cf572cd4f375a2b38f3abebbde2f SHA512 01090a26bb18d226da19c82fca173f0d994ba56562178757347b565d39989b6735f5ff37bb22163c9ea270380fe922098bd0efa87d52615b50cde9f0e8291095

dev-java/openjdk-jre-bin/openjdk-jre-bin-8.265_p01.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+
+IUSE="alsa cups headless-awt nsplugin selinux webstart"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+PDEPEND="
+	webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
+	nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED%/}/${dest#/}"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym ../../../../../etc/ssl/certs/java/cacerts \
+		"${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}