x11-libs/xapps: 1.8.4 version bump

Update xapps to 1.8.4. Switch to EAPI=7 and clean
up eclass usage and dependencies. Fix installation
of pygobject files for multiple targets.

Bug: https://bugs.gentoo.org/672676
Bug: https://bugs.gentoo.org/718316
Bug: https://bugs.gentoo.org/704532
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

x11-libs/xapps/Manifest

@@ -1 +1,2 @@
 DIST xapps-1.4.2.tar.gz 69709 BLAKE2B 514e4cb2e614ccd9fa303625eb5ffb818847447b29d6d989c2abdc90b6b9840dac6124d8484b71ffc2e489a925f83dae597c0904aa79cd5d5a0c27d44420da96 SHA512 2d16bd893a16876270c41d755c62ca454f561931750acc719c480e63036b70dca8dae25e6a313f13ed0daae09fd650e0efcef9d272c405ccd9c04147aaf59fe2
+DIST xapps-1.8.4.tar.gz 179340 BLAKE2B f6558b87320cbd73e73c5294f48a3c0c94c7239abc9ede9cd88e66ccd53fd0c9cba9c638837efbd5eecd8a4f372262fde759e05ba9e97ad9955ab74464c34c21 SHA512 483e8e334d4883e2172e06835d690d20af2752fcc195f63776053b83abc0ffcb25c757633450a02b153e70e67e98c477754de12169c167a2f9f3fea103e12bad

x11-libs/xapps/metadata.xml

@@ -13,6 +13,10 @@
 		<email>proxy-maint@gentoo.org</email>
 		<name>Proxy Maintainers</name>
 	</maintainer>
+	<maintainer type="person">
+		<email>sparky@bluefang-logic.com</email>
+		<name>Matthew Turnbull</name>
+	</maintainer>
 	<upstream>
 		<remote-id type="github">linuxmint/xapps</remote-id>
 	</upstream>

x11-libs/xapps/xapps-1.8.4.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+VALA_USE_DEPEND="vapigen"
+inherit gnome2-utils vala meson python-r1 xdg-utils
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapps/"
+LICENSE="GPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapps/archive/${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.37.3:2
+	dev-libs/gobject-introspection:0=
+	gnome-base/libgnomekbd
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.3.16:3[introspection?]
+	x11-libs/libxkbfile
+	dev-libs/libdbusmenu[gtk3]
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gtk-doc )
+	$(vala_depend)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.40.6
+	sys-devel/gettext
+"
+
+src_prepare() {
+	xdg_environment_reset
+	vala_src_prepare
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/bin" || die
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${PYTHON}" -c 'import gi;print(gi._overridesdir)') || die
+		einfo "gobject overrides directory: $PYTHON_GI_OVERRIDESDIR"
+		mkdir -p "${ED}/$PYTHON_GI_OVERRIDESDIR/"
+		cp -r "${D}"/pygobject/* "${ED}/$PYTHON_GI_OVERRIDESDIR/" || die
+		python_optimize
+	}
+	python_foreach_impl install_pygobject_override
+	rm -rf "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}