dev-util/sysdig: Bump to 0.20.0

dev-util/sysdig/Manifest

@@ -1 +1,2 @@
 DIST sysdig-0.19.1.tar.gz 742149 BLAKE2B 413c03816573b35c35c9a5fc305e8103c118feabe6555b83e029acd5683ad4a361eec07624ea0b0bb8d081fdb62ce0b455ff2fa2ebdc0420546a848af284e25c SHA512 a3947ecd2019af75d787d956b3931dc1aac593279256a92fc02ff0d7e0a85f23786ab821da9bf3ec55430e4da56f70c8583d1b5d24782b426f7deb6f1fca69eb
+DIST sysdig-0.20.0.tar.gz 750798 BLAKE2B 9e5c57abf81531f6643c661e539b06b33bda352eb3072e1ed686da3dc68550d90c94a4273554c2dd4752c73357f0bfe52bcbd10ad8551d8a2876552acf31292a SHA512 2549c8e2d0db0abd95e31272837fe5072c4c26926b2d17348bd8d73177bc024bab0a8503aa427f9134d8ca0a0bbc05fe97495933c3b8236db5fcb74df7c1efb2

dev-util/sysdig/sysdig-0.20.0.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}