Merge updates from master

2026-09-24 04:59:14 -07:00 · 2026-04-11 08:45:54 +00:00
parent a15df38abe 2ad3147158
commit d83f4738da
5 changed files with 191 additions and 4 deletions
--- a/dev-java/bndlib/bndlib-7.2.1.ebuild
+++ b/dev-java/bndlib/bndlib-7.2.1.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}/bnd-${PV/_rc/.RC}"

 LICENSE="Apache-2.0 EPL-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~ppc64"
+KEYWORDS="amd64 ~arm64 ~ppc64"

 CP_DEPEND="
 	~dev-java/bnd-annotation-${PV}:0
--- a/dev-lang/ruby/ruby-3.2.10.ebuild
+++ b/dev-lang/ruby/ruby-3.2.10.ebuild
@@ -19,7 +19,7 @@ SLOT=$(ver_cut 1-2)
 MY_SUFFIX=$(ver_rs 1 '' ${SLOT})
 RUBYVERSION=${SLOT}.0

-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
 IUSE="berkdb debug doc examples gdbm jemalloc jit socks5 +ssl static-libs systemtap tk valgrind xemacs"

 RDEPEND="
--- a/sys-apps/fwupd-efi/fwupd-efi-1.8.ebuild
+++ b/sys-apps/fwupd-efi/fwupd-efi-1.8.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2021-2025 Gentoo Authors
+# Copyright 2021-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2

 EAPI=8
@@ -15,7 +15,7 @@ if [[ ${PV} = *9999 ]]; then
 	EGIT_REPO_URI="https://github.com/fwupd/fwupd-efi.git"
 else
 	SRC_URI="https://github.com/fwupd/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+	KEYWORDS="amd64 ~arm ~arm64 ~loong ~riscv x86"
 fi

 LICENSE="LGPL-2.1+"
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -3,3 +3,5 @@ DIST fwupd-2.0.18.tar.xz 5100336 BLAKE2B c2de6d314b1c146f487c48e45b203e299b0aa3f
 DIST fwupd-2.0.18.tar.xz.asc 488 BLAKE2B 6b0a268a5bc454c8f3d20630b89b16ae1ce036328feaee52c19723685b72938b74764cb9ea3c315221f798d0c92da5bf387f559521715f5753371d2460f2fb8a SHA512 ac3493b66de35d1e2b9f6ecde2ffb8b4c857b874e1c377bff7887e81670f704d06303d2f7d9fc9bca1de4da201b8bce87854ba1685ebc386fc9b68f82ee403f0
 DIST fwupd-2.0.20.tar.xz 5113876 BLAKE2B a12b243e4725627e93bf6e6f9070affe5168207a2de7c468a3136a8b0877644e50919ec8445ddfb3fd283375914975a47f99dd9f60689bb17f87e5e8ff68665c SHA512 7be2b343349b92994c9fa6450cbddb8975fdbaa34cfd28e9b90367f560ba9dd9e6801e1941a16fb41d23a5f94593fb1414ac9ca65377a9bb30bce8119390cfc8
 DIST fwupd-2.0.20.tar.xz.asc 488 BLAKE2B bd3d5a5cf601916a103accf7efc8600dd2741a780b4ce807c3ec9d48790c41d01e737be5632ef4db836235178436a6b3b9553c4f034dd9a84a0187c791229603 SHA512 76a4e4bdfa09fd72d495ef17c7a00f8336b4089f6104f637b03c0183c401ad0e6449785e275de60d54967827d93d881956fe5fb7467a4f390378590e730537e5
+DIST fwupd-2.1.1.tar.xz 5222632 BLAKE2B aab16941695d04417d140958435304a9b6fce6eeccd0660c4d4a193b21983286064b8b260ba83ffb1779fbd8a15e0322fb1bfa89c5df8aaef1c73447817c23bf SHA512 44be2906b8f1f3b1b3029da45e966ada1fc617e26e8f6df7b90bd5230ee880ac263fc47601fef6c2cf083ec3f6e98908a0b7051e69422aca03df0f126c706e91
+DIST fwupd-2.1.1.tar.xz.asc 488 BLAKE2B 6ca785878673c05866492f46c0180f3d4561533b55663e44f4e926aba95267be3f9552ad1b6144d3382406967e1e49c713e372ddf8d8f01d784ff4c09bf7d189 SHA512 77af140e23bf2bc476a6a39b2ea80d6952df81f2d882d0492d76a025ecccd7247699a21afb490652ffc03dc3bf4f8b2c8a0130b46bf4e87682c03ee25f3f4611
--- a/sys-apps/fwupd/fwupd-2.1.1.ebuild
+++ b/sys-apps/fwupd/fwupd-2.1.1.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/hughsie.asc
+inherit meson python-single-r1 vala verify-sig udev xdg
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="
+	https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz
+	verify-sig? ( https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz.asc )
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="amdgpu +archive bash-completion bluetooth cbor elogind flashrom gnutls gtk-doc introspection lzma minimal modemmanager nvme policykit seccomp spi synaptics systemd test tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	minimal? ( !introspection )
+	spi? ( lzma )
+	seccomp? ( systemd )
+	synaptics? ( gnutls )
+	test? ( archive )
+	uefi? ( gnutls )
+"
+# DBus permission failures in 2.0.20 and then other new issues in 2.1.1
+# Likely needs wrangling for ebuild environment
+RESTRICT="!test? ( test ) test"
+
+BDEPEND="$(vala_depend)
+	$(python_gen_cond_dep '
+		dev-python/jinja2[${PYTHON_USEDEP}]
+	')
+	>=dev-build/meson-1.3.2
+	virtual/pkgconfig
+	sys-apps/hwdata
+	gtk-doc? (
+		$(python_gen_cond_dep '
+			>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+		')
+		>=dev-util/gi-docgen-2021.1
+	)
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
+	test? (
+		net-libs/gnutls[tools]
+	)
+	uefi? (
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[cairo]
+		')
+	)
+	verify-sig? ( sec-keys/openpgp-keys-hughsie )
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/xz-utils
+	>=dev-libs/glib-2.72:2
+	>=dev-libs/libjcat-0.2.0[pkcs7]
+	>=dev-libs/libxmlb-0.3.19:=[introspection?]
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=net-misc/curl-7.62.0
+	cbor? ( >=dev-libs/libcbor-0.7.0:= )
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( >=net-libs/gnutls-3.6.0 )
+	virtual/libusb:1
+	lzma? ( app-arch/xz-utils )
+	modemmanager? ( >=net-misc/modemmanager-1.22.0[mbim,qmi] )
+	policykit? ( >=sys-auth/polkit-0.114 )
+	seccomp? ( sys-apps/systemd[seccomp] )
+	dev-db/sqlite
+	systemd? ( >=sys-apps/systemd-249 )
+	uefi? (
+		sys-apps/fwupd-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+	sys-kernel/linux-headers
+	amdgpu? (
+		x11-libs/libdrm[video_cards_amdgpu]
+	)
+"
+
+src_prepare() {
+	default
+
+	vala_setup
+
+	sed -i -e "/install_dir.*'doc'/s/doc/gtk-doc/" \
+		docs/meson.build || die
+
+	# Fails with DBus permission error
+	#sed -i -e "/g_test_add_data_func.*plugin-gtypes/d" \
+	#	src/fu-self-test.c || die
+
+	python_fix_shebang "${S}"/contrib/*.py
+}
+
+src_configure() {
+	local plugins=(
+		$(meson_feature flashrom plugin_flashrom)
+		$(meson_feature modemmanager plugin_modem_manager)
+		$(meson_use uefi plugin_uefi_capsule_splash)
+	)
+
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		-Defi_binary="false"
+		-Defi_os_dir="gentoo"
+		-Dman="true"
+		-Dsupported_build="enabled"
+		-Dsystemd_unit_user=""
+		$(meson_use bash-completion bash_completion)
+		$(meson_feature bluetooth bluez)
+		$(meson_feature cbor)
+		$(meson_feature gnutls)
+		$(meson_feature gtk-doc docs)
+		$(meson_feature introspection)
+		$(meson_feature policykit polkit)
+		$(meson_use test tests)
+
+		${plugins[@]}
+	)
+
+	if use elogind || use systemd ; then
+		emesonargs+=( -Dlogind=enabled )
+	else
+		emesonargs+=( -Dlogind=disabled )
+	fi
+
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_test() {
+	LC_ALL="C.UTF-8" meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
+	fi
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -rf \
+			"${ED}"/usr/libexec/installed-tests \
+			"${ED}"/usr/share/fwupd/device-tests \
+			"${ED}"/usr/share/fwupd/host-emulate.d/thinkpad-p1-iommu.json.gz \
+			"${ED}"/usr/share/fwupd/remotes.d/fwupd-tests.conf \
+			"${ED}"/usr/share/installed-tests \
+		|| die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	use minimal || udev_reload
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	use minimal || udev_reload
+}