dev-python/rdflib: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/rdflib/Manifest

@@ -1,2 +1 @@
-DIST rdflib-7.5.0.gh.tar.gz 5084540 BLAKE2B 5ed4c429d3b31292d37a262c41da0549a65d0a4c44d3165a829677543b6b851cf26800f38af59592759c4bbd2915c4b54acfa7d735c9536499db0f6d63059293 SHA512 54e7078b7784145737e6dce104a868a6c9a6526e7c09947b75594035c689383259a3e913139bda9e17ace07ecf3862099532e612cc1d72fbcb37301d307d8ad1
 DIST rdflib-7.6.0.gh.tar.gz 5175542 BLAKE2B d5e9f9ce4bea6c5d52b62b9271cd182368cd81ab90a72c0a356238c1744a0d03c077bed5801add5e7090db5ea3a947e0d6cfa1a4f785a01336d5dc6951951241 SHA512 464fe52d968bd8618cef5ab99c28cb465b9b07287a28049d7e2916c1dac4971187be5794b4007509f875fb28cb0c198fd2e1d9338893ecdd00ed5d0d6865ee98

dev-python/rdflib/rdflib-7.5.0.ebuild

@@ -1,76 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=poetry
-PYTHON_COMPAT=( python3_{11..14} )
-PYTHON_REQ_USE="sqlite?,threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="RDF library containing a triple store and parser/serializer"
-HOMEPAGE="
-	https://github.com/RDFLib/rdflib/
-	https://pypi.org/project/rdflib/
-"
-# tests removed in 7.1.2
-SRC_URI="
-	https://github.com/RDFLib/rdflib/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
-IUSE="examples sqlite"
-
-RDEPEND="
-	dev-python/html5lib[${PYTHON_USEDEP}]
-	<dev-python/pyparsing-4[${PYTHON_USEDEP}]
-	>=dev-python/pyparsing-3.2.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/requests[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=()
-# (xdist fails to collect)
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	# doctests require internet
-	sed -i -e '/doctest-modules/d' pyproject.toml || die
-
-	# we disable pytest-cov
-	sed -i -e 's@, no_cover: None@@' test/test_misc/test_plugins.py || die
-
-	# allow regular html5lib, html5rdf is a fork with minimal changes:
-	# removing six dep (which is kinda good) and bundling webencodings
-	# (which is horrible)
-	find -name '*.py' -exec sed -i -e 's:html5rdf:html5lib:g' {} + || die
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# tests try to install stuff via pip
-		test/test_misc/test_plugins.py
-		# triggers a GC error (and stack overflow was expected anyway)
-		'test/test_sparql/test_translate_algebra.py::test_roundtrip[test_other__service1]'
-	)
-
-	epytest -m "not webtest and not testcontainer"
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}